perm filename COMCSS[KA,SYS] blob sn#472059 filedate 1976-07-10 generic text, type C, neo UTF8
COMMENT ⊗   VALID 00081 PAGES
C REC  PAGE   DESCRIPTION
C00001 00001
C00008 00002	BEGIN APRSER ↔ SUBTTL	SAVGET	4 AUG 67
C00010 00003	SGSET, SGSET0	SCAN COMMAND STRING ARGUMENTS FOR SAVE,GET,RUN AND R
C00016 00004	SAVJOB, SSAVJB
C00019 00005	THIS JOB GETS A JOB AREA FROM A RETRIEVABLE DEVICE
C00022 00006	JOB HAS JUST A JOB DATA AREA ASSIGNED WHEN CONTROL GETS HERE
C00024 00007	SG1 - SETUP ACS, RESET IO, ASSIGN DEVICE, LOOKUP FILE.
C00029 00008	SGREL ROUTINE TO RELEASE DEVICE AND FIND TTY
C00032 00009	ROUTINE TO GET FILE FROM DEVICE  -- GETJB
C00036 00010	MORE GETJB  - HERE WE DISCOVER IF WE HAVE A HIGH SEGMENT TO SET-UP
C00039 00011	END OF GET, REMAP ERROR, SETPR2 KLUDGE
C00042 00012	SAVJB, SSAVJA, SAVJBB ROUTINE TO SAVE A CORE IMAGE ON A DEVICE
C00048 00013	BEGIN SEGCSS ↔ SUBTTL	SEGCSS	8 SEPT 69	JAM ACCESS
C00050 00014	ESTSEG
C00053 00015	LINKSEG, MAKESEG, SEGFIN
C00057 00016	KILSEG  ROUTINE TO KILL A HIGH SEGMENT
C00061 00017	ZEROSEG - ROUTINE TO ERASE A SEGMENT ENTIRELY, SEGMENT'S JOB NUMBER IN J
C00063 00018	FLUSHSEG
C00067 00019	 UAPPLY - APPLY A ROUTINE TO ALL LOWERS OF AN UPPER.
C00069 00020	COMCSS		CTEXT, CTEXT1, GETLCCHR, CTEX, CTEXA, CTXCNC
C00072 00021	SKIPSJ, SKIPS, SKIPS1, SKIPSA, SKIPSB, CRLF, CONMES, TYO
C00075 00022	COMEND, COMERP, COMERA, COMERR, ERRMES
C00078 00023	INLMES, PRCRCC, PRCNCC, PRQM
C00080 00024	DEASG, DEASTY
C00082 00025	DECIN, OCTIN, ANYRIN
C00085 00026	PJPGNO - GET PROJECT-PROGRAMMER NUMBERS
C00087 00027	ERRCON	4 AUG 67		APRILM, UERROR, CERROR, ADRTST
C00092 00028	PIERR1  
C00093 00029	UUOERR: ILLEGAL UUO  - CALLED AT ANY LEVEL!
C00096 00030	ILLEGAL INSTRUCTION  -  ILLINS, HALT
C00099 00031	SPWMES - ERROR MESSAGE FOR SPW MODULES - HERE FROM P1 CLOCK LEVEL.
C00102 00032	ADRERR,UADRER,UADERR,ILLINP,ILLOUT,BTLERR,ILLMOD,IOIERR,DEVHNG,BADDIR,DEVEXC
C00106 00033	HNGSTP
C00107 00034	HNGMES 
C00108 00035	COMMON ERROR MESSAGE SETUP ROUTINES - ERRPTU, ERRDEV, ERRPNT
C00110 00036	ROUTINE TO PRINT UUO PC AND STOP JOB - UUOMES, UUOPCP
C00112 00037	PCSTOP, EXCALP, PCPNT
C00114 00038	PCP, OCTPNT, RADX10
C00116 00039	ERNAM, PRNAME
C00117 00040		SUBTTL	DISASTER TYPEOUT	DISINIT, DISOUT
C00120 00041	 DISFLUSH - TURNS PIS OFF AND TYPES ENTIRE DISASTER BUFFER TO CTY
C00123 00042	 DISTYO - TYPES ONE CHARACTER IN TEM THROUGH THE DISASTER BUFFER.
C00125 00043	DISMES, DISCRLF, DISTAB, DISJOB
C00127 00044	DISERR - CALLING SEQUENCE
C00129 00045	DISLOC, DISOCT, DISOCH, DISDCP, DISDEC, DISHE2
C00133 00046	DISSIX, DISFIL, DISPPN   -  SIXBIT PRINT ROUTINE FOR DISASTER MESSAGES
C00135 00047	CTYTYO  - TYPE ON THE CTY WITH PIS OFF  (ALSO TYPE ON CTY ON P2)
C00137 00048	DISDATE - SHOVE THE TIME AND DATE INTO DISASTER BUFFER
C00139 00049	IOCSS		ADVBFE ADVBE1
C00142 00050	PRSET, ADRCK
C00145 00051	ADVBFF ROUTINE TO ADVANCE INPUT BUFFER AT INTERRUPT LEVEL.  ADVXIT
C00148 00052	UUOACK, UADCK1, UADRCK
C00151 00053	COMCHK - CHECK VALIDITY OF A DUMP MODE COMMAND LIST AT UUO LEVEL
C00155 00054	DMPCMD - FETCH NEXT IOWD FROM A DUMP MODE COMMAND LIST AND ADDRESS CHECK
C00158 00055	ASSASG	ASSIGN DEVICE IF UNASSIGNED
C00161 00056	FNDDDB, DEVSRC, DEVLG, DEVPHY
C00165 00057	BUFCLC, BUFCLM  SETUP N-RING IO BUFFER IN USER AREA
C00167 00058	BUFCLC, BUFCLM
C00170 00059	BUFCLR - CLRBYT - DEVCR - DEVSTU
C00175 00060	IOALL, IOALLR, IORELS,IOWAIT
C00181 00061	IOKILL, CLRUSR
C00183 00062	FLAG DEVICE AS ACTIVE  - ORACT, SETACT, CLRACT, STOIOS
C00185 00063	DEVCHK  - HUNG TIMEOUT 
C00188 00064	IOSETC
C00193 00065	SETIOS, SETMOD - (SETSTS UUO)  SET DEVICE STATUS WORD FROM UUO, SETUP IOS
C00195 00066	RUNCSS	4 AUG 67	PHOLD, HOLD, ESTOP, ESTOP2, MSTOP
C00201 00067	STOP1, SETSTP - STOP A JOB FROM BEING SCHEDULED
C00204 00068	DLYCOM, NOCORQ, MONJOB
C00207 00069	MONSTR 
C00209 00070	USTART, MSTART
C00213 00071	SETRUN, REQUE
C00215 00072	SETSLP, WAKE
C00217 00073	GETDCDT, GETDCMT, MTWAIT, DTWAIT, DCWAIT, STWAIT, DVWAIT
C00221 00074	STTIOD, SETIOD
C00224 00075	WSCHED - CAUSE CLK ROUTINE TO RESCHEDULE   STOP2
C00226 00076	WAIT1
C00228 00077	WSYNC
C00232 00078	REPEAT 0,<
C00233 00079	BATCON	INITIATE PHANTOM PROCESSES	BATCLK
C00237 00080	GETBAT	
C00242 00081	CSTAT, STAPUT, STAPTT		STATISTICS SERVICE
C00245 ENDMK
C⊗;
BEGIN APRSER ↔ SUBTTL	SAVGET	4 AUG 67

;HISYS			;ASSEMBLE IN HIGH CORE

;SPECIAL LOCATION IN USER JOB DATA AREA FOR STORING ARGUMENTS
;USED IN UUO CALLS TO THE MONITOR

;FOR LOOKUP UUO
FILNAM←←0		;FILE NAME
FILEXT←←FILNAM+1	;FILE EXTENSION
FILDAT←←FILNAM+2	;DATE WRITTEN
FILLEN←←FILNAM+3	;LH=-LENGTH,RH=FIRST LOC-1 DUMPED ON ENTER
			;PROJECT PROGRAMMER ON LOOKUP

DMPEND←←FILLEN+1	;LAST WORD OF DUMP COMMAND LIST=0

;FOR OPEN UUO
MODWRD←←5		;IOS MODE WORD FOR OPEN UUO
DEVWRD←←MODWRD+1	;DEVICE NAME
HEDWRD←←MODWRD+2	;INPUT AND OUTPUT BUFFER HEADER ADDRESSES


DMPWRD←←11	;DUMP WORD FOR SAVE COMMAND
NEWCOR←←12	;NEW CORE ASSIGNMENT FOR RUN AS SPECIFIED BY THIRD
		;ARGUMENT TO PREVIOUS SAVE.
↑INCWRD←←13	;STARTING INCREMENT STORAGE FOR MONITOR JOB.

COMWRD←←17	;IN WHICH WE PASS THE SIXBIT COMMAND TO THE PROGRAM
CHRWRD←←16	;IN WHICH WE PASS THE ASCII DELIMITER TO THE PROGRAM
;SGSET, SGSET0	SCAN COMMAND STRING ARGUMENTS FOR SAVE,GET,RUN AND R
;COMMANDS AND STORE THEM IN JOB DATA AREA WHICH MUST BE IN CORE
;WHEN SGSET IS CALLED FROM COMMAND DECODER
;WE MUST REFERENCE USER CORE BY XCTR, NOT BY ABSOLUTE ADDRESS, THEREFORE,
;THE MAP MUST BE SETUP FOR THIS USER BEFORE WE GET HERE.
;CALL:	MOVE TAC,INPUT BYTE POINTER
;	MOVE TAC1,SIXBIT DEVICE NAME (FIRST ARGUMENT TO RUN, GET, ETC. COMMAND)
;	MOVE DAT,OUTPUT BYTE POINTER
;	MOVE IOS,ADR. OF MONITOR JOB(SAVJOB,GETJOB,RUNJOB)
;	MOVE PROG, ADR. OF JOB AREA
;	PUSHJ P,SGSET
;ALTERNATIVELY: SET AC2 TO EXPLICIT PPN OF FILE AND ENTER BY:  PUSHJ P,SGSET0

SGDVOK:	PUSH	P,TAC			;CHECK TO SEE IF ARG IS LEGAL SAVEGET DEV
	PUSH	P,IOS
	PUSH	P,DAT
	PUSH	P,DDB
	MOVE	TAC,TAC1
	PUSHJ	P,DEVSRC		;IS THERE SUCH A DEVICE
	JRST	SGSETB			;NOT A LEGAL DEVICE. ASSUME IT WAS FILENAME
	MOVE	TAC,DEVMOD(DDB)
	TLNE	TAC,DVDSK!DVDTA!DVMTA	;ONLY LEGAL DEVICES FOR SAVE GET
	AOS	-4(P)
SGSETB:	POP	P,DDB
	POP	P,DAT
	POP	P,IOS
	JRST	TPOPJ

;HERE AT CLOCK LEVEL FROM COMMAND DECODER
SGSET:	MOVEI	AC2,0			;NORMAL ENTRY - DISABLE PPN KLUDGE
SGSET0:	MOVEM	AC2,JOBPPN(J)		;THIS IS THE RUN FROM ANOTHER AREA KLUDGE
	XCTR	XW,[MOVEM TAC1,DEVWRD]	;STORE FIRST ARG. MAY BE DEVICE, OR FILE
	JUMPE	TAC1,SGSETC		;ASSUME DSK IF NO ARG
	PUSHJ	P,SGDVOK		;SEE IF IT'S A VALID DEVICE NAME
	JRST	SGSETC			;WASN'T A DEVICE NAME
	SKIPN	TAC1,JOBNAM(J)		;WAS DEVICE.   AUTOMATIC FILENAME?
	JRST	SGSET3			;NO. READ ONE FROM THE COMMAND STRING
SGSETA:	XCTR	XW,[MOVEM TAC1,FILNAM]	;OK. SET FILE NAME
	MOVSI	TAC1,'DMP'
	XCTR	XW,[MOVEM TAC1,FILEXT]	;DEFAULT EXTENSION
	XCTR	XW,[SETZM FILLEN]
	XCT	SGPPN			;LOAD AC1 WITH DEFAULT PPN
	JRST	SGSET1

SGSETC:	MOVSI	TAC1,'DSK'		;NO TRY TO ASSUME DISK
	XCTR	XRW,[EXCH TAC1,DEVWRD]	;USE THIS FOR FILENAME
	JUMPN	TAC1,SGSETD
	SKIPN	TAC1,JOBNAM(J)
	JRST	NOTENF
	JRST	SGSETA

SGSET3:	PUSHJ	P, CTEXT1		;GET FILE NAME FROM COMMAND STRING
	JUMPE	TAC1,NOTENF		;THERE MUST BE A FILE NAME
SGSETD:	XCTR	XW,[MOVEM TAC1,FILNAM]	;STORE FILE NAME
	MOVEM	TAC1,JOBNAM(J)		;STORE ALSO FOR SYSTAT
IFN FTSTAT,<	PUSHJ	P,NAMSTT>
	MOVSI	TAC1,'DMP'		;ASSUME EXTENSION
	CAIN	TEM,"."			;EXTENSION EXPECTED?
	PUSHJ	P,CTEXT1		;YES. GET EXTENSION, OTHERWISE USE DEFAULT
	XCTR	XW,[HLLZM TAC1,FILEXT]	;STORE IT FOR LOOKUP
	XCTR	XW,[SETZM FILLEN]
	PUSHJ	P,PJPGNO		;SCAN PPN FROM COMMAND LINE
SGPPN:	JSP	AC1,[SKIPN AC2,DSKPPN(J) ;THIS IS A SUBROUTINE CALLED BY XCT SGPPN
		    MOVE AC2,PRJPRG(J)
		    JRST (AC1)]
	PUSHJ	P,DECIN1	;CORE SIZE, IN PAGES OR K, (OPTIONAL THIRD ARG.)
	JRST	SGSET1		;DOES NOT RETURN IF ERROR, RETURN HERE IF NO ARG.
	JRST	COMERA		;ILLEGAL CHARACTER
	LSH	TAC1,-CSHIFT	;CONVERT TO HIGHEST RELATIVE LOCATION (+9 OR +10)
	SUBI	TAC1,1
	TLNE	TAC1,-1		;STOP BEFORE ACTING SILLY
	JRST	COMERR		
SGSET1:	XCTR	XW,[HRRZM TAC1,JOBCOR]	;STORE FOR RUN COMMAND AND SAVE
	SKIPN	JOBPPN(J)	;SKIP IF EXPLICIT PPN KLUDGE.
	MOVEM	AC2,JOBPPN(J)	;SAVE PPN
;IOS CONTAINS DISPATCH ADDRESS (SUCH AS RUNJOB, GETJOB, SAVJOB, SSAVJB)
	MOVE	TAC1,IOS		;SCHEDULE MONITOR JOB
	JRST	MSTART			;START JOB WITH PC IN MONITOR MODE

;MSTART RETURNS TO COMMAND DECODER AFTER SCHEDULING THE JOB TO BE RUN AT
;UUO LEVEL, STARTING AT THE SPECIFIED PC.  NOTE THAT THE NORMAL ACS ETC.
;THAT ARE NORMALLY SETUP AT UUO LEVEL ARE NOT SETUP IN THIS CASE.  HENCE,
;MONSTR MUST BE CALLED TO INITIALIZE ACS TO REASONABLE VALUES.
;SAVJOB, SSAVJB
;THIS JOB SAVES A JOB AREA ON RETRIEVABLE STORAGE
;THIS JOB RUNS IN EXEC. MODE AND CALLS IO ROUTINES DIRECTLY
;NO ATTEMPT IS MADE TO SAVE STATUS OF IO DEVICES, JOBPDP, OR AC'S
;IN FACT THE ONLY USEFUL THING WHICH MAY BE DONE WITH A JOB AREA
;AFTER IT HAS BEEN SAVED IS TO START EXECUTION OVER AT THE STARTING
;ADDRESS


↑SSAVJB:			;HERE AT UUO LEVEL FOR SSAVE COMMAND
	JSP	TAC1,SG1	;SET UP FOR SAVE
	JFCL			;IGNORE LOOKUP FAILURE
	PUSHJ	P,SSAVJA	;NON-FLUSH SEGMENT ENTRANCE
	JRST	SAVJB1

↑SAVJOB:			;HERE AT UUO LEVEL FOR SAVE COMMAND
	JSP	TAC1,SG1	;SET UP ACS AND ASSIGN DEVICE AND LOOKUP
	JFCL			;IGNORE LOOKUP FAILURE
	PUSHJ	P,SAVJB		;THIS ROUTINE ACTUALLY DOES THE WORK

SAVJB1:	PUSHJ	P,INLMES	;Job saved in nn{+qq} pages. {(Upper not saved)}
	ASCIZ	/Job saved in /
	XCTR	XR,[HLRO TAC,FILLEN]
	MOVNS	TAC
	ADDI	TAC,JOBSAV
	LSH	TAC,-12
	ADDI	TAC,1	

IFN FTPAGER,<	LSH	TAC,1	>;COUNT PAGES (CROCK!)

	PUSHJ	P,RADX10	;TELL HIM HOW MUCH WE SAVED IT IN
	XCTR	XR,[SKIPE NEWCOR]
	JRST	SAVEUP		;AND UPPER
	LDB	TAC,PSEGN
	JUMPE	TAC,GETNUP	;IF NO UPPER, CALL PHOLD AND PRINT " K" OR " pages"
	JSP	TAC,PHOLD	;YES, TELL HIM NOT SAVED
IFE FTPAGER,<	ASCIZ	/ K  (Upper not saved)/	>;IFN FTPAGER
IFN FTPAGER,<	ASCIZ	/ pages. (Upper not saved)/	>;IFN FTPAGER


SAVEUP:	MOVEI	TEM,"+"
	XCT	TYO
	XCTR	XR,[HLRO TAC,NEWCOR]
	MOVNS	TAC
	ADDI	TAC,1777
	LSH	TAC,-12
IFN FTPAGER,<	LSH	TAC,1>
	PUSHJ	P,RADX10
	JRST	GETNUP		;CALL PHOLD AND PRINT " K" OR " pages"
;THIS JOB GETS A JOB AREA FROM A RETRIEVABLE DEVICE
;THIS JOB RUNS IN EXEC. MODE AND CALLS IO ROUTINES DIRECTLY
;NO ATTEMPT IS MADE TO RESTORE STATUS OF IO DEVICES, PC, OR AC'S
;JOBPC IS SET TO STARTING ADDRESS OF JOB
;CORE MUST ALREADY HAVE BEEN ASSIGNED AND THE FOLLOWING LOC. SETUP IN
;JOB DATA AREA:
;JOBPDP, JOBREL


↑GETJOB:			;HERE AT UUO LEVEL TO PERFORM GET
	JSP	TAC1,SG1	;SET UP ACS, ASSIGN DEVICE, AND DO LOOKUP
	JRST	NOFILE		;FILE NOT FOUND RETURN
	PUSHJ	P,GETJB		;GET THE JOB
GETJ1:	PUSHJ	P,INLMES	;RETURN ONLY IF EVERYTING OK
	ASCIZ	/Job setup in /
	HLRZ	TAC,JBTPAG(J)

IFE FTPAGER,<	LSH	TAC,-1		;CONVERT PAGES TO K >;IFE FTPAGER

	PUSHJ	P,RADX10
	LDB	TAC,PSEGN
	JUMPE	TAC,GETNUP
	HLRZ	TAC,JBTPAG(TAC)		

IFE FTPAGER,<	LSH	TAC,-1		;CONVERT PAGES TO K >;IFE FTPAGER

	PUSH	P,TAC
	MOVEI	TEM,"+"
	XCT	TYO
	POP	P,TAC
	PUSHJ	P,RADX10
GETNUP:	JSP	TAC,PHOLD
IFE FTPAGER,<	ASCIZ	/ K/		>;IFE FTPAGER
IFN FTPAGER,<	ASCIZ	/ pages/	>;IFN FTPAGER



NOFILE:	PUSHJ	P,CLRTPV		;NOT FOUND--CLEAR TEMPORARY PRIVILEGES
	PUSHJ	P,SGREL			;RELEASE DEVICE, FIND TTY
	PUSHJ	P,PRQM		
	XCTR	XR,[MOVE TAC1,FILNAM]	;PRINT FILE NAME
	PUSHJ	P,PRNAME
	PUSHJ	P,PRPER			;PRINT PERIOD
	XCTR	XR,[HLLZ TAC1,FILEXT]
	PUSHJ	P,PRNAME		;PRINT EXTENSION
	JSP	TAC,PHOLD		;PRINT MESS. AND STOP JOB
	ASCIZ	/ not found/
;JOB HAS JUST A JOB DATA AREA ASSIGNED WHEN CONTROL GETS HERE
;THIS MONITOR JOB GETS A JOB AREA FROM A RETRIEVABLE DEVICE
;ASSIGNS CORE AND START


↑RUNJOB:			;HERE AT UUO LEVEL TO PERFORM RUN OR R COMMAND
	JSP	TAC1,SG1		;SETUP ACS, ASSIGN DEVICE, AND DO LOOKUP
	JRST	NOFILE			;NO FILE FOUND RETURN
	PUSHJ	P,GETJB			;GET THE FILE
	XCTR	XR,[HRRZ TAC,JOBSA]	;GET STARTING ADDRESS
	TRNN	TAC,-1
	JRST	NOSTRT
	ADD	TAC,SAVSAI(J)		;ADD STARTING ADDRESS INCREMENT
	HRLI	TAC,USRMOD		;SET USER MODE BIT
	MOVEM	TAC,UUOPC(J)		;MAKE IT LOOK LIKE UUO RETURN
	MOVE	TAC,JOBPPN(J)		;GET PRJPRG OF FILE
	JRST	USRXIT			;AND GO START USER

NOSTRT:	PUSHJ	P,INLMES
	ASCIZ	/? No starting address.
/
	JRST	GETJ1
;SG1 - SETUP ACS, RESET IO, ASSIGN DEVICE, LOOKUP FILE.
;CALL:	JSP TAC1,SG1
;	FILE NOT FOUND RETURN
;	FILE FOUND RETURN
;	IOWD FOR THIS SIZE CORE RETURNED IN AC TAC
;	DEVMOD IN TAC1



;HERE AT UUO LEVEL.  IF THIS WAS CALLED FOR SAVGET, WE NEED TO SETUP
;UUO LEVEL ACS.  IF THIS WAS CALLED FROM SWAP UUO, WE SETUP AC'S ANYWAY.
SG1:	JSP	TAC,MONSTR		;SET ACS TO NORMAL UUO LEVEL ENVIRONMENT
	PUSHJ	P,RESETUUO		;RELEASE ALL DEVICES
	MOVEI	TAC,17			;DUMP MODE - FLUSH OLD MODE 2.
	XCTR	XW,[MOVEM TAC,MODWRD]	;STORE FOR OPEN UUO
	XCTR	XW,[SETZM HEDWRD]	;CLEAR BUFFER HEADER ARG.
	XCTR	XR,[SKIPN TAC,JOBCOR]	;WAS CORE SIZE SPECIFIED
	JRST	SGCOR			;NO
	HLRZ	TAC1,JBTPAG(J)		;YES.  WHAT'S THE OLD CORE SIZE?
	LSH	TAC1,=9
	CAMGE	TAC,TAC1		;SKIP IF WE HAVEN'T ENOUGH ALREADY.
	JRST	SGCOR1			;WE HAVE ENOUGH.  USE WHAT HE SPECIFIED.
	PUSHJ	P,RUNCOR		;TRY FOR ENOUGH
	JRST	SG2			;CAN'T GET IT.  GIVE HIM WHAT HE'S GOT NOW
SGCOR1:	XCTR	XR,[MOVN TAC,JOBCOR]
	JRST	SGCOR2

SGCOR:	SKIPE	USRDDT(PID)		;IF DDT IS IN
	JRST	SG2			; THEN SAVE UP TO JOBREL
	XCTR	XR,[HRRZ TAC,JOBFF]	;PICK UP FIRST FREE LOCATION
	JUMPE	TAC,SG2			;IF ZERO, SAVE UP TO JOBREL
	HLRZ	TAC1,JBTPAG(J)		;GET THE CORE SIZE
	LSH	TAC1,=9
	CAML	TAC,TAC1		;IS JOBFF IN BOUNDS?
	JRST	SG2			;NO, SAVE THROUGH JOBREL
	MOVN	TAC,TAC			;NEGATE TO FORM HALF OF IOWD
	JRST	SGCOR2

SG2:	HLRZ	TAC,JBTPAG(J)		;HERE, SAVE CORE THRU JOBREL
	LSH	TAC,=9
	SUBI	TAC,1
	MOVN	TAC,TAC
SGCOR2:	ADDI	TAC,JOBSAV		;LOWER CORE NOT DUMPED
	HRLI	TAC,JOBSAV
	XCTR	XW,[MOVSM TAC,DMPWRD]	;STORE IOWD WORD OF THIS SIZE CORE
	OPEN	0,MODWRD		;TRY TO ASSIGN DEVICE
	JRST	SGERRA			;NOT AVAILABLE
	MOVE	TAC1,DEVNAM(DDB)
	MOVEM	TAC1,JOBDEV(J)
	MOVE	TAC1,DEVLOG(DDB)
	MOVEM	TAC1,JOBLOG(J)
	MOVE	TAC1,DEVMOD(DDB)
	MOVE	AC1,JOBPPN(J)		;GET PROJECT-PROGRAMMER NUMBER
	XCTR	XW,[MOVEM AC1,FILLEN]	;SET IT INTO PLACE
	LOOKUP	0,FILNAM		;LOOKUP FILE NAME
	SOS	(P)			;NOT FOUND - NON-SKIP RETURN
	XCTR	XR,[MOVE TAC,DMPWRD]	;FOUND, RETURN IOWD FOR THIS SIZE CORE
	MOVE	TAC1,DEVMOD(DDB)
	MOVE	J,JOB(PID)		;RESTORE JOB NUMBER FOR THOSE WHO NEED IT
	TLNE	TAC1,DVDSK		;DISK?
	JRST	SG3			;YES.
	SETZM	JOBPPN(J)		;NOT DSK.
	JRST	CPOPJ1

SG3:	MOVE	AC1,FILPPN(DDB)
	EXCH	AC1,JOBPPN(J)
	JRST	CPOPJ1			;SKIP RETURN, UNLESS FILE NOT FOUND

;HERE IF SAVE DEVICE NOT AVAILABLE - PRINT ERROR MESSAGE AND STOP JOB

SGERRA:	JUMPE	DDB,SGERR1
	MOVEM	DDB,(P)			;PRINT DEVICE XXX
	PUSHJ	P,TTYFNU		;FIND TTY
	PUSHJ	P,PRQM			;PRINT "?"
	PUSHJ	P,ERNAM			;"DEVICE XXX"
	JSP	TAC,PHOLD		;PRINT AND STOP JOB
	ASCIZ	/ not available/

SGERR1:	PUSHJ	P,TTYFNU
	JSP	TAC,PHOLD
	ASCIZ	/? No such device/
;SGREL ROUTINE TO RELEASE DEVICE AND FIND TTY

SGREL:	SKIPN	USRJDA(PID)	;HAS CHANNEL BEEN RELEASED ALREADY?
	JRST	TTYFUW		;YES. FIND TTY AND WAIT FOR OUTPUT TO FINSIH
	MOVE	TAC,DEVMOD(DDB)
	TLNE	TAC,DVMTA	;MAGTAPE?
	TLNN	DDB,INPB	;YES. WAS AN INPUT DONE?
	JRST	SGREL1		;NO
	CLOSE	0,CLSOUT	;YES. CLOSE INPUT.
	STATO	0,IOTEND	;AT END OF TAPE?
	MTAPE	0,6		;NO. SKIP TO EOF
SGREL1:	RELEASE	0,		;NO, RELEASE DEVICE
	JRST	TTYFUW		;FIND TTY AND WAIT FOR OUTPUT TO FINISH

NOROM0:	MOVE	TAC,DEVMOD(DDB)		;HERE IF USER'S CORE ARG WAS TOO BIG. 
	TLNN	TAC,DVMTA		;PRINT MINIMUM CORE SIZE NEEDED, EXCEPT
	XCTR	XW,[SETZM JOBCOR]	;ON MTA, MINIMUM CORE SIZE IS UNKNOWN.
NOROOM:	PUSHJ	P,SGREL			;RELEASE DEVICE, FIND TTY
	PUSHJ	P,CRLF
	PUSHJ	P,PRQM
	XCTR	XR,[SKIPLE TAC,JOBCOR]	;GET MIN. HIGHEST REL.LOC. FOR JOB TO RUN
	JRST	NOROM1			;USE IT IF SPECIFIED.
	XCTR	XR,[HLRO TAC1,FILLEN]	;-LENGTH OF FILE
	MOVNS	TAC1			;+LENGTH
	XCTR	XR,[HRRZ TAC,FILLEN]	;FIRST LOC-1 DUMPED
	ADD	TAC,TAC1		;LAST LOC DUMPED
NOROM1:	
IFE FTPAGER,<	ADDI	TAC,1777	;ROUND UP TO 1K BOUNDARY >;IFE FTPAGER
IFN FTPAGER,<	ADDI	TAC,777		;ROUND UP TO PAGE BOUNDARY >;IFN FTPAGER
	LSH	TAC,CSHIFT		;CONVERT TO PAGE OR K COUNT
	PUSHJ	P,RADX10
	JSP	TAC,PHOLD		;GO START TTY, AND STOP JOB
IFE FTPAGER,<	ASCIZ	/ K of core needed/ >
IFN FTPAGER,<	ASCIZ	/ pages of core needed/ >

;ROUTINE TO GET FILE FROM DEVICE  -- GETJB


GETJB:	PUSHJ	P,RESETSEG		;FLUSH UPPER AND ANY DETACHED SEGMENTS
	XCTR	XW,[SETZM JOBINT] 	;THIS ISN'T CLEARED BY GETTING FILE
	XCTR	XR,[MOVE TAC,FILDAT]
	MOVEM	TAC,JOBCRD(J)		;COPY CREATION DATE FOR SEGMENT ACCESS
	XCTR	XR,[MOVE TAC,DMPWRD]
	TLNE	TAC1,DVDSK		;DISK?
	XCTR	XRW,[HRRM TAC,FILLEN]	;YES.
	XCTR	XR,[HRRZ TAC,JOBCOR]	;HIGHEST REL.LOC. REQUESTED
	XCTR	XW,[MOVEM TAC,NEWCOR]	;SAVE IT
	JUMPG	TAC,GETJB1		;JUMP IF CORE ARGUMENT WAS SPECIFIED
	TLNE	TAC1,DVMTA		;MAGTAPE?
	JRST	GETJB3			;MAGTAPE.
	XCTR	XR,[MOVE TAC1,FILLEN]
	TLNN	TAC1,-1			;-WC OF ZERO IS ILLEGAL
	JRST	GETERR
	HLRO	TAC1,TAC1		;USE AMOUNT OF CORE SPECIFIED IN DIRECTORY
	XCTR	XR,[HRRZ TAC,FILLEN]	;FIRST LOC.-1
	SUB	TAC,TAC1		;TOTAL # OF WORDS NEEDED-1 = HIGHEST LOCATION DUMPED
	IORI	TAC,1777		;HIGHEST LOC. IN 1K BLOCKS
GETJB1:	MOVE	J,JOB(PID)		;SETUP JOB NUMBER
	PUSHJ	P,RUNCOR		;TRY TO ASSIGN CORE
	JRST	NOROM0			;USER ARG TOO BIG. PRINT MINIMUM NEEDED.
	MOVE	TAC1,DEVMOD(DDB)
	TLNN	TAC1,DVMTA		;MAGTAPE?
	JRST	GETJB2			;NO.
GETJB3:	HLRZ	TAC1,JBTPAG(J)		;YES. SET FILLEN TO CURRENT CORE SIZE.
	LSH	TAC1,=9
	SUBI	TAC1,JOBSAV+1
	MOVNS	TAC1
	HRLI	TAC1,JOBSAV
	XCTR	XW,[MOVSM TAC1,FILLEN]
GETJB2:	XCTR	XW,[SETZM DMPEND]	;SET 2ND WORD OF DUMP LIST TO 0
	XCTR	XW,[SETZM JOBCOR]	;SO NOROOM MESSAGE ALWAYS WORKS
	XCTR	XR,[HLRO TAC,FILLEN]	;GET - NO. WORDS TO READ OR WRITE
	SUBI	TAC,JOBSAV		;NO. OF LOWER CORE LOC. NOT DUMPED
	HLRZ	TAC1,JBTPAG(J)
	LSH	TAC1,=9
	ADDI	TAC,-1(TAC1)		;+HIGHEST LOCATION IN USER AREA
	JUMPL	TAC,NOROOM		;WILL IT FIT?
	MOVEM	DDB,USRHCU(PID)		;SET HIGHEST IO CHAN IN USE NEGATIVE
					;ALSO ADDRESS OF SAVE GET DEVICE.
	INPUT	0,FILLEN		;READ INTO PROTECTED PART OF JOB DATA AREA
	PUSHJ	P,CLRUSR		;CLEAR OUT POSSIBLE GARBAGE
					;AND SET USRHCU BACK TO 0
	MOVEM	DDB,USRJDA(PID)		;RESTORE CHANNEL 0 ASSIGNMENT
	PUSH	P,IOS			;SAVE POSSIBLE ERROR BITS
	PUSHJ	P,SGREL			;RELEASE DEVICE,FIND TTY
	XCTR	XR,[MOVE TAC,JOBS41]	;RESTORE USER UUO JSR LOC.
	XCTR	XW,[MOVEM TAC,JOB41]	;IN CASE THIS IS GET OR RUN
	POP	P,TAC			;GET BACK BITS
	TRNE	TAC,IOBKTL+IODERR+IODTER+IOIMPM	;ANY ERRORS FROM GET DEVICE?
	JRST	SGTERR			;YES.  LOSE MESSAGE
	MOVE	TAC,JOBPPN(J)
;	XCTR	XW,[MOVEM TAC,FILLEN]	;RESTORE PPN FOR PROGRAM TO SEE
	XCTR	XR,[HLRZ TAC,HILOC]	;SEGMENT PROTECTION SAVED HERE
					;IF NO SEGMENT WAS SAVED, PROT WILL BE 0.
	ANDI	TAC,377			;FLUSH UNUSED BITS
	DPB	TAC,[POINT 9,JOBCRD(J),8]
;FALL OFF PAGE.  SEE IF THERE'S AN UPPER TO SETUP
;MORE GETJB  - HERE WE DISCOVER IF WE HAVE A HIGH SEGMENT TO SET-UP
;FIRST TRY TO ATTACH TO THE SAVED NAME (IF ANY)
;MAKE SURE IT IS WRITE PROTECTED, AND THAT IS WHAT WE WANT
;IF ALL THIS FAILS, TRY A REMAP ON OUR SEGMENT.

	XCTR	XR,[SKIPN TAC,HILOC]	;DOES THIS JOB HAVE A HIGH SEGMENT?
	JRST	GETDN1			;NO, FIX UP CORE SIZE AND LEAVE
	MOVEI	TAC,(TAC)		;ONLY INTERESTED IN RIGHT HALF
	IORI	TAC,1777		;WHERE IT WILL BE MOVED TO
	HLRZ	TAC1,JBTPAG(J)
	LSH	TAC1,=9
	CAIL	TAC,-1(TAC1)		;IS ADDRESS ABOVE TOP?
	JRST	GETERA			;YES, EVIL EVIL(NOT A DUMP FILE)
	PUSH	P,DDB			;DDB CLOBBERED BY SEGMENT UUOS
	XCTR	XR,[SKIPN TAC,HINAME]	;GET SAVED HIGH SEGMENT NAME!
	JRST	GETJ5
	XCTR	XW,[MOVEM TAC,FILLEN]
GETJ5C:	ATTSEG	FILLEN,			;ATTACH TO IT?
	JRST	GETJ5			;ERROR RETURN
	LDB	TAC,PSEGN		;GET ITS JOB NUMBER
	MOVE	TAC,JBTSTS(TAC)
	XCTR	XR,[SKIPL HILOC]	;DO WE WANT WRITE PROT?
	JRST	GETJ7
	TLNE	TAC,JWP			;YES, IS HE WRITE PROTECTED
	JRST	GETDON			;PROT MATCHES
	JRST	GETJ8

GETJ7:	TLNN	TAC,JWP			;IS HE UNPROTECTED?
	JRST	GETDON			;THAT'S IT!
GETJ8:	DETSEG				;DETACH THIS ONE
GETJ5:	XCTR	XR,[HRRZ TAC,HILOC]	;CURRENT BOTTEM OF SEGMENT
	SUBI	TAC,1
	PUSHJ	P,BLTUP			;MOVE UPPER TO NEXT 1K BOUNDARY
	XCTR	XR,[MOVE TAC,HILOC]	;SIGN BIT INDICATES WANT WRITE PROT
	SUBI	TAC,1
	IORI	TAC,1777
	XCTR	XW,[MOVEM TAC,FILLEN]	;SET UP AC FOR REMAP, SIGN ON IF WANT...
	REMAP	FILLEN,			;...WRITE PROTECT
	JRST	GETJ5B			;ERROR RETURN, TRY SETPR2
	JRST	GETDN2
;END OF GET, REMAP ERROR, SETPR2 KLUDGE

GETJ5B:	POP	P,DDB			;GET BACK TTY DDB
	MOVEI	DAT,TTOBUF(DDB)		;AND SET UP THIS GUY
	PUSHJ	P,INLMES
	ASCIZ	/
Couldn't get you a segment.  Will try to let you win with SETPR2.
/
	HLRZ	TAC,JBTPAG(J)
	LSH	TAC,=9
	SUBI	TAC,1
	XCTR	XW,[MOVEM TAC,JOBCOR]	;DON'T LET HIM CORE DOWN BELOW UPPER
	ADDI	TAC,1
	XCTR	XW,[MOVEM TAC,JOBFF]	;AND TELL HIM NOT TO WRITE OVER IT
	XCTR	XRW,[HRLM TAC,JOBSA]	;IN BOTH WAYS
	XCTR	XR,[SUB TAC,FILLEN]	;LENGTH OF UPPER+1
	MOVSI	TAC,-2(TAC)
	XCTR	XR,[SKIPL HILOC]
	TLZ	TAC,1			;SET UP W.P. BIT
	XCTR	XR,[HRR TAC,FILLEN]
	ADDI	TAC,1+3			;REMOVE OFFSET, SET "RELATIVE"
					;   & "PSEUDO-UPPER" BITS
	PUSHJ	P,STPR2
	JRST	GETDN1

GETERR:	PUSHJ	P,SGREL			;RELEASE DEVICE AND FIND TTY
GETERA:	JSP	TAC,PHOLD
	ASCIZ /? not a dump file/

GETDN2:	XCTR	XR,[SKIPN TAC,HINAME]
	JRST	GETDON
	LDB	TAC1,PSEGN
	MOVE	DDB,NJOBS(TAC1)
IFE FTSTAT,<CAIG DDB,1			;MORE THAN ONE JOB MEANS WE'RE NOT THE FIRST
	MOVEM	TAC,JOBNAM(TAC1)
>;IFE FTSTAT
IFN FTSTAT,<
	CAILE	DDB,1
	JRST	GETDON
	MOVEM	TAC,JOBNAM(TAC1)
	PUSH	P,J
	MOVE	J,TAC1
	PUSHJ	P,NAMSTT
	POP	P,J
>;FTSTAT
GETDON:	POP	P,DDB			;GET BACK TTY DDB
	MOVEI	DAT,TTOBUF(DDB)
GETDN1:	PUSHJ	P,FINZRL		;(IN SCHEDU)  SETS UP JOBRL2 (aka JOBHRL)
	MOVE	TAC,JOBPPN(J)
	XCTR	XW,[MOVEM TAC,FILLEN]	;RESTORE PPN FOR PROGRAM TO SEE
	XCTR	XW,[MOVEM TAC,DMPEND]	;IN USER'S ACS 3 AND 4
	XCTR	XR,[SKIPE TAC,NEWCOR]	;DID USER TYPE 3RD ARGUMENT?
	XCTR	XR,[CAMG TAC,JOBCOR]	;YES, IS 3RD ARG GREATER THAN MIN SIZE
					;SPECIFIED BY 3RD ARG TO SAVE (IF ANY)
	XCTR	XR,[MOVE TAC,JOBCOR]	;NO, ASSIGN NEW BIGGER AMOUNT OF CORE
	JUMPLE	TAC,CPOPJ		;IF 0 OR NEG, DOESN'T MAKE SENSE.
	IORI	TAC,1777
	HLRZ	TAC1,JBTPAG(J)		;HOW MUCH DOES HE HAVE NOW
	LSH	TAC1,=9
	SUBI	TAC1,1
	CAMN	TAC1,TAC		;DIFFERENT?
	POPJ	P,			;NO
	PUSHJ	P,RUNCOR
	JFCL				;IGNORE IF CAN'T
	POPJ	P,
;SAVJB, SSAVJA, SAVJBB ROUTINE TO SAVE A CORE IMAGE ON A DEVICE
;ENTER AT SAVJB FOR SAVE COMMAND
;SSAVJA FOR SSAVE COMMAND
;SAVJBB FOR SAVE SIDE OF THE SWAP UUO, WITH NEWCOR SETUP.

;DO NOT CLOBBER ANY ACS BETWEEN CALLING SG1 AND ENTERING ANY OF THESE.

SSAVJA:	XCTR	XW,[SETOM NEWCOR]	;FLAG TO SAVE UPPER
	JRST	SAVJBB

SAVJB:	XCTR	XW,[SETZM NEWCOR]	;SIGNAL NO SAVE OF UPPER SEGMENT
SAVJBB:	XCTR	XW,[MOVEM AC1,FILLEN]	;RESTORE PPN TO FOURTH WORD OF LOOKUP BLOCK
	TLNN	TAC1,DVDSK		;DISK?
	XCTR	XW,[MOVEM TAC,FILLEN]	;NO. SET FILE LENGTH IN DIRECTORY HEADER
	XCTR	XW,[SETZM FILDAT]	;MAKE SURE WE GET TODAY'S DATE
	XCTR	XRW,[HLLZS FILEXT]	;DATE75 - MAKE SURE RH. OF EXT. WORD IS CLEAR.
	TLNE	TAC1,DVDSK		;DSK?
	CLOSE	0,CLSOUT		;YES, CLOSE INPUT TO AVOID BEING IN READ/ALTER
	ENTER	0,FILNAM		;ENTER FILE NAME IN DIRECTORY
	JRST	SAV4			;DIRECTORY FULL
	XCTR	XR,[MOVE TAC,DMPWRD]	;RESTORE FILLEN AFTER DISC ENTER
	XCTR	XW,[MOVEM TAC,FILLEN]
	XCTR	XR,[MOVE TAC,JOB41]	;SAVE USER UUO HANDLING JSR
	XCTR	XW,[MOVEM TAC,JOBS41]	;IN UPPER PART OF JOB DATA AREA
	XCTR	XR,[SKIPN NEWCOR]	;SHALL WE SAVE UPPER?
	JRST	SAVJ1			;NO
	LDB	TAC,PSEGN		;SEGMENT NUMBER
	JUMPE	TAC,SAVJ1

IFN FTHPSG,<
	HRRZ	TAC1,JBTPAG(TAC)
	CAIGE	TAC1,1000
	JRST	SAVJ0
	MOVE	J,JOB(PID)
	MOVEI	TAC,1
	PUSHJ	P,LTHUUO		;MOVE FROM HIGH TO LOW
	MOVE	J,JOB(PID)
	LDB	TAC,PSEGN
	PUSHJ	P,SAVJ0			;SSAVE THE LOWER AND LOWCORE-UPPER
	MOVEI	TAC,0
	PUSHJ	P,LTHUUO		;MOVE FROM LOW TO HIGH
	JFCL				;IGNORE FAILURE
	MOVE	J,JOB(PID)
	POPJ	P,
>;FTHPSG

SAVJ0:	HLRZ	TAC1,JBTPAG(TAC)
	LSH	TAC1,=9			;SIZE OF SEGMENT 
	MOVN	TAC1,TAC1
	MOVS	TAC1,TAC1
	HRRI	TAC1,377777		;-WC,,ADDRESS-1
	XCTR	XW,[MOVEM TAC1,NEWCOR]
	XCTR	XR,[HLRO TAC1,FILLEN]	;-LENGTH OF LOWER
	SETCM	TAC1,TAC1		;COMPUTE +(LENGTH OF FIRST PART)-1
	IORI	TAC1,177		;MAKE IT A DISK BLOCK BOUNDARY-1
	ADDI	TAC1,JOBSAV+1+1		;ROUNDING UP AND MAKING INTO CORE LOC
	LDB	TAC,[POINT 9,JOBCRD(TAC),8]
	HRL	TAC1,TAC		;SET SEGMENT PROT BITS IN JOBRL2 LH.
	LDB	TAC,PSEGN		;GET THIS BACK
	MOVE	TAC,JBTSTS(TAC)
	TLNE	TAC,JWP
	TLO	TAC1,(1B0)		;SET SIGN BIT IF WRITE PROTECTED.
	XCTR	XW,[MOVEM TAC1,JOBRL2]	;MAKE COMPATIBLE
	XCTR	XW,[MOVEM TAC1,HILOC]
	LDB	TAC,PSEGN		;AND AGAIN
	MOVE	TAC,JOBNAM(TAC)
	CAMN	TAC,JOBNAM(J)		;SAME NAMED UPPER AS LOWER
	SETZ	TAC,			;YES, FLAG AS SUCH
	XCTR	XW,[MOVEM TAC,HINAME]	;SAVE IN THIS NEW PLACE!
	JRST	SAVJ3

SAVJ1:	XCTR	XW,[SETZM HILOC]
	XCTR	XW,[SETZM JOBRL2]
	XCTR	XW,[SETZM HINAME]
	XCTR	XW,[SETZM NEWCOR]	;MAKE SURE NO SAVE HAPPENS!
SAVJ3:	XCTR	XW,[SETZM DMPEND]
	XCTR	XR,[HLRO TAC,FILLEN]
	SUBI	TAC,JOBSAV
	HRLZ	TAC1,JBTPAG(J)
	LSH	TAC1,=9
	ADDI	TAC,-1(TAC1)
	JUMPL	TAC,NOROOM
	XCTR	XR,[HLRO TAC,FILLEN]
	MOVNS	TAC
	ADDI	TAC,JOBSAV
	XCTR	XW,[MOVEM TAC,JOBCOR]	;MAKE SURE HE GETS TO BE RIGHT SIZE WHEN HE COMES BACK IN
	OUTPUT	0,FILLEN
	TRNE	IOS,IOBKTL!IODERR!IODTER!IOIMPM
	JRST	SGTERA			;TRANSMISSION ERROR
	XCTR	XR,[SKIPN NEWCOR]	;ANY UPPER TO WRITE?
	JRST	SGREL			;NO.
	XCTR	XW,[SETZM NEWCOR+1]
	OUTPUT	0,NEWCOR
	LDB	TAC,PSEGN
	JUMPE	TAC,SAVJ2
	HLRZ	TAC1,JBTPAG(TAC)
	LSH	TAC1,=9		
	SUBI	TAC1,1			;PROTECTION SIZE OF SEGMENT
	TRO	TAC1,400000
	XCTR	XW,[MOVEM TAC1,HILOC]
	XCTR	XW,[MOVEM TAC1,JOBRL2]
SAVJ2:	TRNN	IOS,IOBKTL!IODERR!IODTER!IOIMPM
	JRST	SGREL
SGTERA:	PUSHJ	P,SGREL
SGTERR:	JSP	TAC,PHOLD		;PRINT ERROR MESSAGE AND STOP JOB
	ASCIZ	\? SAVE/GET IO error\


SAV4:	PUSHJ	P,SGREL		;RELEASE,DEVICE, FIND TTY
	JSP	TAC,PHOLD	;PRINT MESSAGE AND STOP JOB
	ASCIZ	/? Enter failed/
BEGIN SEGCSS ↔ SUBTTL	SEGCSS	8 SEPT 69	JAM; ACCESS
; SEGMENT ACCESS CONTROL
; PUT JOB NUMBER OF MASTER ON STACK AND NUMBER OF SEGMENT IN J
; CALLING . . .
;	PUSH P,J		;MASTER JOB NUMBER
;	MOVE J,<SEGMENT NUMBER>
;	PUSHJ P,ACCESS
;	<NO ACCESS POSSIBLE>
;	<READ ACCESS ONLY>
;	<ALL ACCESS LEGAL>

↑ACCESS:MOVE TAC,-1(P)		; PICK UP MASTER JOB NUMBER
	MOVE TAC1,JBTPRV(TAC)	; GET PRIV BITS OF MASTER
	TLNE TAC1,SEGPRV	; DO WE HAVE THE PRIVILEGE?
	JRST CPOPJ2		; YES, AUTOMATIC SUCCESS
	MOVE TAC1,PRJPRG(TAC)
	LDB TAC,[POINT 9,JOBCRD(J),8]
	TRZE TAC,400		;UNPURIFIED?
	JRST ACCES2		;YES - DIFFERENT TEST (TAC IS NOW JOB # OF DEFILER)
	CAMN TAC1,JOBPPN(J)	; IS THIS THE SAME JOB?
	JRST ACCES1		; YES, USE OWNER'S PROTECTION
	MOVE TAC1,JBTPRV(TAC)	;BH 10/23/74 CHANGING PROTECTION CODE MEANING
	TLNN TAC1,LUPPRV	;BH TO OWNER-LOCAL-GUEST
	LSH TAC,3		; SHIFT TO GUEST PROTECTION
	LSH TAC,3		; MOVE OVER TO LOCAL PROTECTION
ACCES1:	TRNN TAC,300		; NOW, IS THERE ANY PROTECTION?
	JRST CPOPJ2		; NO, EVERYTHING GOES
	TRNN TAC,200		; IS IT READ PROTECTED?
	AOS (P)			; NO, IT CAN BE READ
	POPJ P,			; OTHERWISE INACCESSABLE

ACCES2:	CAMN TAC,-1(P)		;ONLY ORIGINAL OWNER WINS HERE
	JRST CPOPJ2
	POPJ P,
;ESTSEG

; ROUTINE TO INVENT AN UPPER SEGMENT
; SKIP RETURNS WITH JOB NUMBER OF SEGMENT IN J; NON SKIP IF JOB CAPACITY EXCEEDED
; SETS CORE SIZE TO ZERO, SETS PPN TO *SEG*, SETS AS DETATCHED

↑ESTSEG:MOVEI	J,1
	MOVSI	TAC,JNA!CMWB		;BITS WHICH MUST BE OFF IN A FREE SLOT
ESTSE1:	TDNN	TAC,JBTSTS(J)		;SKIP IF JOB SLOT IN USE.
	JRST	ESTSE2			;WE HAVE A SLOT TO USE.
	CAMGE	J,JOBNM1		;HAVE WE SEEN ALL SLOTS?
	AOJA	J,ESTSE1		;NOT YET.
	MOVEI	J,0			;RETURN A ZERO
	POPJ	P,			;FAILURE.

ESTSE2:	SKIPE	JBTPAG(J)		;BUG TRAP
	PUSHJ	P,INIJXX		;MAKE LOSE MESSAGE
	SETZM	JBTPAG(J)
	MOVSI	TAC,JSEG!JNA!JLOG	;SET SEGMENT, SLOT USED, LOGGED IN
	IORM	TAC,JBTSTS(J)		;IN JOB STATUS FOR SEGMENT
	SETZM	NJOBS(J)		;NO ONE USING THIS UPPER YET
	SETOM	JBTLIN(J)		;DETACHED
	SETZM	TTIME(J)		;NO RUN TIME FOR THIS UPPER
	SETZM	RTIME(J)
	SETZM	XTIME(J)		;NO XTIME
	SETZM	DSKOPS(J)		;NO DISK OPS

IFKL10,<SETZM	JBTCSH(J)		;NOT IN THE CACHE YET >;IFKL10

	MOVE	TAC,TIMDAT
	MOVEM	TAC,FTIME(J)		;SET UP JOB LAST RUN TIME.
	MOVE	TAC,[SIXBIT /*SEG*/]	;PPN = *SEG*
	MOVEM	TAC,PRJPRG(J)
	MOVEI	TAC,STOPQ		;QUEUE US INTO THE STOPQ
	MOVNM	TAC,JOBQUE(J)
	AOS	(P)			;SETUP SKIP RETURN
	JRST	REQUE
;LINKSEG, MAKESEG, SEGFIN

;THIS ROUTINE DEFINES A SEGMENT. IT SEARCHES FOR AN EXISTING
; SEGMENT FIRST WITH THE PROPER CREDENTIALS AND GIVES YOU ITS NUMBER FIRST.
; OTHERWISE, IT MAKES ONE UP AND PUTS YOUR ID IN ITS CREDENTIALS. RETURNS
; THE NUMBER OF THE SEGMENT IN JBTSTS, 0 FOR FAILURE.

↑LINKSEG:
	PUSHJ P,KILSEG		;GET RID OF EXISTING UPPER.
	PUSH P,J
	MOVE AC1,J		; SAVE NUMBER OF MASTER JOB
	MOVE J,JOBNM1
DEFSE1:	MOVE TAC,JBTSTS(J)	;LOOK FOR AN UPPER.
	TLNN TAC,JSEG
	JRST DEFSE2		;NOT AN UPPER. SKIP IT.
	MOVE TAC,JOBNAM(J)
	MOVE TAC1,JOBPPN(J)
	CAMN TAC,JOBNAM(AC1)	;DOES THE JOB NAME MATCH?
	CAME TAC1,JOBPPN(AC1)	;AND DOES THE PPN MATCH?
	JRST DEFSE2		; NO
	MOVE TAC,JOBCRD(J)
	MOVE TAC1,JOBDEV(J)
	CAMN TAC,JOBCRD(AC1)	;DOES THE CREATION DATE AND PROTECTION MATCH?
	CAME TAC1,JOBDEV(AC1)	;AND DOES THE DEVICE MATCH?
	JRST DEFSE2		;NO
	MOVE TAC,JOBLOG(J)	;CHECK LOGICAL NAME TOO
	CAMN TAC,JOBLOG(AC1)
	PUSHJ P,ACCESS		;NOW, CAN WE LEGALLY ACCESS THIS SEGMENT?
	JRST DEFSE2		;NO
	JFCL

IFN FTPAGER,<	MOVE	TAC,(P)		;GET OUR JOB NUMBER IN TAC
		PUSHJ	P,ASGMAP	;ADD SEGMENT TO THE PAGE MAP >;FTPAGER

DEFSE3:	MOVE TAC,J		;JOB NUMBER OF THE SEGMENT
	POP P,J			;GET BACK OUR OWN JOB NUMBER
	DPB TAC,PSEGN		;MAKE IT OUR UPPER

IFN FTSTAT,<	PUSHJ	P,SEGSTT
		LDB	TAC,PSEGN	>;IFN FTSTAT

	JUMPE TAC,SEGFIN	;(MAKESEG GOES TO DEFSE3 WITH J 0)
	AOS NJOBS(TAC)		;BUMP COUNT OF NUMBER OF PEOPLE POINTING TO HIM
	AOS (P)
SEGFIN:	CAME	J,JOB(PID)
	POPJ	P,

IFE FTPAGER,<	PUSHJ	P,GETPR
		DATAO APR,TAC 		>;NOT FTPAGER

IFN FTPAGER,<
NOKL10,<	CONO	PAG,3		>;NOKL10
IFKL10,<	CONO	KLPAG,@KLPCON	>;IFKL10
					>;FTPAGER - FLUSH ALL USER ARS.

	POPJ	P,

DEFSE2:	SOJG	J,DEFSE1
	POP	P,J
	POPJ	P,

↑MAKESEG:
	PUSHJ P,KILSEG
	PUSH P,J
	PUSHJ P,ESTSEG		;IF NO EXISTING ONE, MAKE ONE UP
	JRST DEFSE3		;IF NOT AVAILABLE, JUST LEAVE
	MOVE TAC,J		;SAVE SEGMENT NUMBER
	POP P,J
	DPB TAC,PSEGN
IFN FTSTAT,<
	PUSHJ P,SEGSTT
	LDB TAC,PSEGN
>;FTSTAT
↑MAKSE2:AOS NJOBS(TAC)		;BUMP # PEOPLE POINTING TO HIM (CALLED FROM UNPURE)
	MOVE TAC1,JOBNAM(J)	; NOW ESTABLISH ITS CREDENTIALS
	MOVEM TAC1,JOBNAM(TAC)
IFN FTSTAT,<
	PUSH P,J
	MOVE J,TAC
	PUSHJ P,NAMSTT
	POP P,J
>;FTSTAT
	MOVE TAC1,JOBPPN(J)
	MOVEM TAC1,JOBPPN(TAC)
	MOVE TAC1,JOBCRD(J)
	MOVEM TAC1,JOBCRD(TAC)
	MOVE TAC1,JOBDEV(J)
	MOVEM TAC1,JOBDEV(TAC)
	MOVE TAC1,JOBLOG(J)
	MOVEM TAC1,JOBLOG(TAC)
	POPJ P,
;KILSEG  ROUTINE TO KILL A HIGH SEGMENT
; ENTER WITH JOB NUMBER OF OWNER IN J
; IF OTHER PEOPLE POINT TO IT, IT WILL REMAIN
; IF NO-ONE ELSE POINTS TO IT, IT WILL GO AWAY

↑↑KILSEG:
IFE FTPAGER,<
	SKIPE JBTPR2(J)			;IS HE DOING PEEK-POKE?
	JRST [	SETZM JBTPR2(J)		;YES, MUST KILL IT HERE
		JRST SEGFIN]
>;NOT FTPAGER
IFN FTPAGER,<
	PUSHJ P,ZERPR2			;ZERO PAGE MAP ENTRIES IF THERE'S A JBTPR2
	JRST SEGFIN			;THERE WAS A JBTPR2 AND IT'S NOW ZERO
>;FTPAGER
	MOVE TAC,J			;SAVE JOB NUMBER
	LDB J,PSEGN			;GET OUR SEGMENT NUMBER
	JUMPN J,KILSE6			;JUMP IF THERE IS A SEGMENT
	MOVE J,TAC			;THERE'S NO SEGMENT. FORGET IT
	POPJ P,

KILSE6:	PUSH P,TAC			;SAVE JOB NUMBER ON THE STACK

IFN FTPAGER,<	PUSHJ P,ZSGMAP	>	;FLUSH THE SEGMENT FROM LOWER'S PAGE MAP

	PUSH P,J			;SAVE SEGMENT NUMBER.
	SKIPA J,JOBNM1			;SEARCH FOR ANY OTHERS POINTING HERE
KILSE3:	SOJLE J,KILSE1			;DECREMENT J. JUMP IF JOB LIST EXHAUSTED
	CAMN J,-1(P)			;IS THIS THE CURRENT JOB?
	JRST KILSE3			;YES. WE KNOW ABOUT HIM, SO SKIP IT.
	LDB TAC,PSEGN
	CAMN TAC,(P)			;DOES HE POINT TO OUR SEGMENT?
	JRST KILSE4			;YES. - DON'T KILL SEGMENT.
KILSE7:	SKIPN AC1,JBTDTS(J)		;DOES THIS GUY HAVE A DETACHED SEGMENT LIST?
	JRST KILSE3			;NO.
KILSE5:	LDB TAC,PDSEGN			;LOOK THRU DET SEG LIST
	JUMPE TAC,KILSE3		;JUMP WHEN DET SEG LIST IS EMPTY
	CAME TAC,(P)			;SAME AS THIS SEGMENT?
	AOJA AC1,KILSE5			;NO. KEEP LOOKING.
KILSE4:	POP P,J				;SOMEONE ELSE POINTS TO THIS SEGMENT
KILSE2:	SOSGE	NJOBS(J)
	PUSHJ	P,KILSE9		;MAKE LOSE MESSAGE.
	POP	P,J			;POP CURRENT JOB NUMBER
	MOVEI	TAC,0
	DPB	TAC,PSEGN		;ZERO SEGMENT FIELD
IFN FTSTAT,<
	PUSHJ P,SEGSTT
	LDB TAC,PSEGN
>;FTSTAT
	JRST SEGFIN

;HERE IF THERE ARE NO FURTHER REFERENCES TO THIS SEGMENT.
KILSE1:	POP P,J				;GET THE SEGMENT NUMBER
	PUSHJ P,ZEROSEG			;EXPUNGE SEGMENT
	MOVE TAC,NJOBS(J)
	CAIE TAC,1			;THERE SHOULD BE ONLY 1 POINTER TO THIS
	PUSHJ P,NZERR
	JRST KILSE2

NZERR:	PUSHACS
	PUSHJ P,DISMES
	ASCIZ /NJOBS NOT 0 AT KILSE1
/
	POPACS
	POPJ P,


KILSE9:	PUSHACS
	PUSHJ P,DISMES
	ASCIZ /NJOBS NEGATIVE AT KILSE2
/
	POPACS
	SETZM NJOBS(J)
	POPJ P,
;ZEROSEG - ROUTINE TO ERASE A SEGMENT ENTIRELY, SEGMENT'S JOB NUMBER IN J

ZERO5:	PUSHJ P,WSCHED			;WAIT FOR SPW TO STOP.
ZEROSEG:MOVEI TAC,0			;NEW SIZE DESIRED = 0
	PUSHJ P,CORE0			;GIVE BACK THIS SEGMENT'S CORE
	JRST ZERO5			;I/O OR SPACEWAR STILL ACTIVE
	PUSHJ P,UAPPLY			;CONTINUE SPACWAR FOR LOWERS
	 PUSHJ P,SPWCNT
	MOVSI TAC,JSEG!JWP!JNA!JLOG!JACCT!RUN
	ANDCAM TAC,JBTSTS(J)
	SETZM JOBNAM(J)
	SETZM PRJPRG(J)
	JRST NOCORQ			;REQUE TO NULQ. ZERO JBTMAP, JBTSWP
					;FLUSH FASTBANDS
;FLUSHSEG

; ROUTINE TO FLUSH A JOB'S HIGH SEGMENT AND ALL THE SEGMENTS HE MAY HAVE
; PREVIOUSLY DETACHED, IF AND ONLY IF NO ONE ELSE IS POINTING AT THEM.
; CALL FROM UUO OR CLOCK LEVEL ONLY!!!!!!

↑↑FLUSHSEG:
	PUSHJ P,KILSEG			;KILL HIS IMMEDIATE UPPER
	SKIPN AC1,JBTDTS(J)		;IS THERE A DET SEG LIST?
	POPJ P,				;NO. THIS IS EASY.
	PUSH P,J			;SAVE CALLING JOB'S NUMBER
FLUSH1:	SKIPN J,(AC1)			;GET THE NUMBER OF THE DETACHED SEGMENT
	JRST FLUSH2			;JUMP IF THERE ARE NO MORE.
	JUMPL J,FLUSH6			;JUMP IF THIS IS SPECIAL DETACHED.
	MOVE TAC1,JOBNM1
	ANDI J,77			;SEGMENT NUMBER ONLY.
FLUSH3:	LDB TEM,[POINT 6,JBTSTS(TAC1),35]	;DO OTHERS POINT HERE?
	CAMN TEM,J			;DIRECT MATCH?
FLUSH6:	AOJA AC1,FLUSH1			;YES. CAN'T BE FLUSHED.
	CAME TAC1,(P)			;DON'T MATCH AGAINST OUR OWN JOB
	SKIPN DAT,JBTDTS(TAC1)		;DOES THIS JOB HAVE A DETACH LIST?
	JRST FLUSH5			;NO, GO TO NEXT JOB
FLUSH4:	LDB TEM,[POINT 6,(DAT),35]	;YES, PICK UP ITS SEGMENT NUMBER
	JUMPE TEM,FLUSH5		;JUMP IF END OF LIST
	CAMN TEM,J			;DOES HE POINT TO US?
	AOJA AC1,FLUSH1			;YES, CAN'T ZERO THIS SEGMENT
	AOJA DAT,FLUSH4			;NO, TRY NEXT DETACHED SEGMENT

FLUSH5:	SOJG TAC1,FLUSH3		;LOOP AROUND FOR NEXT JOB
	MOVE TAC,JBTSTS(J)		;NOW, DOES THIS SEGMENT STILL EXIST?
	TLNN TAC,JNA
	AOJA AC1,FLUSH1			;NO, DON'T BOTHER
	PUSH P,AC1
	PUSHJ P,ZEROSEG			;WIPE OUT THAT SEGMENT, NO OTHER REFS TO IT
	SKIPE NJOBS(J)
	PUSHJ P,NZERR
	POP P,AC1
	AOJA AC1,FLUSH1

FLUSH2:	POP P,J				;GET OUR JOB NUMBER BACK
	MOVE AC1,JBTDTS(J)		;SEARCH FOR SPECIAL DET SEG.
	MOVEI AC2,(AC1)			;AC1 POINTS AT HOLE. AC2 POINTS AT DATUM
FLUSH7:	SKIPLE TAC,(AC2)		;SKIP IF SPECIAL OR EMPTY
FLUSH8:	AOJA AC2,FLUSH7			;NORMAL DET SEG. GET NEW DATUM
	MOVEM TAC,(AC1)			;DATUM IS BUBBLED DOWN.
	JUMPE TAC,FLUSH9		;JUMP IF DONE.
	AOJA AC1,FLUSH8			;ADVANCE HOLE, ADVANCE DATUM.

FLUSH9:	CAME AC1,JBTDTS(J)		;IS HOLE IS STILL IN THE SAME PLACE?
	POPJ P,				;NO. WE STILL HAVE A DET SEG LIST.
	PUSHJ P,FSGIVE
	SETZM JBTDTS(J)
	POPJ P,

↑↑DSFLUSH:				;MAKE SPECIAL DET SEG INTO ORDINARY.
	SKIPN AC1,JBTDTS(J)
	POPJ P,
DSFL1:	MOVSI TAC,400000
	ANDCAB TAC,(AC1)
	JUMPE TAC,CPOPJ
	AOJA AC1,DSFL1
; UAPPLY - APPLY A ROUTINE TO ALL LOWERS OF AN UPPER.
;CALL:
;	MOVE J,<UPPER'S NUMBER>
;	PUSHJ P,UAPPLY
;	<INSTRUCTION TO XCT>	;J HAS LOWER'S NUMBER, DDB HAS UPPER'S NUMBER
;	RETURN HERE
;NO AC'S ARE CLOBBERED EXCEPT BY THE XCT'ED INSTRUCTION.
;DDB AND J SHOULD NOT BE USED TO RETURN ARGUMENTS, ETC.
;IF THE XCT'ED INSTRUCTION SKIPS, THE SCAN TERMINATES IMMEDIATELY

↑↑UAPPLY:	
	PUSH P,DDB
	PUSH P,J
	MOVEI J,JOBN-1
UAPP1:	LDB DDB,PSEGN		;GET NUMBER OF THIS LOWER'S UPPER
	CAMN DDB,(P)
	JRST UAPP3		;MATCHES.
UAPP2:	SOJG J,UAPP1
	POP P,J
	POP P,DDB
	JRST CPOPJ1

UAPP3:	PUSH P,J
	XCT @-3(P)		;J = JOB NUMBER OF LOWER, DDB = JOB NUMBER OF UPPER.
	JRST .+2
	SETZM (P)		;IF INSTR. SKIPS, STOP THIS PROCESS!
	POP P,J
	JRST UAPP2

BEND SEGCSS
SUBTTL	COMCSS		;CTEXT, CTEXT1, GETLCCHR, CTEX, CTEXA, CTXCNC

LOSYS

;RETURN NEXT ALPHANUMERIC STRING IN COMMAND LINE (SIXBIT)
;CALL:	MOVE TAC,BYTE POINTER TO PREVIOUS CHAR.
;	PUSHJ	P,CTEXT
;SIXBIT STRING RETURNED LEFT JUSTIFIED IN TAC1


↑CTEXT:	PUSHJ	P,SKIPS		;SKIP LEADING SPACES, TABS, NULLS, AND CLEAR TAC1
	CAIA
↑CTEXT1:PUSHJ	P,SKIPS1	;DO NOT RETURN IF CR WAS PREVIOUS BREAK
	MOVE	UCHN,[POINT 6,TAC1]
	LDB	TEM,TAKR(DAT)
	ANDI	TEM,177
	PUSHJ	P,GETLC1	;CONVERT TO UPPERCASE.
CTEX1:	PUSHJ	P,CTEX		;IS IT ALPHANUMERIC
	TRC	TEM,40		;CONVERT TO SIXBIT
	TLNE	UCHN,770000	;HAVE WE ACCUMULATED 6 CHARS?
	IDPB	TEM,UCHN	;NOT YET.  STORE AWAY
	PUSHJ	P,GETLCCHR	;GET UPPERCASE CHARACTER
	JRST	CTEX1

;SCAN FOR ALPHANUMERIC CHAR IN TEM
CTEX:	CAIL	TEM,"0"
	CAILE	TEM,"Z"		;LETTERS ARE LARGER THAN NOS.
	JRST	CTEXA		;NEITHER
	CAILE	TEM,"9"
	CAIL	TEM,"A"
	POPJ	P,		;LETTER OR NUMBER RETURN
CTEXA:	CAIN	TEM,":"		;DEVICE NAME?
	PUSHJ	P,GETLCCHR	;YES, SKIP COLON
	CAIE	TEM,0		;↑C?
	JRST	TPOPJ		;NO, RETURN UP ONE LEVEL
CTXCNC:	MOVSI	TAC1,'HAL'	;CUE UP A PHONY 'HALT'
	MOVEI	TEM,12		;TERMINATE WITH LINE FEED
	DPB	TEM,TAKR(DAT)	;STORE IN INPUT BUFFER DO ↑C NOT SEEN
	JRST	TPOPJ		;AND RETURN UP A LEVEL


↑GETLCCHR:			;GET NEXT CHARACTER - MAKE IT UPPER CASE.
	PUSHJ	P,GETCHR
GETLC1:	CAIG	TEM,"Z"+40
	CAIGE	TEM,"A"+40
	POPJ	P,
	SUBI	TEM,40
	POPJ	P,
;SKIPSJ, SKIPS, SKIPS1, SKIPSA, SKIPSB, CRLF, CONMES, TYO

;IGNORE LEADING SPACES, TABS, AND NULLS.  CLEARS TAC1.
;DOES NOT RETURN IF PREVIOUS CHAR. OR NEXT NON-SPACING
;CHAR. IS CR (I.E., POPS SUBROUTINE LEVEL UP 1 ON RETURN)
;CALL:	MOVE	TAC,<BYTE POINTER TO PREVIOUS BREAK CHAR.>
;	PUSHJ	P,SKIPS1


SKIPSJ:	PUSHJ	P,SKIPS1	;BEWARE OF UPLEVEL RETURN
	POPJ	P,

SKIPS:	PUSHJ	P,GETLCCHR	;GET FIRST CHAR ON LINE
SKIPS1:	MOVEI	TAC1,0		;FOR CTEXT AND DECIN
	LDB	TEM,TAKR(DAT)	;IN CASE TEM IS CLOBBERED
	ANDI	TEM,177
	CAIE	TEM,"."		;IF A PERIOD, GET NEXT CHARACTER
	CAIN	TEM,15		;SKIP TO LF IF CR.
SKIPSA:	PUSHJ	P,GETLCCHR	;GET NEXT CHARACTER
SKIPSB:	JUMPE	TEM,SKIPS3	;LEAVE IF NO MORE CHARS
	CAIN	TEM,";"		;STOP HIM AT SEMI-COLON
	JRST	SKIPS3		;MAKE IT LOOK LIKE END OF LINE
	PUSHJ	P,SPCHEK	;IS THIS A SPECIAL CHAR?
	JRST	SKIPS2		;NO
	TLNE	TAC,BREAKB	;BREAK? END OF LINE?
	JRST	SKIPS3		;YES, LEAVE
SKIPS2:	CAIG	TEM,40		;SPACE OR CONTROL CHAR?
	JRST	SKIPSA		;YES
	POPJ	P,		;NO, RETURN

SKIPS3:	JUMPE	TEM,CTXCNC	;↑C?
	MOVEI	TEM,12		;WE USE LINE FEEDS FOR BREAK CHARS
	JRST	TPOPJ		;RETURN UP ONE LEVEL



;ROUTINE TO MOVE ASCIZ STRING TO USER'S TERMINAL OUTPUT BUFFER
;CALL:	MOVE	DAT,BYTE POINTER TO LAST OUTPUT CHARACTER
;	MOVEI	TAC,<ADDRESS OF ASCIZ MESSAGE>
;	PUSHJ	P,CONMES 	;DOESN'T START TTY

;CALL:	MOVE	DAT,BYTE POINTER TO OUTPUT
;	PUSHJ	P,CRLF		;DOESN'T START TTY.

↑CRLF:	MOVEI	TAC,[BYTE (7) 15,12,0]
↑CONMES:HRLI	TAC,440700		;FORM ASCIZ BYTE POINTER
	PUSH	P,TAC			;SAVE BYTE POINTER
CON0:	ILDB	TEM,(P)			;GET NEXT CHAR.
	JUMPE	TEM,TPOPJ		;IF NULL, RETURN UPLEVEL
↑TYO:
↑CONTYO:PUSHJ	P,OUTCHS		;***PATCHED BY ONCE
	JRST	CON0			;KEEP GOING
;COMEND, COMERP, COMERA, COMERR, ERRMES

;APPEND A "?" TO INPUT STRING AND SET AS OUTPUT.
;CALLED FROM OCTIN, RETURNS TO SECOND LEVEL ON PDL
;CALL:	MOVE TAC, BYTE POINTER TO LAST CHAR. IN INPUT STRING
;	PUSHJ	P,COMERA


↑COMEND:PUSHJ	P,SKIPS1	;IF ANYTHING LEFT IN INPUT LINE, FALL INTO COMERA
↑COMERP:POP	P,UCHN		;REMOVE SUBROUTINE RETURN BEFORE CALLING COMERA
↑COMERA:PUSHJ	P,GETCHR


;REPLACE LAST CHARACTER IN INPUT STRING BY "?" AND SET AS OUTPUT.
;CALL:	MOVE	TAC,<BYTE POINTER TO LAST CHAR. IN INPUT STRING>
;	PUSHJ	P,COMERR

↑COMERR:MOVE	UCHN,TITCTR(DDB)	;SAVE POSITION IN SCAN
	PUSHJ	P,TRESCN		;BACK UP TO START OF COMMAND
COMERL:	PUSHJ	P,GETCHR		;GET A CHARACTER FROM COMMAND LINE
	JUMPE	TEM,COMER1		;QUIT ON NULL HERE!
	CAIE	TEM,15			;QUIT AT CR
	CAMN	UCHN,TITCTR(DDB)	;HAVE WE PASSED A BAD CHAR YET?
	JRST	COMER1			;YES
	PUSHJ	P,OUTCHS		;NO, TYPE CHARACTER
	JRST	COMERL			;AND LOOP FOR ANOTHER

COMER1:	PUSHJ	P,SETBFI		;CLEAR ANY MORE TYPE IN
	MOVEI	TEM,"?"			;APPEND ? TO ERRONEOUS WORD
	PUSHJ	P,OUTCHS		;AND PRINT IT
	MOVSI	J,NOJOBN!NOINCK		;NOW WE PAINSTAKINGLY FAKE OUT COMRET
	IORM	J,-1(P)			;*** IF YOU CALL COMERR FROM ANYPLACE THAT
	MOVSI	J,NOPER!NOCRLF		;*** DOESN'T HAVE COMRET NEXT ON THE PDL
	ANDCAM	J,-1(P)			;*** BOY ARE YOU IN BAD TROUBLE!
	MOVEI	J,0			;CLEAR JOB NUMBER
	JRST	CRLF

↑ERRMES:MOVEI	J,0			;CLEAR JOB NUMBER TO INDICATE ERROR
	JRST	CONMES

;INLMES, PRCRCC, PRCNCC, PRQM

;PRINT INLINE ASCIZ MESSAGE
;CALL:	PUSHJ	P,INLMES
;	ASCIZ	/THE MESSAGE/
;RETURN TO NEXT LOC AFTER MESSAGE


↑INLMES:POP	P,TAC			;SETUP PRINT ADDRESS FOR CONMES
	PUSHJ	P,CONMES
	JRST	1(TAC)			;RETURN TO NEXT LOC AFTER MESSAGE

;TYPE "? " FOR ERROR MESSAGE
;CALL	PUSHJ	P,PRQM
;	RETURN

↑PRQM:	MOVEI	TEM,"?"
	XCT	TYO
	MOVEI	TEM," "
	XCT	TYO
	POPJ	P,

PRSPC:	MOVEI	TAC,[ASCIZ /    /]	;PRINT 4 SPACES.
	JRST	CONMES


;PRINT "TOO FEW ARGUMENTS"
;CALL:	MOVE	DAT,<OUTPUT BYTE POINTER>
;	PUSHJ	P,NOTENF

↑NOTENF:JSP	TAC,ERRMES
	ASCIZ	/Too few arguments
/

;ROUTINE TO PRINT A PERIOD
;CALL:	PUSHJ	P,PRPER


↑PRCRCC:PUSHJ	P,CRLF
↑PRCNTC:PUSHJ	P,INLMES
	ASCIZ	/↑C
/
↑PRPER:	MOVEI	TEM,"."
	JRST	OUTCHS
;DEASG, DEASTY

;ROUTINE TO DEASSIGN A DEVICE
;CALL:	MOVE DDB,DEVICE DATA BLOCK
;	MOVE J,JOB NUMBER
;	PUSHJ P,DEASG
;	<NOT PREVIOUSLY ASSIGNED BY CONSOLE>
;	<RETURN WITH DEVICE DEASSIGNED>

↑DEASG:	LDB	UCHN,PJOBN	;WAS DEVICE ASSIGNED TO THIS JOB?
	CAME	UCHN,J
	POPJ	P,		;NO, RETURN
	PUSH	P,J		;SAVE JOB NUMBER
	MOVSI	UCHN,DVDIRIN	;CLEAR DIRECTORY IN CORE BIT
	ANDCAM	UCHN,DEVMOD(DDB)
	SETZM	DEVLOG(DDB)	;CLEAR LOGICAL NAME
	MOVEI	TAC1,ASSCON	;IS DEVICE ASSIGNED BY CONSOLE?
	TDNE	TAC1,DEVMOD(DDB)
	AOS	-1(P)		;ASSIGNED BY CONSOLE.  DO OK RETURN
	PUSHJ	P,RELEA6	;CLEAR JOB NO. IN DDB IF DDB NOT NEEDED
	POP	P,J		;BY THIS JOB ANY MORE
	POPJ	P,

;ROUTINE TO DEASSIGN ALL DEVICES EXCEPT LOGICAL TTY
;CALL:	MOVE	J,<JOB NUMBER>
;	MOVE	DDB,<ADR. OF DEVICE NOT TO BE DEASSIGNED>
;	PUSHJ	P,DEASTY


↑DEASTY:
	ANDI	DDB,-1		;CLEAN OUT THE LH SHIT
	PUSH	P,DDB		;SAVE DDB ADDRESS
	HLRZ	DDB,DEVLST	;SEARCH ALL DDB'S
DEA1:	CAME	DDB,(P)		;IS THIS DEVICE NOT TO BE DEASSIGNED?
	PUSHJ	P,DEASG		;NO, TRY TO DEASSIGN IT
	JFCL			;IGNORE IF CAN'T
	HLRZ	DDB,DEVSER(DDB)
	JUMPN	DDB,DEA1
	POP	P,DDB		;RESTORE TTY DDB ADDRESS
	POPJ	P,
;DECIN, OCTIN, ANYRIN

;READ CONSOLE AND CONVERT ANY RADIX NUMBER
;CALL:	MOVE	DSER,<DESIRED RADIX>
;	PUSHJ	P,ANYRIN
;	<NO ARG. TYPED RETURN, TAC1=0>
;	<ILLEGAL CHARACTER RETURN>
;	<NORMAL EXIT>		;TAC1 RETURNS NUMBER
;
;SCAN STOPS ON FIRST CR,HYPHEN,SPACE,TAB OR ILLEGAL CHAR.
;IF IT IS ILLEGAL CHAR.,SUBROUT. LEVEL IS POPED AND COMERA IS CALLED
;WHICH PRINTS MONITOR COMMAND ERROR. THUS CALLER NEVER SEES RETURN
;SKIPS LEADING SPACES AND TABS



↑DECIN1:
↑DECIN:	MOVEI	DSER,=10	;DECIMAL INPUT
	JRST	ANYRIN

↑OCTINS:PUSHJ	P,GETLCCHR	;SKIP PRECEEDING + OR -
↑OCTIN:	MOVEI	DSER,10		;OCTAL INPUT
ANYRIN:	PUSHJ	P,SKIPS1	;SKIP LEADING SPACES, TABS, NULLS
				;DO NOT RETURN IF CR WAS PREVIOUS BREAK
				;OR THIS BREAK
OCT0:	CAIE	TEM,12		;LF IS A DELIMITER TOO
	CAIL	TEM,175		;ALT MODE?
	JRST	CPOPJ2
	CAIE	TEM,";"		;SEMICOLON?
	CAIN	TEM," "		;SPACE?
	JRST	CPOPJ2		;YES, SKIP RETURN
	CAIE	TEM,"-"		;NO, DASH?
	CAIN	TEM,15		;CR?
	JRST	CPOPJ2		;YES
	CAIE	TEM,","		;COMMA?
	CAIN	TEM,"["		;LEFT BRACKET?
	JRST	CPOPJ2		;YES.
	SUBI	TEM,60
	JUMPL	TEM,CPOPJ1	;ERROR IF NEG.  GIVE THE 1 SKIP RETURN.
	CAIL	TEM,(DSER)	;OR .GE. RADIX
	JRST	CPOPJ1		;ERROR, GREATER OR EQUAL TO RADIX
	IMULI	TAC1,(DSER)
	ADD	TAC1,TEM
↑CONTYI:PUSHJ	P,GETCHR	;***PATCHED BY ONCE.
	JRST	OCT0
;PJPGNO - GET PROJECT-PROGRAMMER NUMBERS
;CALL:	MOVE	TAC,<INPUT BYTE POINTER>
;	PUSHJ	P,PJPGNO
;	<ERROR RETURN>
;	OK RETURN
;
;(AC2)LH ← PROJECT NUMBER
;(AC2)RH ← PROGRAMMER NUMBER

PJPGNO:	PUSHJ	P,SKIPS1	;SKIP LEADING BLANKS.
	CAIE	TEM,"["		;IS THERE A [?
	POPJ	P,		;NO. NO PPN.
	PUSHJ	P,PJPG1		;READ PROJ. "NUMBER".
	HLL	AC2,TAC1
	CAIE	TEM,","		;SHOULD BE FOLLOWED BY A COMMA.
	JRST	PJPG2
	PUSHJ	P,PJPG1		;NOW PROG. NO.
	HLR	AC2,TAC1
	CAIN	TEM,"]"		;] IS OPTIONAL.
	PUSHJ	P,GETLCCHR	;THROW IT AWAY IF PRESENT.
	JRST	CPOPJ1

PJPG1:	PUSHJ	P,CTEXT		;SCAN NEXT THING.
	JUMPE	TAC1,TPOPJ	;RETURN UPLEVEL IF NOTHING.
	TLNN	TAC1,7777
	LSH	TAC1,-14	;JUSTIFY NOW IN CASE SKIPSB DOESN'T COME BACK
	TLNN	TAC1,77
	LSH	TAC1,-6
	PUSHJ	P,SKIPSB	;MAKE SURE WE SEE TERMINATOR.
	POPJ	P,		;PROGRAM BUMMERS BEWARE OF UPLEVEL RETURN!

PJPG2:	CAIE	TEM,12		;TERMINATED BY LF?
	POPJ	P,		;NO.  THEN WASN'T A GOOD PPN
	SKIPN	TAC1,DSKPPN(J)	;COPY PRG FROM APPROPRIATE PLACE
	MOVE	TAC1,PRJPRG(J)
	HRR	AC2,TAC1
	JRST	CPOPJ1
SUBTTL	ERRCON	4 AUG 67		;APRILM, UERROR, CERROR, ADRTST

;THESE ERROR ROUTINE PRINT "ERROR IN JOB N"
;FOLLOWED BY AN APPROPRIATE ERROR MESSAGE
;THEN THE JOB IS STOPPED AND CONSOLE IS RETURNED TO
;MONITOR COMMAND MODE

;ADRTST - SKIP IF TAC CONTAINS A LEGAL ADDRESS.
;NEEDS J, PID SETUP. CLOBBERS TAC1.
ADRTST:	MOVEI	TAC1,(J)
	PUSHJ	P,CORSGT	;TAC1←CORE SIZE OF LOWER
	CAMGE	TAC,TAC1	;SKIP IF PC OUTSIDE OF LOWER
	JRST	CPOPJ1		;PC IN BOUNDS.
	JUMPN	PID,CPOPJ	;NO SEGMENTS ON P2.
	TRNN	TAC,400000	;PC IN UPPER?
	POPJ	P,		;NO.  OUT OF BOUNDS
	PUSH	P,TAC		;SAVE SUSPECT PC.
	MOVE	TAC,TAC1	;TAC←FIRST ADDRESS ABOVE LOWER
	CAIGE	TAC,400000	;IF THAT'S GREATER THAN 400000 THEN IT'S FIRST
	MOVEI	TAC,400000	;    LOC. IN UPPER, ELSE 400000 IS FIRST IN UPPER
	LDB	TAC1,PSEGN	;IS THERE AN UPPER?
	JUMPE	TAC1,TPOPJ	;IF NOT, THEN PC IS OUT OF BOUNDS
	PUSHJ	P,CORSGT	;TAC1←SIZE OF UPPER IN WORDS
	ADD	TAC1,TAC	;TAC1←FIRST LOC BEYOND THE UPPER.
	POP	P,TAC		;GET TARGET PC AGAIN
	CAML	TAC,TAC1	;SKIP IF PC IS WITHIN THE UPPER.
	POPJ	P,		;PC OUT OF BOUNDS.
	JRST	CPOPJ1

;APR DETECTED ERRORS
;PUSHDOWN OVERFLOW,ILLEGAL MEMORY, NONEXISTENT MEMORY
;FOR WHICH THE USER IS NOT ENABLED.
;SEE APRSER TO SEE HOW APR INTERRUPTS ARE HANDLED
;CALL:	SKIPE	TAC,APRERR	;RESULT OF CONI APR,APRERR
;	PUSHJ	P,APRILM	;FROM CLK SERVICE ROUT.(LOWEST PRIOTITY PI)
;	RETURN TO RESCHEDULE NEW USER

↑APRILM:SETZM	APRERR(PID)	;ZERO ERROR FLAG
	MOVE	J,JOB(PID)	;BLAME CURRENT JOB, WHOMEVER IT MAY BE
	TRNN	TAC,ILM		;ILLEGAL MEMORY REFERENCE?
	JRST	APRNXM		;NO
	MOVE	TAC,APRPC(PID)
	TLNN	TAC,USRMOD
	JRST	APRIL1		;MPV FROM EXEC MODE PC. (SHIT)
APRIL2:	HRRZ	TAC,TAC
	PUSHJ	P,ADRTST	;SEE IF PC IS OUT OF BOUNDS (OTHERWISE, NORMAL ILM)
	JRST	APRJRS		;PC OUT OF BOUNDS
APRIL1:	JSP	TAC,ERRPNT
	ASCIZ	/Ill mem ref/
	JRST	APRSCD		;PRINT LOC, THEN STOP JOB

APRJRS:	JSP	TAC,ERRPNT
	ASCIZ	/PC exceeds mem bounds/
	JRST	APRSCD		;PRINT LOC, THEN STOP JOB

APRNXM:	TRNN	TAC,NXM		;NX MEM?
	JRST	PDLAPR		;NO
	JSP	TAC,ERRPNT	;YES
	ASCIZ	/Non ex mem/
	JRST	APRSCD		;PRINT LOC, THEN STOP JOB

PDLAPR:	TRNN	TAC,POV		;PUSHDOWN OVERFLOW?
	JRST	APRCNS		;NO
	JSP	TAC,ERRPNT	;YES
	ASCIZ	/Pdl ov/
	JRST	APRSCD

APRCNS:	TRNN	TAC,CNS		;CONS TRAP?
	JRST APRPBL		;NO
	JSP	TAC,ERRPNT
	ASCIZ	/Cons trap/
APRSCD:	MOVE	TAC1,APRPC(PID)	;PRINT APR PC 
	JRST	PCPNT

APRPBL:	TLNN TAC,PCPUBL		;PROPRIETARY VIOLATION?
	JSP DAT,UERROR		;NO. HARDWARE PROBLEM.
	JSP TAC,ERRPNT
	ASCIZ /Proprietary violation (Public bit set in PC)/
	JRST APRSCD

;UERROR IS FOR UUO LEVEL, BLAMES CURRENT JOB
;CERROR IS FOR CLOCK LEVEL AND LOSES

↑UERROR:MOVE	J,JOB(PID)	;PRINT FOR CURRENT JOB NUMBER
↑CERROR:JSP	TAC,ERRPNT	;J ALREADY SET UP "?ERROR IN JOB CRLF"
	ASCIZ	/Error in monitor/
	MOVE	TAC1,-1(P)	;GET LOC OF JSP DAT,ERROR
	JRST	PCPNT		;PRINT PC AND STOP JOB
;PIERR1  
;CALL:	JSR PIERR (OR PIERR+P2PID)
;
;TYPES "ERROR IN MONITOR" FOLLOWED BY CONTENTS OF DAT.  HALTS


↑PIERR1:MOVEM	PID,ESVPID	;SAVE PID
	MOVEI	PID,0
	JRST	PIERR3

↑PIERR2:MOVEM	PID,ESVPID+P2PID
	MOVEI	PID,P2PID
PIERR3:	MOVEM	P,ERRPDL(PID)	;SAVE IT WHERE WE CAN FIND IT
	MOVE	P,ERRPD(PID)
	AOBJN	P,.+1
	PUSHACS
	PUSHJ	P,DISDATE
	PUSHJ	P,DISMES
	ASCIZ	/MONITOR ERROR AT /
	MOVE	TAC,PIERR(PID)
	SUBI	TAC,1
	PUSHJ	P,DISOCT
	PUSHJ	P,DISCRLF
	PUSHJ	P,DISFLUSH
	POPACS
	PUSHJ	P,DDTCALL
	HALT	AUTOLOAD		;THIS IS A LOSE ALWAYS NOW

;UUOERR: ILLEGAL UUO  - CALLED AT ANY LEVEL!

↑UUOERR:ERRSPW			;IF SPACEWAR MODE, JUMP TO SPWERR
	MOVEM	J,TSAVJ#	;I HATE VARIABLES, BUT SAVE J
	MOVE	J,JOB(PID)	;SOMETIMES NOT SET UP BY DPYSER
	MOVE	TAC1,UUOPC(J)
	JUMPE	J,UUOER3
	TLNE	TAC1,USRMOD
	JRST	UUOER1		;USER MODE CALL
UUOER3:	MOVEM	P,ERRPDL	;UUO CALLED FROM EXEC STORE LOSER'S P.
 	MOVE	P,ERRPD(PID)
	ADD	P,[1,,1]
UUOER1:	JSP	TAC,ERRPTU	;RETURNS WITH DAT AND DDB PUSHED
	ASCIZ	/Illegal UUO/
	MOVE	TAC1,UUOPC(J)	;GET LAST UUO PC
	TLNE	TAC1,USRMOD	;USER ERROR?
	SOJA	TAC1,PCPNT
	PUSHACS
	PUSHJ	P,DISDATE
	PUSHJ	P,DISMES
	ASCIZ	/ILL UUO FROM EXEC AT UUO LEVEL
UUO AT /
	MOVE	TAC,UUOPC(J)
	MOVEI	TAC,-1(TAC)
	PUSHJ	P,DISOCT
	PUSHJ	P,DISTAB
	PUSHJ	P,DISJOB
	PUSHJ	P,DISMES
	ASCIZ	/ UUOOPC = /
	MOVE	TAC,UUOOPC(J)
	PUSHJ	P,DISOCT
	PUSHJ	P,DISMES
	ASCIZ	/  P= /
	MOVE	TAC,ERRPDL
	PUSHJ	P,DISOCT
	CAMN	J,TSAVJ
	JRST	UUOER2
	PUSHJ	P,DISMES
	ASCIZ	/J WAS: /
	MOVE	TAC,TSAVJ
	PUSHJ	P,DISOCT		;ONLY MAKES SENSE IN DECIMAL IF A JOB NUMBR
UUOER2:	PUSHJ	P,DISCRLF
	PUSHJ	P,SYSFIX
	JFCL			;NO ERRORS
	JFCL			;FOUND TROUBLE, BUT COULDN'T FIX IT!
	PUSHJ	P,DISFLUSH	;TELL THE WORLD
	POPACS
	PUSHJ	P,WDDTCALL
	MOVE	TAC1,UUOPC(J)
	SOJA	TAC1,PCPNT	;ALWAYS TRY JUST FLUSHING LOSER
;ILLEGAL INSTRUCTION  -  ILLINS, HALT
;HALT INSTRUCTION IS A SPECIAL CASE WHICH STOPS JOB BUT
;THE USER MAY CONTINUE FROM IT (EFFECTIVE ADR.)
;CALLED AT UUO LEVEL WITH A JRST


↑ILLINS:HLRZ	TAC,UUO		;ILLEGAL OPCODE
	ANDI	TAC,777600	;LOOK AT OPCODE AND HIGH 2 AC BITS
	CAIN	TAC,(<JRST 4,>)	;IS IT A HALT? (JRST 14, IS ILLEGAL)
	JRST	HALT		;YES, PRINT DIFFERENT MESSAGE

IFKL10,<
	LDB	TAC,[POINT 9,UUO,8]	;GET THE OPCODE
	MOVSI	AC3,-ILLTLN		;LENGTH OF TABLE OF OLD INSTRUCTIONS
	PUSH	P,[USRXT0]		;(IN CASE WE FIND ONE) SIMULATION WILL POPJ
ILLIN1:	LDB	TAC1,[POINT 9,ILLTAB(AC3),8]	;ILLTAB IS IN KLSER
	CAMN	TAC1,TAC
	JRST	@ILLTAB(AC3)		;SIMULATE OLD INSTRUCTION
	AOBJN	AC3,ILLIN1		;LOOP, LOOKING THRU OLD TABLE
	SUB	P,[1,,1]		;FAILED.  FLUSH "RETURN" FROM STACK
>;IFKL10

	JSP	TAC,ERRPTU
	ASCIZ	/Illegal Instruction/
	JRST	UUOPCP		;PRINT UUO PC AND STOP JOB

↑HALT:	MOVE	J,JOB(PID)	;PICK UP JOB NUMBER
	PUSHJ	P,TTYERP	;SET TTY IN MONITOR MODE
	PUSHJ	P,INLMES
	ASCIZ	/Halt/
	SOS	TAC1,UUOPC(J)	;UUOPC = LOCATION OF HALT PLUS ONE
	PUSHJ	P,PCP		;PRINT "USER LOC XXX"
	PUSHJ	P,PRCRCC	;PRINT MONITOR MODE RESPONSE (CRLF ↑C .)
	HRRM	UUO,UUOPC(J)	;SAVE EFFECTIVE ADDRESS OF HALT
	PUSHJ	P,TTYSTC	;START TTY TYPING
	PUSHJ	P,SETSTP	;STOP JOB, BUT FINISH THIS UUO
	SKIPN	INTACT(PID)	;ILLEGAL AT INTERRUPT LEVEL
	JRST	USRXIT		;"RETURN" TO ADDRESS OF HALT (WILL NEVER GET THERE)
	JRST	ESTOP		;FLUSH USERS WHO HALT AT USER INTERRUPT LEVEL
;SPWMES - ERROR MESSAGE FOR SPW MODULES - HERE FROM P1 CLOCK LEVEL.

HISYS

↑SPWMES:JSP	TAC,ERRPNT
	ASCIZ	/Spacewar lossage/
	MOVE	TAC,JBTST2(J)		;GET GOOD BITS
	TLNN	TAC,ILMSPW		;ILL MEM REF?
	JRST	SPWNXM			;NO
	HRRZ	TAC,TAC
	PUSHJ	P,ADRTST	;SEE IF PC IS OUT OF BOUNDS (OTHERWISE, NORMAL ILM)
	JRST	SPWIPC		;PC OUT OF BOUNDS
	PUSHJ	P,INLMES
	ASCIZ	/ - Ill mem ref/
	JRST	SPWMS1

SPWIPC:	PUSHJ	P,INLMES
	ASCIZ	/ - PC exceeds mem bounds/
	JRST	SPWMS1

SPWNXM:	TLNN	TAC,NXMSPW
	JRST	SPWPDL
	PUSHJ	P,INLMES
	ASCIZ	/ - Non ex mem/
	JRST	SPWMS1

SPWPDL:	TLNN	TAC,POVSPW
	JRST	SPWCNS
	PUSHJ	P,INLMES
	ASCIZ	/ - Pdl ov/
	JRST	SPWMS1

SPWCNS:	TLNN	TAC,CNSSPW
	JRST	SPWTMX
	PUSHJ	P,INLMES
	ASCIZ	/ - Cons trap/
	JRST	SPWMS1

SPWTMX:	TLNN	TAC,ILLTMO
	JRST	SPWMS1
	PUSHJ	P,INLMES
	ASCIZ	/ - Time out/
SPWMS1:	HRRZ	TAC1,JBTST2(J)
	HRLI	TAC1,USRMOD		;SETUP FOR PCPNT
	PUSHJ	P,KILSPW		;FLUSH SPACEWAR
	JRST	PCPNT


;ADRERR,UADRER,UADERR,ILLINP,ILLOUT,BTLERR,ILLMOD,IOIERR,DEVHNG,BADDIR,DEVEXC

;ADDRESS CHECK ERROR AT ANY LEVEL
;DDB MUST BE SET UP TO POINT TO OFFENDING DEVICE

↑ADRERR:JSP	TAC,ERRDEV	;GET JOB NO. FROM DDB
UADER1:	ASCIZ	/Address check for /
	JRST	DEVEXC		;"DEVICE XXX; EXEC CALLED FROM EXEC/USER LOC YYY"
				;THEN STOP JOB

↑UADRER:			;SAME AS ADRERR EXCEPT GETS JOB # FROM JOB(PID)
	MOVEI	TAC,UADER1	;ADDRESS CHECK AT UUO LEVEL.
	JRST	ERRPTU		;WILL PRINT UADER1 AND CALL DEVEXC

;ADDRESS CHECK FOR NON-IO UUOS
;CALL BY <JRST UADERR>, DOES NOT RETURN
;WE GET HERE FOR MPV INTERRUPTS FROM UUO LEVEL OR FROM SPACEWAR
;IN CASE OF SPACEWAR, UUOMES TRANSFERS TO SPWERR IN SPWSER

↑UADERR:JSP	TAC,UUOMES
	ASCIZ	/Address out of bounds, UUO /

↑ILLINP:JSP	TAC,ERRPTU	;INPUT UUO FOR OUTPUT DEVICE - UUO LEVEL ONLY
	ASCIZ	/Output /
	PUSHJ	P,ERNAM		;PRINT "DEVICE XXX"
	JSP	TAC,UUOMES	;PRINT MESSAGE, PC, AND STOP JOB
	ASCIZ	/ cannot do input/


;USER'S BUFFER IS TOO BIG FOR DEVICE SERVICE THAT EMPLOYS AN 
;"INTERNAL SYSTEM BUFFER" - CALLED FROM UUO LEVEL ONLY

↑BTLERR:JSP	TAC,ERRPTU	;SET UP TTY DDB
	ASCIZ	/Buffer too large for /
	JRST	DEVEXC		;"DEVICE XXX", PC, AND STOP JOB



↑ILLOUT:JSP	TAC,ERRPTU	;OUTPUT UUO FOR INPUT DEVICE - UUO LEVEL ONLY
	ASCIZ	/Input /
	PUSHJ	P,ERNAM		;PRINT "DEVICE XXX"
	JSP	TAC,UUOMES	;PRINT MESSAGE,UUOPC,STOP JOB
	ASCIZ	/ cannot do output/

;ILLEGAL DEVICE DATA MODE (INIT, OPEN, OR SETSTS UUOS) - UUO LEVEL ONLY
↑ILLMOD:JSP	TAC,ERRPTU
	ASCIZ	/Illegal data mode for /
	JRST	DEVEXC		;PRINT "DEVICE XXX",UUO PC

;IO UUO TO USER CHANNEL WITH NO PREVIOUS INIT OR OPEN - UUO LEVEL ONLY
↑IOIERR:JSP	TAC,ERRPTU
	ASCIZ	/IO to unassigned channel/
	JRST	UUOPCP		;PRINT UUO PC

;ROUTINE FOR HUNG IO DEVICE
;CALL	MOVE DDB,ADDRESS OF DEVICE DATA BLOCK
;	PUSHJ	P,DEVHNG


↑DEVHNG:MOVEI	TAC,IOACT		;TURN OFF IO DEVICE ACTIVE BIT IN
	ANDCAM	TAC,DEVIOS(DDB)		;MEMORY AND IOS
	TRZ	IOS,IOACT
	JSP	TAC,ERRDEV
	ASCIZ	/Hung /
	JRST	DEVEXC			;"DEVICE XXX UUO AT ... "

↑BADDIR:JSP	TAC,ERRPNT
	ASCIZ	/Bad directory for /

;ROUTINE TO PRINT "DEVICE XXX; EXEC CALLED FOR EXEC/USER YYY"
;THEN STOP JOB
;TO BE USED BY DEVICE DEPENDENT ERROR MESSAGES AFTER JSP TAC,DEVERR

↑DEVEXC:PUSHJ	P,ERNAM			;PRINT "DEVICE XXX"
	MOVE	TAC,(P)			;GET DEVICE DDB
	MOVE	TAC1,DEVMOD(TAC)	;RPH PATCH TO CLEAR GOBIT ON DISK ERRORS
	TLNN	TAC1,DVDSK
	JRST	EXCALP
	MOVSI	IOS,GOBIT
	ANDCAB	IOS,DEVIOS(TAC)		;CLEAR GO BIT IF STOPPING DISK
	JRST	EXCALP			;PRINT PC AND STOP.
;HNGSTP
;STOP A JOB WHEN A DEVICE IS NOT READY FOR I/O - UUO LEVEL ONLY
;CALL	MOVE	DDB,<ADDR OF DEVICE DDB>
;	MOVE	J,JOB NUMBER
;	PUSHJ	P,HNGSTP


↑HNGSTP:PUSH	P,IOS		;SAVE STUFF FOR DEVICE
	PUSH	P,DDB
	PUSHJ	P,TTYFUW
	PUSHJ	P,PRQM		;"? "
	PUSHJ	P,ERNAM		;"Device XXX"
	PUSHJ	P,INLMES	;AND MESSAGE
	ASCIZ	/ isn't ready/
	PUSHJ	P,PRCRCC
	PUSHJ	P,TTYSTC	;START TTY IN COMMAND MODE
	POP	P,DDB
	POP	P,IOS
	PUSHJ	P,STOP1		;STOP JOB
	JRST	WSCHED		;AND RESCHEDULE
;HNGMES 
;PRINT A MESSAGE AND STOP A JOB BUT ALLOW IT TO CONTINUE.
;	MOVEI	TAC,[ASCIZ /MESSAGE HERE/]
;	PUSHJ	P,HNGMES

↑HNGMES:
	PUSH	P,IOS
	PUSH	P,DDB
	PUSH	P,AC1
	PUSH	P,AC2
	PUSH	P,AC3
	PUSH	P,DAT
	PUSH	P,TEM
	PUSH	P,TAC1
	PUSH	P,TAC
	MOVE	J,JOB(PID)
	PUSHJ	P,TTYFUW
	POP	P,TAC		;ADDRESS OF MESSAGE
	PUSHJ	P,CONMES
	PUSHJ	P,PRCRCC	;APPEND CRLF ↑C .
	PUSHJ	P,TTYSTC	;START TTY
	PUSHJ	P,STOP1		;AND STOP USER
	POP	P,TAC1
	POP	P,TEM
	POP	P,DAT
	POP	P,AC3
	POP	P,AC2
	POP	P,AC1
	POP	P,DDB
	POP	P,IOS
	JRST	WSCHED
;COMMON ERROR MESSAGE SETUP ROUTINES - ERRPTU, ERRDEV, ERRPNT

LOSYS

;CALL:	JSP TAC,ERRPTU, ERRDEV, OR ERRPNT
;	ASCIZ /MESSAGE/
;	RETURNS HERE WITH DDB SAVED 0(P)
;	C(DDB)=TTYDDB, DAT TO TTY OUTPUT BUFFER POINTER
;	ITEM=JOB NUMBER

;USE ERRPTU IF AT UUO LEVEL FOR SURE
;ERRDEV IF ERROR FOR AN ASSIGNED DEVICE AT ANY LEVEL
;ERRPNT WITH ITEM ALREADY SET TO OFFENDING JOB NUMBER
;THE JSP CALL IS USED IN CASE PUSHDOWN SPACE BECOMES CRITICAL
;AGAIN AND ERRPNT HAS TO WIPE EXISTING LIST OUT

↑ERRPTU:SKIPN	J,JOB(PID)	;BLAME CURRENT JOB IF NOT 0
↑ERRDEV:LDB	J,PJOBN		;JOB NUMBER FROM DEVICE DATA BLOCK
↑ERRPNT:JUMPN	J,.+2
	SETOM	NULBAD(PID)
	PUSH	P,DAT		; SAVE CALL TO ERROR
	SKIPL	J
	CAIL	J,JOBN		;REASONABLE JOB NUMBER?
	CAIA
	JRST	ERRZZ2		;JOB NUMBER IS OK
	PUSHACS
	PUSHJ	P,DISDATE
	PUSHJ	P,DISMES
	ASCIZ	/JOB(PID) CLOBBERED AT ERRPTU
/
	POPACS
	DEBCHECK
ERRZZ2:	PUSH	P,DDB		;SAVE ADR. OF DEV. DATA BLOCK
	PUSH	P,TAC		;SAVE RETURN FROM ERRPNT
	PUSHJ	P,TTYERP	;FIND JOB'S TTY AND SET UP DDB.
	PUSHJ	P,INLMES
	ASCIZ	/? Error in job /
	PUSHJ	P,PJOB		;PRINT JOB NO.
	JRST	INLMES		;PRINT MESSAGE SPECIFIED BY CALLER
;ROUTINE TO PRINT UUO PC AND STOP JOB - UUOMES, UUOPCP
;IF IN USER MODE PC WILL PRINT AS "AT USER LOC XXX"
;IF IN EXEC MODE "AT EXEC LOC XXX; EXEC CALLED FORM EXEC/USER/ LOC YYY


↑UUOMES:
	MOVE	J,JOB(PID)	;MAKE SURE J IS SET UP
	ERRSPW			;JUMP TO SPWERR IF SPACEWAR IN PROGRESS
	PUSH	P,TAC
	PUSHJ	P,TTYERP
	POP	P,TAC
	PUSHJ	P,CONMES	;PRINT MESSAGE POINTED TO BY TAC
↑UUOPCP:
	MOVE	TAC1,UUOPC(J)	;UUO PC STORED AT BOTTOM OF PDL
				;FIRST LOC ON PD LIST
	SOJA	TAC1,PCPNT	;DECREMENT TO POINT TO UUO IN USER AREA
;PCSTOP, EXCALP, PCPNT

;ROUTINE TO PRINT ONE OF THREE MESSAGES AND STOP JOB
;1) "AT EXEC LOC XXX; EXEC CALLED FROM EXEC LOC YYY"
;2) "AT EXEC LOC XXX; EXEC CALLED FORM USER LOC YYY"
;3) "AT USER LOC YYY"

;CALL:	MOVE TAC1,XXX		;WITH PC FLAGS IN LH
;	PUSHJ	P,PCPNT
;	NEVER RETURN IF AT UUO LEVEL


↑PCPNT:	PUSHJ	P,PCP		;PRINT " AT EXEC XXX" OR " AT USER "
	TLNE	TAC1,USRMOD	;WAS PC IN USER MODE?
	JRST	PCSTOP		;YES, ENOUGH INFO.

;ROUTINE TO PRINT EITHER:
;1) "; EXEC CALLED FROM EXEC LOC YYY"
;2) "; EXEC CALLED FROM USER LOC YYY"
;AND STOP JOB
;CALL:	PUSHJ	P,EXCALP
;	NEVER RETURNS IF AT UUO LEVEL


↑EXCALP:PUSHJ	P,INLMES
	ASCIZ	/; UUO/
	MOVE	TAC1,UUOPC(J)	;UUO PC ON PDL
	SUBI	TAC1,1		;BACK IT UP TO POINT TO UUO
	PUSHJ	P,PCP		;PRINT "EXEC LOC " OR USER LOC
↑PCSTOP:PUSHJ	P,HOLD		;STOP JOB, START TTY AND SET JOB ERROR BIT
	POP	P,DDB		;RETURN ONLY IF AT INTERRUPT LEVEL
	JRST	TPOPJ		;REMOVE ERROR CALL AND RETURN

;PCP, OCTPNT, RADX10
;ROUTINE TO PRINT PC AS:
;1) "EXEC LOC XXX" OR "USER LOC XXX"
;CALL:	MOVE TAC1,PC TO PRINT(LH=PC FLAGS)
;	PUSHJ	P,PCP


XMODE:	ASCIZ / at exec /
UMODE:	ASCIZ / at user /

PCP:	MOVEI	TAC,XMODE	;ASSUME PC IN EXEC MODE
	TLNE	TAC1,USRMOD	;IS IT?
	MOVEI	TAC,UMODE	;NO, USER MODE
	PUSHJ	P,CONMES	;PRINT ONE OR OTHER
	HRRZ	TAC,TAC1	;PRINT RIGHT HALF IN OCTAL
				;FALL INTO OCTPNT

;ROUTINE TO PRINT 36 BIT OCTAL NO
;CALL:	MOVE DAT, TTY OUTPUT BYTE POINTER
;	MOVE TAC,OCTAL NO
;	PUSHJ	P,OCTPNT

↑OCTPNT:PUSH	P,TAC1		;SAVE TAC1
	MOVEI	TAC1,10		;OCTAL BASE
ANYRDX:	PUSH	P,J
	MOVEI	J,(TAC1)
	PUSHJ	P,OCTP1
	POP	P,J
	POP	P,TAC1
	POPJ	P,

OCTP1:	IDIVI	TAC,(J)
	HRLM	TAC1,(P)
	JUMPE	TAC,.+2
	PUSHJ	P,OCTP1
	HLRZ	TEM,(P)
	MOVEI	TEM,"0"(TEM)
	XCT	TYO
	POPJ	P,

;ROUTINE TO PRINT DECIMAL NO.
;CALL:	SAME AS OCTPNT
;TAC1 IS PRESERVED

↑RADX10:PUSH	P,TAC1		;OUTPUT DECIMAL
	MOVEI	TAC1,12
	JRST	ANYRDX
;ERNAM, PRNAME

;PRINT "DEVICE XXX" 
;CALL	MOVE DAT,ASCII OUTPUT BYTE POINTER
;	PUSH	P,DDB
;	PUSHJ	P,ERNAM


↑ERNAM:	PUSHJ	P,INLMES
	ASCIZ	/Device /
	SKIPE	TAC1,-1(P)		;IS DDB = 0?
	MOVE	TAC1,DEVNAM(TAC1)	;GET DEVICE NAME
					;FALL INTO PRNAME
;PRINT SIXBIT NAME
;CALL	MOVE DAT,ASCII OUTPUT BYTE POINTER
;	MOVE TAC1,NAME
;	PUSHJ	P,PRNAME

↑PRNAME:JUMPE	TAC1,CPOPJ	;DONE IF NULL
	MOVEI	TAC,0
	LSHC	TAC,6		;SHIFT IN NEXT CHAR.
	MOVEI	TEM,40(TAC)
	XCT	TYO		;TYPE OUT IN ASCII.
	JRST	PRNAME
	SUBTTL	DISASTER TYPEOUT	;DISINIT, DISOUT

↑DISINIT:			;INITIALIZE DISASTER SERVICE 
	MOVE	TAC,[POINT 7,DISBUF]
	MOVEM	TAC,DISPTR
	MOVEM	TAC,DISOPT
	MOVEI	TAC,5*DISLEN
	MOVEM	TAC,DISCTR
	POPJ	P,

; ROUTINE TO TYPE OUT DISASTER BUFFER ON CTY AT CLOCK LEVEL
; RECCOMMENDED CALLING . . .
;	MOVE TAC,DISPTR
;	CAME TAC,DISOPT
;	PUSHJ P,DISOUT
; PUTS AS MUCH TEXT AS IT CAN INTO THE CTY OUTPUT BUFFER AND INITIATES
; CTYTYO.

↑DISOUT:
	MOVEI	J,0
	PUSHJ	P,TTYFND		;SET UP DDB AND DAT TO THE CTY
	MOVEI	IOS,IOSUPR
	ANDCAM	IOS,DEVIOS(DDB)		;TURN OFF ↑O
DISOU1:	MOVE	TAC,FCTR(DAT)		;HOW FULL IS THE BUFFER?
	CAIG	TAC,1
	JRST	TYPGO			;FULL TO THE GILLS. INITIATE TYPEOUT
	PUSHJ	P,DISOUX		;GET A CHARACTER
	JRST	TYPGO			;THERE ARE NONE LEFT IN DISBUF. GO TYPEOUT
	XCT	TYO			;STUFF IT.
	JRST	DISOU1			;LOOP.

;ROUTINE TO REMOVE A CHARACTER FROM DISBUF.
;CALL AT ANY LEVEL.  MAINTAINS STATE OF PION.
;SKIP-RETURNS WITH CHARACTER IN TEM, WRAPS DISOPT AS NEEDED
;DIRECT RETURN IF DISBUF IS EMPTY

DISOUX:	PUSH	P,AC2			;SAVE ACS
	PUSH	P,AC3
	MOVE	AC2,[POINT 7,DISBUF]	;SET TO REINITIALIZE DISPTR
	MOVE	AC3,[POINT 7,DISBUF+DISLEN-1,34]	;LAST BYTE
	CONSZ	PI,PION			;PI SYSTEM ON?
	SKIPA	AC1,[CONO PI,PION]	;YES. TURN IT ON WHEN WE EXIT
	MOVSI	AC1,(<JFCL>)
	CONO	PI,PIOFF		;OK. NOBODY MOVE
	AOS	TEM,DISCTR		;CHARACTERS LEFT IN THE BUFFER?
	CAILE	TEM,5*DISLEN
	JRST	DISOX2			;NO - OOPS.
	ILDB	TEM,DISOPT		;STUFF THE BYTE
	CAMN	AC3,DISOPT		;WAS THAT THE LAST AVAILABLE BYTE?
	MOVEM	AC2,DISOPT		;YES. RESET TO FRONT OF BUFFER
	XCT	AC1			;RESTORE PION IF WE TURNED IT OFF.
	AOS	-2(P)			;SKIP-RETURN - WE HAVE A CHARACTER
DISOX1:	POP	P,AC3
	POP	P,AC2
	POPJ	P,

DISOX2:	SOS	TEM,DISCTR		;BUFFER BETTER LOOK EMPTY!
	XCT	AC1
	JRST	DISOX1
; DISFLUSH - TURNS PIS OFF AND TYPES ENTIRE DISASTER BUFFER TO CTY
; SERVOS CTY ALL BY ITSELF
; CALLING . . .
;	PUSHJ P,DISFLUSH

↑DISFLUSH:
	SKIPP1				;SKIP IF P1
	POPJ	P,			;ON P2 THERE'S NOTHING TO FLUSH.
	CONSZ	PI,PION
	SKIPA	AC1,[CONO PI,PION]
	MOVSI	AC1,(<JFCL>)
	PUSH	P,AC1			;SAVE STATE OF PI SYSTEM
	CONO	PI,PIOFF

NOKL10,<	CONI	CTY,AC1
		PUSH	P,AC1		;SAVE CTY PIA
		CONO	CTY,0		;AND SET TO 0 SO WE WON'T INT
		MOVEI	AC1,100000	;WAIT FOR THE CTY TO COOL OFF
		SOJG	AC1,.		>;NOKL10

IFKL10,<	MOVEI	TAC,DTMONG
		PUSHJ	P,DTEXX		;GET STATE OF MONITOR MODE
		PUSH	P,TAC		;SAVE STATE OF MONITOR MODE
		MOVEI	TAC,DTMONC	;CLEAR MONITOR MODE
		PUSHJ	P,DTEXX		>;IFKL10

	SKIPN	DAT,TTYTAB+TCONLN	;IS THE CTY THERE AT ALL?
	JRST	DISFL1			;NO, SKIP ALL THIS CRAP
	ADDI	DAT,TTOBUF		;POINT TO OUTPUT BUFFER.
DISFL3:	MOVE	TAC,TAKR(DAT)		;TYPE CTY OUTPUT BUFFER BEFORE
	CAMN	TAC,PUTR(DAT)		;  TYPING DISASTER BUFFER
	JRST	DISFL1			;CTY OUTPUT BUFFER EMPTY.  DO DISBUF NEXT
	PUSHJ	P,GETCHO		;PICK UP A CHARACTER FROM THE OUTPUT BUFFER
	PUSHJ	P,CTYTYO		;AND TYPE IT OUT
	JRST	DISFL3

DISFL1:	PUSHJ	P,DISOUX		;GET A CHARACTER FROM DISASTER BUFFER
	JRST	DISFLX			;DISASTER BUFFER EMPTY NOW.
	PUSHJ	P,CTYTYO		;TYPE OUT ON CTY
	JRST	DISFL1

DISFLX:
NOKL10,<	POP	P,AC1
		ANDI	AC1,7		;RESTORE CTY PIA
		CONO	CTY,(AC1)	>;NOKL10

IFKL10,<	POP	P,AC1		;RESTORE PREVIOUS STATE OF MONITOR MODE
		MOVEI	TAC,DTMONS	;IT'S OFF NOW, SET IT, IF NEEDED.
		SKIPE	AC1		;SKIP IF IT WAS OFF
		PUSHJ	P,DTEXX		>;IFKL10

	POP	P,AC1
	XCT	AC1			;RESTORE STATE OF PI SYSTEM
	POPJ	P,
; DISTYO - TYPES ONE CHARACTER IN TEM THROUGH THE DISASTER BUFFER.
; CALLING . . .
;	MOVE TEM,<CHARACTER>
;	PUSHJ P,DISTYO

DISTYF:	PUSH	P,AC1		;SAVE AN AC
	PUSH	P,TEM
	PUSHJ	P,DISFLUSH	;EMPTY THE DISASTER BUFFER
	POP	P,TEM
	POP	P,AC1
↑DISTYO:SKIPP1	
	JRST	CTYTYO		;ON P2, JUST HANG THINGS UP WHILE WE TYPE
	PUSHJ	P,DISTY1	;TRY TO TYPE A CHARACTER
	JRST	DISTYF		;FAILED - NO ROOM IN THE BUFFER
	POPJ	P,		;SUCCESS!

DISTY1:	PUSH	P,AC2			;SAVE ACS
	PUSH	P,AC3
	PUSH	P,AC1
	MOVE	AC2,[POINT 7,DISBUF]	;SET TO REINITIALIZE DISPTR
	MOVE	AC3,[POINT 7,DISBUF+DISLEN-1,34]	;LAST BYTE
	CONSZ	PI,PION			;PI SYSTEM ON?
	SKIPA	AC1,[CONO PI,PION]	;YES. TURN IT ON WHEN WE EXIT
	MOVSI	AC1,(<JFCL>)
	CONO	PI,PIOFF		;OK. NOBODY MOVE
	SOSGE	DISCTR			;ROOM IN THE BUFFER?
	JRST	DISTY3			;NO - OOPS.
	IDPB	TEM,DISPTR		;STUFF THE BYTE
	CAMN	AC3,DISPTR		;WAS THAT THE LAST AVAILABLE BYTE?
	MOVEM	AC2,DISPTR		;YES. RESET TO FRONT OF BUFFER
	XCT	AC1			;RESTORE PION IF WE TURNED IT OFF.
	AOS	-3(P)
DISTY2:	POP	P,AC1
	POP	P,AC3
	POP	P,AC2
	POPJ	P,

DISTY3:	AOS	DISCTR
	XCT	AC1
	JRST	DISTY2
;DISMES, DISCRLF, DISTAB, DISJOB
; ROUTINE TO DO A DISASTER OUTPUT OF A STRING
; CALL BY:
;	PUSHJ P,DISMES
;	ASCIZ /<STRING>/

↑DISMES:
	MOVSI	AC1,(<POINT 7,0>)
	HLLM	AC1,(P)			;SET RETURN ADDRESS TO A BYTE POINTER
DISME1:	ILDB	TEM,(P)			;GET A BYTE
	JUMPE	TEM,CPOPJ1		;NONE THERE. INCREMENT SAVED PC AND RETURN
	PUSHJ	P,DISTYO
	JRST	DISME1

↑DISCRLF:			;CALL TO DO DISASTER OUTPUT OF CRLF ON THE CTY
	MOVEI	TEM,15
	PUSHJ	P,DISTYO
	SKIPA	TEM,[12]
↑DISTAB:MOVEI	TEM,11		;TYPE TAB THRU DISASTER SERVICE
	JRST	DISTYO

↑DISJOB:			;TYPE JOBNUMBER(JOBNAME). J IS SET WITH JOBNUMBER
				;J IS PRESERVED.
	PUSH	P,J		;SAVE JOB NUMBER
	JUMPLE	J,DISJAR
	CAIL	J,JOBN
	JRST	DISJAR
	MOVE	TAC1,JOBNAM(J)	;GET THE JOBNAME
	PUSHJ	P,DISSIX
	MOVEI	TEM,"("
	PUSHJ	P,DISTYO
DISJB1:	MOVE	TAC,(P)
	PUSHJ	P,DISDCP	;TYPE JOB NUMBER IN DECIMAL WITH DECIMAL POINT
	MOVEI	TEM,")"
	PUSHJ	P,DISTYO
	POP	P,J
	POPJ	P,

DISJAR:	PUSHJ	P,DISMES
	ASCIZ	/(DISJOB - ILLEGAL JOB NUMBER - /
	JRST	DISJB1
;DISERR - CALLING SEQUENCE
;	PUSHJ P,DISERR
;	XWD CODE,ADDR
;	XWD CODE,ADDR
;	      .
;	      .
;	      .
;	      .
;	     -1
;

↑DISERR:SKIPGE	TEM,@(P)
	JRST	CPOPJ1			;SKIP RETURN
	ASH	TEM,-=23		;ONLY CODE BITS PLEASE
	MOVEI	AC1,@(P)		;GET EFFECTIVE ADDRESS
	MOVEI	AC1,@(AC1)		;NOW GET IT'S EFFECTIVE ADDRESS
	MOVE	TAC,(AC1)		;SET UP ARGUMENT FOR MOST CALLS.
	CAIG	TEM,ERRLEN-1
	PUSHJ	P,@ERRTAB(TEM)		;DISPATCH
	AOS	(P)			;NEXT ARG
	JRST	DISERR

DEFINE ERRMAC $ (I)
<	ERR$I
>
ERRTAB:	QQQNAM
ERRLEN←←.-ERRTAB


; HERE ARE THE VARIOUS PRINTOUT ROUTINES FOR DISERR
;	OTHERS CALL DISOCT,DISDEC,DISDCP,DISLOC,DISSIX DISHE2 DIRECTLY

ERRSTR:	HRLI	AC1,(<POINT 7,0>)
	PUSH	P,AC1
ERRST1:	ILDB	TEM,(P)
	JUMPE	TEM,TPOPJ		;QUIT ON ZERO (ADJUST STACK AND RETURN)
	PUSHJ	P,DISTYO
	JRST	ERRST1
;DISLOC, DISOCT, DISOCH, DISDCP, DISDEC, DISHE2
;DISLOC PRINTS OUT 6 DIGIT OCTAL LOCATION WITHOUT LEADING ZEROES
;CALL	MOVE TAC,<LOCATION>
;	PUSHJ P,DISLOC

↑DISLOC:
ERRLOC:
	PUSH	P,[=6]
	HRLZ	TAC1,TAC
DISLC1:	TLNE	TAC1,700000	;DO WE HAVE A DIGIT YET?
	JRST	DSOCT2		;YES, PRINT ADDRESS
	LSH	TAC1,3		;SHIFT LEFT 3 BITS
	SOSLE	(P)
	JRST	DISLC1
	JRST	DSOCT2		;PRINT ONE ZERO.

;DISADR - PRINT AN 8-OCTAL DIGIT PHYSICAL MEMORY ADDRESS FROM TAC
↑DISADR:MOVEI	TEM,=8		;PRINT WITH LEADING ZEROES
	AND	TAC,[17777777]	;MAX PHYSICAL ADDRESS
DISAD1:	IDIVI	TAC,=8
	HRLM	TAC1,(P)	;STORE DIGIT
	SUBI	TEM,1
	JUMPE	TAC,DISAD3	;
	PUSHJ	P,DISAD1
DISAD2:	HLRZ	TEM,(P)
	ADDI	TEM,"0"
	JRST	DISTYO

DISAD3:	JUMPLE	TEM,DISAD2
	PUSH	P,[0,,DISAD2]
	SOJA	TEM,DISAD3


; OCTAL PRINT ROUTINE FOR DISASTER MESSAGES
; CALLING . . .
;	MOVE TAC,<NUMBER>
;	PUSHJ P,DISOCT

↑DISOCT:
ERROCT:	PUSH	P,[=12]
	MOVE	TAC1,TAC
DSOCT2:	SETZ	TAC,
	LSHC	TAC,3
	MOVEI	TEM,"0"(TAC)
	PUSH	P,TAC1
	PUSHJ	P,DISTYO
	POP	P,TAC1
	SOSLE	(P)
	JRST	DSOCT2
	JRST	TPOPJ

;ANOTHER OCTAL PRINT ROUTINE. PRINTS  HALFWORD COMMA COMMA HALFWORD
↑DISOCH:
	PUSH	P,TAC		;SAVE THE ARGUMENT
	HLLZ	TAC1,TAC	;GET LEFT SIDE IN LEFT SIDE
	PUSH	P,[DSOCH1]	;"RETURN" ADDRESS
	PUSH	P,[6]		;6 CHARACTERS PLEASE
	JRST	DSOCT2		;DO IT.  RETURN TO DSOCH1

DSOCH1:	MOVEI	TEM,","
	PUSHJ	P,DISTYO
	MOVEI	TEM,","
	PUSHJ	P,DISTYO
	POP	P,TAC1		;GET RIGHT SIDE
	HRLZ	TAC1,TAC1
	PUSH	P,[6]
	JRST	DSOCT2		;WRITE IT AND RETURN

↑DISDCP:
ERRDCP:	PUSHJ	P,DISDEC	;DECIMAL FOLLOWED BY "."
	MOVEI	TEM,"."
	JRST	DISTYO		;APPEND . TO DECIMAL NUMBER

↑DISDEC:
ERRDEC:	JUMPGE	TAC,DISDC1
	MOVEI	TEM,"-"
	PUSHJ	P,DISTYO
DISDC1:	MOVM	TAC,TAC

DISNUM:	IDIVI	TAC,=10
	HRLM	TAC1,(P)
	JUMPE	TAC,.+2
	PUSHJ	P,DISNUM
	HLRZ	TAC,(P)
	MOVEI	TEM,"0"(TAC)
	JRST	DISTYO

;PRINT TAC AS TWO HEX DIGITS
↑DISHE2:
ERRHE2:	MOVEI	TEM,"H"
	PUSHJ	P,DISTYO
	LDB	TEM,[POINT 4,TAC,31]
	PUSHJ	P,ERRHET		;TYPE 4 BIT NUMBER AS HEX
	LDB	TEM,[POINT 4,TAC,35]	;SECOND DIGIT
ERRHET:	CAIL	TEM,=10
	ADDI	TEM,"A"-"0"-=10
	ADDI	TEM,"0"
	JRST	DISTYO
;DISSIX, DISFIL, DISPPN   -  SIXBIT PRINT ROUTINE FOR DISASTER MESSAGES
; CALLING . . .
;	MOVE TAC1,<WORD>
;	PUSHJ P,DISSIX

ERRSIX:	MOVE	TAC1,TAC		;SPECIAL ENTRY FROM DISERR
↑DISSIX:
	JUMPE	TAC1,CPOPJ
	MOVEI	TAC,0
	ROTC	TAC,6
	MOVEI	TEM," "(TAC)		;CONVERT TO ASCII
	PUSH	P,TAC1
	PUSHJ	P,DISTYO
	POP	P,TAC1
	JRST	DISSIX

↑DISFIL:PUSH	P,TAC		;PRINT FILE NAME.  SAVE POINTER
	MOVE	TAC1,(TAC)	;GET FILE NAME
	PUSHJ	P,DISSIX	;SIXBIT
	MOVE	TAC,(P)
	HLLZ	TAC1,1(TAC)	;EXT
	JUMPE	TAC1,DISFI1
	MOVEI	TEM,"."
	PUSHJ	P,DISTYO
	PUSHJ	P,DISSIX
DISFI1:	POP	P,TAC
	MOVE	TAC,3(TAC)	;PPN IN TAC.
	JUMPE	TAC,CPOPJ
↑DISPPN:MOVEI	TEM,"["		;PRINT A PPN FROM TAC.
	PUSHJ	P,DISTYO
	PUSH	P,TAC
	HLLZ	TAC1,TAC
	PUSHJ	P,DISSIX
	MOVEI	TEM,","
	PUSHJ	P,DISTYO
	POP	P,TAC
	HRLZ	TAC1,TAC
	PUSHJ	P,DISSIX
	MOVEI	TEM,"]"
	JRST	DISTYO
;CTYTYO  - TYPE ON THE CTY WITH PIS OFF  (ALSO TYPE ON CTY ON P2)
; CALLING . . .
;	MOVE TEM,<CHARACTER>
;	PUSHJ P,CTYTYO
; CLOBBERS TAC AND SOME OTHERS

↑CTYTYO:PUSHJ	P,CTGETC		;HAS THERE BEEN ANY TYPEIN?
	JRST	CTYTY3			;NO.
	ANDI	TAC,177
	SKIPP2				;IGNORE IT IF THIS IS P2
	CAIE	TAC,"O"-100		;IS IT ↑O?
	JRST	CTYTY3			;NOT ↑O OR THIS IS P2.  GO ON.
	MOVEI	TAC,"↑"
	PUSHJ	P,CTPUTC
	MOVEI	TAC,"O"
	PUSHJ	P,CTPUTC
	MOVEI	TAC,15
	PUSHJ	P,CTPUTC
	MOVEI	TAC,12
	PUSHJ	P,CTPUTC
	PUSH	P,DAT			;SAVE THIS
	SKIPN	DAT,TTYTAB+TCONLN	;IS THERE A CTY DDB
	JRST	.+3			;NO.
	ADDI	DAT,TTOBUF
	PUSHJ	P,SETBFO		;CLEAR OUTPUT BUFFER
	POP	P,DAT
	JRST	DISINI			;CLEAR DISASTER BUFFER AND POPJ

CTYTY3:	MOVE	TAC,TEM			;GET THE CHARACTER
	PUSHJ	P,CTPUTC		;TYPE IT.
IFKL10,<	SKIPP1	>
	CAIE	TEM,11
	POPJ	P,
	MOVEI	TEM,5
TABWAT:	MOVEI	TAC,0
	PUSHJ	P,CTPUTC
	SOJGE	TEM,TABWAT
	POPJ	P,
;DISDATE - SHOVE THE TIME AND DATE INTO DISASTER BUFFER

JIFMIN←←JIFSEC*=60		;NUMBER OF JIFFIES PER MINUTE.

↑DISDATE:
	MOVEI	TEM,1		;SHLUFF
	PUSHJ	P,DISTYO	;TO WARM UP THE CTY
	MOVE	TAC,THSDAT
	IDIVI	TAC,=31		;DAY-1 IN TAC1
	PUSH	P,TAC		;SAVE MONTH AND YEAR
	MOVEI	TAC,1(TAC1)	;GET DAY INTO TAC
	PUSHJ	P,DISDEC	;PRINT DECIMAL
	POP	P,TAC		;MONTH AND YEAR INTO TAC
	IDIVI	TAC,=12		;MONTH-1 IN TAC1, YEAR-64 IN TAC
	PUSH	P,TAC		;SAVE YEAR
	PUSH	P,DSER		;SAVE DSER = TEM+1
	LDB	DSER,[POINT 21,MONTAB(TAC1),35]	;GET MONTH NAME
	LSH	DSER,8				;SHIFT
	OR	DSER,[BYTE(7)40,0,0,0,40]	;SPACES ON EACH SIDE
DISDA1:	MOVEI	TEM,0
	LSHC	TEM,7
	PUSH	P,DSER
	PUSHJ	P,DISTYO
	POP	P,DSER
	JUMPN	DSER,DISDA1
	POP	P,DSER
	POP	P,TAC1		;YEAR-64
	MOVEI	TAC,=64(TAC1)
	PUSHJ	P,DISDEC
	MOVEI	TEM," "
	PUSHJ	P,DISTYO
	MOVE	TAC,TIME
	IDIVI	TAC,JIFMIN	;HOURS AND MINUTES IN TAC
	IDIVI	TAC,=60		;MINUTES IN TAC1
	IMULI	TAC,=100	;HOURS TIMES 100 TO MAKE IT PRINT RIGHT
	ADD	TAC,TAC1
	PUSHJ	P,DISDEC
	JRST	DISCRLF		;TYPE CRLF AND POPJ

HISYS
SUBTTL	IOCSS		;ADVBFE ADVBE1

;ROUTINE TO ADVANCE OUTPUT BUFFER AT INTERRUPT LEVEL

;CALL:	PUSHJ P,ADVBFE
;	EXIT1		RETURN IF NEXT BUFFER IS EMPTY
;	EXIT2		RETURN IF NEXT BUFFER IS FULL
;CLEARS THE USE BIT (IOUSE:=0) OF THE BUFFER POINTED TO BY THE
;OUTPUT BUFFER ADDRESS (DEVOAD) OF THE CURRENT DEVICE DATA BLOCK
;AND ADVANCES THE BUFFER ADDRESS TO THE NEXT BUFFER IN THE RING.
;UPON RETURN, SKIPS IF THE NEXT BUFFER IS FULL.
;SECOND WORD OF NEXT BUFFER IS ADDRESS CHECKED TO
;MAKE SURE IT IS NOT IN JOB DATA AREA OR ABOVE USER AREA
;THE SECOND WORD OF CURRENT BUFFER WAS CHECKED AT UUO LEVEL
;OR PREVIOUS CALL TO ADVBFE



↑ADVBFE:AOS	NABFE			;COUNT BUFFER ADVANCE
	PUSH	P,AC3
	JSP	AC3,PRSET		;SET UP PROT-RELOC REGISTERS
	SKIPN	TAC1,DEVOAD(DDB)	;PICK UP BUFFER ADDRESS
	JRST	ADVXIT			;NONE THERE, EXIT
	JSP	AC3,ADRCK		;MAKE SURE BUFFER ADDRESS IS LEGAL
	XCTR	XW,[MOVEM IOS,-1(TAC1)]	;STORE IO STATUS INTO USER'S BUFFER
	MOVSI	TAC,IOUSE
	XCTR	XRW,[ANDCAB TAC,(TAC1)]	;CLEAR BUFFER IN USE BIT.
	TRNE	IOS,740000		;ANY IO ERRORS?
	JRST	ADVXIT			;YES, DO NOT FILL NEXT BUFFER
	MOVEI	TAC1,(TAC)		;ADDRESS OF NEXT BUFFER IN RING.
	JSP	AC3,ADRCK		;CHECK IT
	HRRM	TAC1,DEVOAD(DDB)	;COPY FREE BUFFER ADDRESS TO DDB
	JRST	ADVBE2

;ENTER HERE FROM SCNSER TO CHECK IF NEXT BUFFER FULL OF DATA YET

↑ADVBE1:PUSH	P,AC3
	JSP	AC3,PRSET
ADVBE2:	SKIPN	TAC1,DEVOAD(DDB)	;GET BUFFER ADDRESS FROM DDB
	JRST	ADVXIT			;NONE THERE.
	XCTR	XR,[SKIPL (TAC1)]	;SKIP IF BUFFER IS NOT BUSY
	JRST	ADVXIT			;STILL BUSY
	JRST	ADVBF1			;SKIP RETURN TO CALLER.  BUFFER FREE.
;PRSET, ADRCK

;PRSET  ROUTINE TO PUSH CURRENT PR ON STACK AND SET UP NEW PR
; CALLING . . .
;	JSP AC3,PRSET
; RETURNS WITH PR ON STACK.

;NOTE: ADVBF1 KNOWS PRECISELY HOW MANY THINGS ARE PUSHED BY PRSET, SO
;IF YOU PUSH ANYTHING ELSE, BE SURE TO CHANGE ADVBF1 AND ADVXIT

PRSET:	PUSH	P,AC2
	PUSH	P,AC1
	PUSH	P,J
	PUSH	P,TEM
	PUSHJ P,PSHMAP			;SAVE STATE OF MAP
	LDB	J,PJOBN
	PUSHJ	P,APRMAP		;SETUP MAP OR PROTECT-RELOCATE
	MOVEI	TEM,JOBPFI		;PROTECTED AREA BOUNDARY.
	PUSH	P,TAC1
	MOVEI	TAC1,(J)
	PUSHJ	P,CORSGT		;TAC1←SIZE OF LOWER IN WORDS
	MOVE	AC1,TAC1
	LDB	AC2,PSEGN
	JUMPE	AC2,PRSET1		;NO UPPER SEGMENT, LEAVE
	MOVE	TAC,AC1
	CAIGE	TAC,400000	;IF LOWER EXCEEDS 128K THEN FIRST ADDRESS IN UPPER
	MOVEI	TAC,400000	;  IS 1 ABOVE LOWER, ELSE 400000
	MOVEI	TAC1,(AC2)
	PUSHJ	P,CORSGT	;TAC1←CORE SIZE OF UPPER IN WORDS
	ADD	TAC1,TAC	;+UPPER SEGMENT ORIGIN=FIRST LOC AFTER UPPER.
	MOVE	AC2,TAC1
PRSET1:	POP	P,TAC1
	JRST	(AC3)

;ADRCK ROUTINE TO ADDRESS CHECK SOMETHING
; CALLING . . .
;	MOVE TAC1,<ADDRESS TO BE CHECKED>
;	MOVE TEM,<FIRST PROTECTED ADDRESS>
;	MOVE AC1,<LOWER SEGMENT LENGTH> (I.E., FIRST ADDRESS ABOVE LOWER)
;	MOVE AC2,<UPPER SEGMENT LENGTH> (I.E., FIRST ADDRESS ABOVE UPPER)
;	JSP AC3,ADRCK
; GOES TO ADVXIT IF ERROR

ADRCK:	CAILE	TEM,(TAC1)	;ABOVE PROTECTED JOB DATA AREA?
	JRST	ADVXIT		;NO, ERROR
	CAILE	AC1,(TAC1)	;INSIDE LOWER?
	JRST	(AC3)		;YES
	TRNE	TAC1,400000	;IS IT UPPER SEGMENT ADDRESS?
	CAIG	AC1,(TAC1)	;YES, IS IT WITHIN THE UPPER SEGMENT?
	JRST	ADVXIT		;NO, ERROR
	JRST	(AC3)		;YES
;ADVBFF ROUTINE TO ADVANCE INPUT BUFFER AT INTERRUPT LEVEL.  ADVXIT

;CALL:	PUSHJ	P,ADVBFF
;	EXIT1		RETURN IF NEXT BUFFER IS FULL
;	EXIT2		RETURN IF NEXT BUFFER IS EMPTY
;SETS THE USE BIT (IOUSE:=1) OF THE BUFFER POINTED TO BY THE
;INPUT BUFFER ADDRESS (DEVIAD) OF THE CURRENT DEVICE DATA BLOCK
;AND ADVANCES THE BUFFER ADDRESS TO THE NEXT BUFFER IN THE RING.
;UPON RETURN, SKIPS IF THE NEXT BUFFER IS EMPTY.
;SECOND WORD OF NEXT BUFFER IS ADDRESS CHECKED TO MAKE SURE
;IT IS NOT IN IO PROTECTED PART OF JOB DATA AREA OR ABOVE
;USER AREA
;ALSO END OF BUFFER IS CHECKED TO MAKE SURE NOT ABOVE JOB AREA



↑ADVBFF:AOS	NABFF
	PUSH	P,AC3
	JSP	AC3,PRSET
	SKIPN	TAC1,DEVIAD(DDB)	;IS THERE A BUFFER ADDRESS THERE?
	JRST	ADVXIT			;NO, ERROR EXIT
	JSP	AC3,ADRCK		;IS BUFFER ADDRESS LEGAL?
	XCTR	XW,[MOVEM IOS,-1(TAC1)]	;STORE DEVICE STATUS IN BUFFER
	MOVSI	TAC,IOUSE
	XCTR	XRW,[IORB TAC,(TAC1)]	;TURN ON USE BIT
	MOVEI	TAC1,(TAC)		;ADDRESS OF NEXT BUFFER IN THE RING
	JSP	AC3,ADRCK		;IS SECOND BUFFER'S ADDRESS LEGAL?
	HRRM	TAC1,DEVIAD(DDB)	;YES. STUFF IT IN THE DDB
	XCTR	XR,[SKIPGE TAC1,(TAC1)]	;IS THE NEXT BUFFER FREE?
	JRST	ADVXIT			;NO. STILL BUSY
	HLRZ	TAC1,TAC1		;TAC1←BUFFER SIZE
	ADDI	TAC1,(TAC)		;TAC1←ADDRESS OF END OF THE BUFFER
	JSP	AC3,ADRCK		;ADDRESS CHECK
ADVBF1:	SKIPGE	TAC,JBTSTS(J)		;IF JOB IS NOT RUNNING
	TLNE	TAC,STOPIO		;OR SHUFFLING OR SWAPPING OR COMMAND WAIT
	JRST	ADVXIT			;DO NOT ALLOW THE DEVICE TO GO ON.
	TRNN	IOS,IOCON+740000	;SKIP IF ANY ERRORS OR IOCON MODE.
IFN FTPAGER,<	AOS -11(P)	>	;SUCCESS RETURN.  FALL INTO ADVXIT
IFE FTPAGER,<	AOS -6(P)	>	;SUCCESS RETURN.  FALL INTO ADVXIT
;***  CHANGE THE AOS ABOVE IF THE NUMBER OF THINGS PUSHED BY PRSET IS CHANGED
ADVXIT:	PUSHJ P,POPMAP			;POP BACK MAP AND AC CONTEXT
	POP P,TEM
	POP P,J
	POP P,AC1
	POP P,AC2
	POP P,AC3
	POPJ P,
;UUOACK, UADCK1, UADRCK

;ROUTINE TO ADDRESS CHECK AT UUO LEVEL ONLY
;CALL	HRRZ	AC1,<REL ADR.>
;	PUSHJ	P,UADCK1
;	NEVER RETURNS IF ERROR,STOPS JOB AND PRINTS ERROR
;BAD ADR. IF IN LOC 20-JOBPFI IN JOB DATA AREA
;OR IF ABOVE PROTECTION(USRREL) FOR CURRENT JOB


↑UUOACK:HRRZ	AC1,UUO		;CHECK UUO.
↑UADCK1:TRNN	AC1,777760	;IN USER ACS?
	POPJ	P,		;YES, ADDRESS IS OK
				;FALL INTO UADRCK

;UADRCK ROUTINE TO ADDRESS CHECK AT UUO LEVEL ONLY
;USER ACS ARE ALSO ILLEGAL(ADR IS FOR IO USE LATER AT
;INTERRUPT LEVEL)
;CALL:	HRRZ	AC1,<REL.ADR.>
;	PUSHJ	P,UADRCK
;	NEVER RETURN IF ERROR


↑UADRCK:MOVE	J,JOB(PID)
	CAILE	AC1,JOBPFI 	;IS ADR. IN IO PROT. PART OF JOB DATA AREA?
	JRST	UADCK2		;NO
	PUSH	P,AC1
	MOVE	AC1,UUOPC(J)
	TLNE	AC1,USRMOD
	JRST	UADRER		;USER ISN'T ALLOWED, BUT SAVGET IO NEEDS TO
	POP	P,AC1
	POPJ	P,

UADCK2:	PUSH	P,TAC
	PUSHJ	P,TAC1
	MOVE	TAC,AC1
	PUSHJ	P,ADRTST
	JRST	UADCK3
	POP	P,TAC1
	POP	P,TAC
	POPJ	P,

UADCK3:	POP	P,TAC1
	POP	P,TAC
	JRST	UADRER
;COMCHK - CHECK VALIDITY OF A DUMP MODE COMMAND LIST AT UUO LEVEL
;A DUMP MODE COMMAND LIST IS A LIST OF 0 OR MORE IOWD FORMAT WORDS
; TERMINATED BY A GOTO WORD (LH=0), WHICH POINTS TO ANOTHER LIST
; OF 0 OR MORE IOWD FORMAT WORDS, ETC., UNTIL A GOTO WORD IS ENTIRELY ZERO.
;SINCE MONITOR DOES NOT RESCHEDULE WHEN IN EXEC MODE A MAXIMUM LIST
; OF 100 WORDS IS IMPOSED.

;THIS ROUTINE MUST BE CALLED ONLY WHEN THE APR (MAP) IS SET FOR THIS JOB
;CALL:	MOVE	UUO,<RELATIVE ADDRESS OF FIRST COMMAND>
;	PUSHJ	P,COMCHK
;	<ADDRESS CHECK>		;NO ERROR ROUTINE IS CALLED BY COMCHK
;	<OK>			;TOTAL -WC IS RETURNED IN DAT
;				;ADDRESS OF FIRST IOWD (LH NOT 0) IN UUO


↑COMCHK:
	PUSH	P,UUO		;SAVE POINTER TO LIST
	PUSH	P,AC2
	PUSH	P,AC3		;JS
	PUSH	P,UCHN
	HLRZ	UCHN,JBTPAG(J)
	LSH	UCHN,=9		;UCHN←NUMBER OF WORDS IN LOWER
	MOVEI	AC1,JOBPFI	;HIGHEST LOC PROTECTED FROM IO IN JOB DATA AREA
	MOVE	AC2,UUOPC(J)
	TLNN	AC2,USRMOD	;IF THIS A MONITOR CALL, THEN
	MOVEI	AC1,JOBSAV	;     HIGHEST LOCATION NOT USED BY SAVGET IO
	SETZB	DAT,AC2		;CLEAR WORD COUNT AND ADDRESS OF FIRST IOWD
	MOVEI	J,100		;ONLY 100 LISTS
	JRST	COMCK1

COMCK0:	HRR	UUO,TAC1		;CHANGE COMMAND LIST POINTER ON GO TO WORD
	HRRZ	TAC,UUO			;CHECK JUMP ADDRESS
	CAILE	TAC,JOBPFI		;ADR ABOVE PROTECETED AREA?
	CAIL	TAC,(UCHN)		;AND WITHIN USER'S CORE?
	JRST	COMCKE			;ADDRESS ERROR.
COMCK1:	SOJLE	J,COMCKE		;JUMP IF WE EXCEED 100 WORDS FETCHED
	XCTR	XR,[SKIPN TAC1,(UUO)]	;GET NEXT IOWD.
	JRST	COMCK2			;END OF LIST.
	TLNN	TAC1,-1			;IS IT A GO TO WORD?
	JRST	COMCK0			;YES.  INTERPRET JUMP COMMANDS
	HLRO	AC3,TAC1		;NO.  SAVE NEGATIVE WORD COUNT
	HRRZ	TAC1,TAC1		;GET LOWEST ADDRESS-1
	CAIGE	TAC1,(AC1)		;ABOVE LOWEST PROTECTED ADDRESS?
	JRST	COMCKE			;NO.  ERROR.
	SUB	TAC1,AC3		;COMPUTE LAST LOCATION
	CAIL	TAC1,(UCHN)		;IN BOUNDS?
	JRST	COMCKE			;NO.  ERROR.
	SUB	DAT,AC3			;ACCUMULATE -WC
	SKIPN	AC2			;IS THIS THE FIRST IOWD IN LIST?
	MOVE	AC2,UUO			;YES. SAVE ITS ADDRESS IN AC2
	AOJA	UUO,COMCK1		;FETCH NEXT IOWD

COMCK2:	SKIPE	AC2			;ARE THERE ANY IOWDS WITH LH NOT 0?
	MOVE	UUO,AC2			;YES, POINT UUO TO FIRST SUCH IOWD.
					;  OTHERWISE, UUO POINTS TO A ZERO.
	POP	P,UCHN
	POP	P,AC3	
	POP	P,AC2
	JRST	TPOPJ1			;REMOVE SAVED UUO AND SKIP RETURN

COMCKE:	POP	P,UCHN
	POP	P,AC3			;ERROR RETURN.
	POP	P,AC2
	POP	P,UUO
	POPJ	P,			;ERROR RETURN
;DMPCMD - FETCH NEXT IOWD FROM A DUMP MODE COMMAND LIST AND ADDRESS CHECK
;CLOBBERS AC1,AC2,AC3, (CALLED BY IMPSER, DSKSER)

;CALL AT UUO LEVEL, OR WITH APR (MAP) SETUP FOR THIS USER:
;	MOVE	UUO,<ADDRESS OF COMMAND LIST>
;	PUSHJ	P,DMPCMD
;	<END OF LIST>
;	<OK RETURN.>	;UUO POINTS TO CURRENT IOWD FROM COMMAND LIST
;			;TAC1 = RELATIVE STARTING ADDRESS, + BIT 0 IF READONLY
;			;TAC = -WC
;ON ERROR, THIS ROUTINE DOES NOT RETURN, BUT CALLS ADRERR.
;UPPER SEGMENT AND SETPR2 ADDRESSES ARE OK.

DMPTCH:	HRR	UUO,TAC1		;HERE ON JUMP WORD.  UUO←NEW ADDRESS
↑DMPCMD:XCTR	XR,[SKIPN TAC1,(UUO)]	;GET NEXT COMMAND WORD.
	POPJ	P,			;ZERO TERMINATES
	TLNN	TAC1,-1			;SKIP IF THERE IS A WORD COUNT
	JRST	DMPTCH			;WC=0, THIS IS A JUMP WORD
	MOVEI	TAC,1(TAC1)		;USER-RELATIVE STARTING ADDRESS.
	PUSH	P,TAC			;SAVE IT.
	HLRO	TAC,TAC1		;TAC←-WC
	HRRZ	TAC1,TAC1		;FIRST ADDRESS-1
	SUB	TAC1,TAC		;TAC1←ENDING ADDRESS
	TLNN	TAC1,-1			;SKIP IF ENDING ADDRESS .GT. 256K
	PUSHJ	P,RELOCA
	JSP	DAT,ADRERR		;ADDRESS ERROR
	MOVE	TAC1,(P)		;GET RELATIVE STARTING ADDRESS
	PUSHJ	P,RELOCB		;CHECK STARTING ADDRESS (MUST BE SAME SEG)
	JSP	DAT,ADRERR		;LOSE.
	HRR	TAC1,(P)		;KEEP WRITE PROTECT BIT AND GET
	SUB	P,[1,,1]		;  STARTING ADDRESS.  
	JRST	CPOPJ1			;RETURN.  TAC=-WC. TAC1=USER STARTING ADDR
;ASSASG	ASSIGN DEVICE IF UNASSIGNED
;CALL:	MOVE	J, JOB NUMBER
;	MOVE	DDB, ADDRESS OF DDB
;	MOVEI	TAC1, EITHER ASSPRG OR ASSCON
;	PUSHJ	P, ASSASG
;	CAN'T	ASSIGN RETURN
;	DEVICE ASSIGNED RETURN


↑ASSASG:
IFN FTDEVLUP,<
	MOVE	TAC,JBTPRV(J)
	TLNE	TAC,LUPPRV		;LOCAL USER?
	JRST	ASSAS3			;YES. BYPASS TEST
	MOVE	TAC,DEVCMR(DDB)
	TLNE	TAC,DEVLUP		;REQUIRES LOCAL USER STATUS?
	POPJ	P,			;YES.  FAIL.
>;FTDEVLUP
ASSAS3:	MOVE	TAC,DEVCMR(DDB)
	TLNN	TAC,DEVSHR		;SHARABLE DEV?
	JRST	ASSAS2			;NO
	HRRZ	TAC,DEVSER(DDB)
	PUSHJ	P,DGETDD(TAC)		;YES - MAKE A NEW DDB
	AOS	(P)
	JRST	ASSAS0			;Can't be a TTY if it's sharable

ASSAS4:	IORM	TAC1,DEVMOD(DDB)	;DDB IS ALREADY OURS
	JRST	CPOPJ1

ASSAS2:	LDB	TAC,PJOBN
	CAIN	TAC,(J)			;IS THIS DDB OURS ALREADY?
	JRST	ASSAS4			;YES
ASSAS1:	MOVE	TAC,[TTYATC,,ASSCON!ASSPRG]
;	CONO	PI,SCNOFF		;TURN SCANNER OFF
	OFFSCN				;TURN OFF SCANNER CHANNEL
	TDNE	TAC,DEVMOD(DDB)		;ONE LAST CHECK
	JRST	SCNONJ			;OOPS - EATEN AWAY FROM UNDER US
	PUSHJ	P,ASSAS0
;	CONO	PI,SCNON		;TURN SCANNER CHAN. BACK ON
	ONSCN				;TURN ON SCANNER CHANNEL
	JRST	CPOPJ1

ASSAS0:	DPB	J,PJOBN			;NO, STORE JOB NUMBER
	IORM	TAC1,DEVMOD(DDB)	;SET ONE OF ASSIGN BITS
	MOVSI	TAC,DVTTY
	TDNN	TAC,DEVMOD(DDB)		;SKIP IF ASSIGNING A TTY
	POPJ	P,			;NOT A TTY
	PUSH	P,AC1
	LDB	TAC,PUNIT
	SKIPGE	TTYTAB(TAC)		;SKIP IF COMBIT IS NOT SET
	SOS	COMCNT			;CLEAR COMMAND COUNT
	MOVSI	AC1,COMBIT!DLYBIT!PAUSEB  ;NO MONITOR COMMANDS FOR THIS GUY NOW
	ANDCAM	AC1,TTYTAB(TAC)		;AND CLEAR COMMAND READY BITS, ETC.
	POP	P,AC1
	POPJ	P,
;FNDDDB, DEVSRC, DEVLG, DEVPHY
	
;FIND THE DDB, GIVEN SIXBIT NAME OR CHANNEL NUMBER.
↑FNDDDB:TLNE	TAC,770000		;IS IT NAME OR #?
	JRST	DEVSRC			;NAME.
	CAMG	TAC,USRHCU(PID)		;LEGAL CHANNEL?
	SKIPN	DDB,USRJDA(TAC)		;GET DDB POINTER, IF ANY
	POPJ	P,			;LOSE
	JRST	CPOPJ1

;ROUTINE TO SEARCH FOR A DEVICE, GIVEN THE SIXBIT NAME
;CALL:	MOVE	J,<JOB NUMBER>		;(FOR LOGICAL NAMES)
;	MOVE	TAC,[SIXBIT .DEVICE NAME.]
;	PUSHJ	P,DEVSRC
;	<NOT FOUND>
;	<FOUND>			;DDB SETUP.

↑DEVSRC:MOVSI	DDB,JLOG	;IF JOB IS NOT LOGGED IN, THEN
	TDNE	DDB,JBTSTS(J)	;  SEARCH ONLY PHYSICAL NAMES (DSK:LOGOUT[1,2])
	PUSHJ	P,DEVLG		;SEARCH LOGICAL NAMES FIRST
	JRST	DEVPHY		;NOT FOUND, SEARCH PHYSICAL NAMES
	JRST	CPOPJ1		;FOUND

↑DEVLG:	HLRZ	DDB,DEVLST	;SEARCH LOGICAL NAMES. BEGINNING OF DDB CHAIN
DEVLP0:	CAME	TAC,DEVLOG(DDB)	;COMPARE WITH LOGICAL NAME
	JRST	DEV0		;NO MATCH
	LDB	TAC1,PJOBN	;DOES THE LOGICAL NAME BELONG TO THIS JOB?
	CAMN	TAC1,J
	JUMPN	TAC,CPOPJ1	;YES, GIVE SUCCESSFUL RET. IF NAME NOT 0
DEV0:	HLRZ	DDB,DEVSER(DDB)	;NO, KEEP LOOKING
	JUMPN	DDB,DEVLP0
	POPJ	P,		;FINISHED AND NOT FOUND

↑DEVPHY:CAMN	TAC,['OPR   ']	;SEARCH PHYSICAL NAMES.   IS IT "OPR"?
	MOVE	TAC,DEVOPR	;YES, CHANGE TO OPERATOR'S TTY
	CAMN	TAC,['SYS   ']	;IS IT "SYS"?
	SKIPA	TAC,SYSTAP	;YES, CHANGE TO SYSTEM TAPE DEVICE NAME
	TDZA	TAC1,TAC1	;NO, CLEAR SYSTEM TAPE FLAG
	MOVEI	TAC1,SYSDEV	;YES, SET SYSTEM TAPE FLAG
	HLRZ	DDB,DEVLST	;SEARCH DEVICE DATA BLOCKS
DEVLP1:	TLO	DDB,(TAC1)	;SET SYSTEM TAPE BIT IF SEARCHING FOR SYS
	CAMN	TAC,DEVNAM(DDB)	;MATCH OF PHYSICAL NAME?
	JUMPN	TAC,CPOPJ1	;YES, GIVE OK RET. IF NAME IS NOT 0
DEVLP2:	HLRZ	DDB,DEVSER(DDB)
	JUMPN	DDB,DEVLP1
	CAME	TAC,['TTY   ']	;IS THIS PUBLIC LOGICAL NAME TTY?
	JRST	DEVLP3		;NO. SEE IF IT'S A SPECIFIC TTY.
	PUSH	P,DAT		;SAVE OUTPUT BYTE POINTER (TTY) OR INIT. ARG. ADR.
	PUSHJ	P,TTYFND	;YES, FIND TTY JOB IS ATTACHED TO
	POP	P,DAT		;RESTORE
	JRST	CPOPJ1		;AND GIVE SUCCESSFUL RETURN

DEVLP3:	PUSH	P,TAC		;SAVE DEVICE NAME IN CASE NOT FOUND
	PUSH	P,DAT		;AND THIS IN CASE IT IS
	PUSHJ	P,GETDDB	;SEE IF TTY DDB
	CAIA
	AOS	-2(P)		;SKIP ON SUCCESS
	POP	P,DAT
	POP	P,TAC
	POPJ	P,
;BUFCLC, BUFCLM  SETUP N-RING IO BUFFER IN USER AREA

;CALL:	PUSHJ	P,BUFCLC
;	<OK RETURN>		;IF MEMORY NOT EXCEEDED

Comment $	Buffer Ring Format

This routine will set up an N buffer ring, where N is taken from the
right half of ac UUO.  The byte pointer PDVBLN into the DDB yields
the <data size of each buffer>+1.  In addition to the one overhead
word implied by PDVBLN, two additional words are needed for each
buffer.  Thus, the size of each buffer (refered to as SIZE+2) is three
more than the data area in the buffer.  (The UUOs UINBF and UOUTBF
enter at BUFCLM with TAC setup to the <data size of the buffer>+1
which is the parameter specified by the user.)

N buffers are set up, (B0, B1, ... B(N-1)).  The address of the first
buffer, B0, is given by the right half of JOBFF.  JOBFF will be 
advanced by N*(SIZE+2) upon return.  User's core size will be expanded
if necessary.

The buffer ring looks like:
B0/
B0+1/		SIZE,,B1+1
		BLOCK	SIZE
B1/
B1+1/		SIZE,,B2+1
	    	BLOCK	SIZE

		....

B(N-1)/
B(N-1)+1/	SIZE,,B0+1
		BLOCK	SIZE


On return, ac BUFPNT will contain IOUSE,,B0+1
and JOBFF will have been increased by N*(SIZE+2)

$

;BUFCLC, BUFCLM

BUFCLC:	LDB	TAC,PDVBLN	;GET BUFFER SIZE IN TAC
BUFCLM:	PUSH	P,AC3		;ALTERNATE ENTRY FOR UINBF, UOUTBF
	XCTR	XR,[HRRZ BUFPNT,JOBFF]
	ADDI	BUFPNT,1	;BUFPNT←FIRST FREE USER LOC+1
	HRRZ	AC3,BUFPNT
	HRL	AC3,TAC		;AC3←(BUFSIZ,,JOBFF+1)
	ADDI	TAC,2		;ADD 2 TO BUFFER SIZE (= ACTUAL SIZE OF BUFFER)
	HRRZ	TAC1,UUO	;GET NUMBER OF BUFFERS
	JUMPG	TAC1,.+2	;SKIP UNLESS NONE WERE REQUESTED. (ME 12-11-72)
	MOVEI	TAC1,2		;GIVE HIM TWO, IF NONE WERE REQUESTED.
	HRRZ	AC1,TAC		;AC1←(SIZE+2)
	IMUL	AC1,TAC1	;AC1←N*(SIZE+2)
	ADDI	AC1,-1(AC3)	;AC1←N*(SIZE+2)+(C(JOBFF)+1)-1 (=NEW JOBFF)
	PUSH	P,AC1		;SAVE NEW VALUE FOR JOBFF
	MOVE	AC1,JOB(PID)
	HLRZ	AC1,JBTPAG(AC1)
	LSH	AC1,=9
	CAMLE	AC1,(P)		;SKIP IF WE HAVE LESS CORE THAN WE NEED
	JRST	BUFC1		;WE HAVE ENOUGH CORE.  GO MAKE BUFFERS.
	MOVE	AC1,(P)		;THIS IS HOW MUCH WE'LL NEED
	PUSH	P,TAC		;NO. SO, SAVE SOME ACS AND GET MORE CORE.
	PUSH	P,UUO
	PUSH	P,TAC1
	PUSH	P,BUFPNT
	PUSH	P,AC3
	PUSH	P,DDB
	PUSH	P,DSER
	MOVE	J,JOB(PID)
	MOVE	TAC,AC1		;HOW HIGH WE NEED.
	MOVEI	UUO,UUO
	PUSHJ	P,UCORE
	JRST	UADRER		;ADDRESS ERROR IF WE CAN'T GET ENOUGH CORE.
	POP	P,DSER
	POP	P,DDB
	POP	P,AC3
	POP	P,BUFPNT
	POP	P,TAC1	
	POP	P,UUO
	POP	P,TAC
	JRST	BUFC1

BUFC2:	HRR	BUFPNT,AC3		;ADVANCE TO NEXT BUFFER.
BUFC1:	ADD	AC3,TAC			;MAKE ADDRESS OF NEXT BY ADDING LENGTH
;BUFPNT=CURRENT BUFFER, AC3=POINTER TO NEXT BUFFER.
	XCTR	XW,[MOVEM AC3,(BUFPNT)]	;PREVIOUS BUFFER POINTS TO NEXT BUFFER
	SOJG	TAC1,BUFC2		;LOOP TO MAKE ENOUGH BUFFERS.
	XCTR	XR,[HRR AC3,JOBFF]	;GET JOBFF
	ADDI	AC3,1			;SIZE,,ADDRESS OF FIRST BUFFER
	XCTR	XW,[MOVEM AC3,(BUFPNT)]	;LINK LAST BUFFER TO FIRST BUFFER
	POP	P,AC1
	XCTR	XRW,[HRRM AC1,JOBFF]	;STORE NEW VALUE OF JOBFF.
	HRRZ	BUFPNT,AC3		;LOAD IN USE BIT AND ADDRESS OF FIRST BUFFER
	HRLI	BUFPNT,IOUSE
	POP	P,AC3
	POPJ	P,
;BUFCLR - CLRBYT - DEVCR - DEVSTU


;BUFCLR - ROUTINE TO CLEAR IO BUFFER IN USER AREA - UUO LEVEL ONLY!
;CALL:	HRRZ	TAC,<REL. ADR. OF 2ND WORD OF USER BUFFER>
;	PUSHJ	P,BUFCLR	;CLEARS THE WC AND DATA AREA OF THE BUFFER
;	<OK RETURN>		;CALLS UADRER ON FAILURE

↑BUFCLR:XCTR	XW,[SETZM 1(TAC)]	;CLEAR WC WORD OF BUFFER.
	XCTR	XLB,[LDB TAC1,[POINT 17,(TAC),17]]	;TAC1←BUFFER SIZE
	ADDI	TAC1,(TAC)		;TAC1←LAST ADDRESS IN BUFFER
	HRL	TAC,TAC			;ADDR,,ADDR
	ADD	TAC,[1,,2]		;<WC WORD ADDR>,,<WC WORD ADDR+1>
	XCTR	XBLTRW,[BLT TAC,(TAC1)]	;ZERO CORE IN USER SPACE.
	POPJ	P,


;CLRBYT - CLEAR RESIDUE OF WORD POINTED TO BY A BYTE POINTER
;CALL:	MOVE	TAC,<BYTE POINTER>
;	PUSHJ	P,CLRBYT
;	EXIT		ALWAYS RETURNS HERE
;CLEARS THE REST OF THE WORD POINTED TO BY THE BYTE POINTER.

↑CLRBYT:LDB	TAC1,[POINT 6,TAC,5]	;SET UP POINTER
	DPB	TAC1,[POINT 12,TAC,11]	;TAC 0-5:=0,TAC 6-12:=P
	MOVEI	TAC1,0
	DPB	TAC1,TAC		;CLEAR BITS 36-P THROUGH 35
	POPJ	P,			;RETURN


;CHECK RING USE BIT TO SEE IF USER HAS ANOTHER BUFFER TO FILL.  UUO LEVEL ONLY!
;CLOBBERS TAC.  SKIPS IF USER HAS SOME FREE BUFFER TO FILL.

↑DEVCR:	HLRZ	TAC,DEVBUF(DDB)		;ADDRESS OF USER'S BUFFER HEADER
	XCTR	XR,[MOVE TAC,(TAC)]	;FETCH POINTER TO CURRENT BUFFER.
	XCTR	XR,[SKIPL (TAC)]	;CHECK THE RING USE BIT.
	JRST	CPOPJ1			;BUFFER IS FREE, LET HIM FILL IT
	POPJ	P,


;SET UP WORD COUNT IN AC2 AND 7-BIT RELATIVE BYTE POINTER TO DATA IN AC3
;DDB MUST BE SET UP.  ROUTINE SKIPS ON SUCCESS, DOESN'T SKIP IF BUFFER IS EMPTY.
;UUO LEVEL ONLY!

↑DEVSTU:HRRZ	AC3,DEVOAD(DDB)			;GET ADDRESS OF USER BUFFER
	XCTR	XR,[SKIPL (AC3)]		;SKIP UNLESS BUFFER IS EMPTY
	POPJ	P,				;BUFFER ALREADY HAS BEEN EMPTIED.
	XCTR	XR,[HRRZ AC2,1(AC3)]		;AC2←BUFFER WC.
	ADD	AC3,[POINT 7,2]			;7 BIT BYTES RELATIVE TO BUFFER.
	JRST	CPOPJ1				;SKIP ON SUCCESS
;IOALL, IOALLR, IORELS,IOWAIT

;THE SIGN BIT IN THE ARGUMENT TO IOALL (USED BY IOWAIT) PREVENTS IOALLP
;FROM RELEASING THE IO PDL, WHICH WOULD OTHERWISE HAPPEN IF IT CONTAINS
;ONLY UNUSED CHANNELS (NO DDB POINTER).  AS OF 8/27/75 THE ONLY CALLERS
;OF IOALL ARE THE TWO BELOW AND ONE ON THE NEXT PAGE WHICH CALLS RELEA5
;SO IOWAIT IS THE ONLY USER WHO DOESN'T WANT TO RELEASE THE PDL.  -- BH

;NOTE FURTHER THAT IOALL (AND, HENCE ITS CALLERS, IORELS, IOKILL, IOWAIT)
;CALLS ANYACT WHICH WILL SUSPEND SPACEWAR.  YOU'D BETTER MAKE SURE THAT
;ALL CALLERS REINSTATE SPACEWAR WHEN THEY CAN (ONLY RELEVANT FOR IOWAIT,
;SINCE ALL OTHER CALLERS ARE DOING RESET OR EXIT).

;IOALL - DO IO FOR ALL DEVICES ASSIGNED TO JOB.
;CALL	MOVEI	TAC,<ADR. OF IO SUBR>
;	PUSHJ	P,IOALL


↑IOWAIT:SKIPA	TAC,[400000,,WAIT1]	;WAIT FOR ALL DEVICES TO BE INACTIVE
↑IORELS:MOVEI	TAC,RELEA3		;RELEASE ALL IO DEVICES. FALL INTO IOALL
IOALL:	PUSH	P,TAC			;SAVE SUBROUTINE CALL
	SETZB	UCHN,UUO		;START WITH USER CHANNEL 0
	SKIPL	DDB,USRHCU(PID)		;IS THIS NEGATIVE?
	JRST	IOALL1			;NO. - NORMAL
	SETZM	USRHCU(PID)		;SAVGET ACTIVE. RELEASE DEVICE ANYWAY!
	JRST	IOALL2

IOALL1:	CAMLE	UCHN,USRHCU(PID)	;IS IT GREATER THAN HIGHEST CHAN. USED?
	JRST	IOALLP			;YES. DO THE IOPDL NEXT
	SKIPN	DDB,USRJDA(UCHN)	;GET NEXT DDB ADR., IS IT IN USE?
	AOJA	UCHN,IOALL1		;NO, KEEP GOING
IOALL2:	MOVE	IOS,DEVIOS(DDB)
	DPB	UCHN,PUUOAC
	MOVE	DSER,DEVSER(DDB)	;SETUP ADR. OF DEV. DISP. TABLE
	LDB	J,PJOBN			;DOES THIS DDB BELONG
	CAME	J,JOB(PID)		;TO THIS JOB?
	AOJA	UCHN,IOALL1		;NO. DON'T BOTHER WITH THIS OTHER
	PUSH	P,UCHN			;JAM CLOBBERS THIS IN IMPSER
	PUSHJ	P,@-1(P)		;CALL IO SUBR
	POP	P,UCHN
	MOVE	J,JOB(PID)		;KEEP THIS HONEST
	AOJA	UCHN,IOALL1		;INCREMENT USER CHAN. NO.

IOALLP:	SKIPL	UCHN,JBTIOP(J)		;GET IO PDL POINTER
	JRST	IOALLW			;NONE THERE. 
IOALP1:	SKIPN	DDB,(UCHN)		;SKIP FLUSHED CHANNELS
	JRST	IOALP2
	EXCH	DDB,USRJDA
	MOVEM	DDB,(UCHN)		;EVERYONE MUST LIVE SOMEWHERE
	MOVE	DDB,USRJDA
	PUSH	P,UCHN
	MOVEI	UCHN,0
	MOVE	IOS,DEVIOS(DDB)
	DPB	UCHN,PUUOAC
	MOVE	DSER,DEVSER(DDB)	;SETUP ADR. OF DEV. DISP. TABLE
	LDB	J,PJOBN			;DOES THIS DDB BELONG
	CAMN	J,JOB(PID)		;TO THIS JOB?
	PUSHJ	P,@-1(P)		;YES, CALL THE SUB.
	MOVE	J,JOB(PID)		;KEEP THIS HONEST
	POP	P,UCHN
	MOVE	DDB,(UCHN)
	EXCH	DDB,USRJDA
	MOVEM	DDB,(UCHN)
	JUMPE	DDB,IOALP2
	MOVSI DDB,400000		;SET FLAG TO NOT RETURN JBTIOP
	IORM DDB,(P)
IOALP2:	ADD	UCHN,[2,,2]
	JUMPL	UCHN,IOALP1
	SKIPG	(P)			;SKIP IF WE SHOULD RETURN THE IOPDL
	JRST	IOALLW			;DON'T RETURN THE IOPDL
	PUSH	P,AC1
	HRRZ	AC1,JBTIOP(J)		;FLUSH IO STACK
	SETZM	JBTIOP(J)
	PUSHJ	P,FSGIVE
	POP	P,AC1
IOALLW:	PUSH	P,AC2
	PUSH	P,TAC1
	JRST	IOALLY

IOALLX:	PUSHJ	P,WSCHED		;DELAY A WHILE
IOALLY:	PUSHJ	P,ANYACT		;MAKE SURE ALL IO HAS REALLY STOPPED
	JRST	IOALLX
	POP	P,TAC1
	POP	P,AC2
	JRST	TPOPJ			;FLUSH ARGUMENT ADDRESS AND RETURN.


;HERE TO CHASE THROUGH THE DDB LIST AND CALL RELEA5 FOR ANY DDB OF OURS
;CALLED FROM IOKILL, FINISH COMMAND.
;THIS IS A KLUDGE TO RECTIFY THE PROBLEM OF DDBS GETTING LOST FROM JOBJDA
;DUE TO SWAPPING, PARITY ERRORS, ETC.

IOALLR:	PUSH	P,USRJDA
	MOVEI	DDB,DEVLST-DEVSER
IOALR1:	HLRZ	DDB,DEVSER(DDB)
	JUMPE	DDB,IOALR3
IOALR2:	LDB	J,PJOBN
	CAME	J,JOB(PID)
	JRST	IOALR1
	MOVE	UCHN,DEVMOD(DDB)
	TRNN	UCHN,ASSPRG		;ASSIGNED BY PROGRAM?
	JRST	IOALR1			;NO
	MOVEM	DDB,USRJDA
	MOVEI	UCHN,0
	DPB	UCHN,PUUOAC
	MOVE	IOS,DEVIOS(DDB)
	MOVE	DSER,DEVSER(DDB)	;SETUP ADR. OF DEV. DISP. TABLE
	PUSH	P,DSER			;SAVE DSER
	PUSHJ	P,RELEA5		;RELEASE THIS DDB
	POP	P,DDB
	HLRZ	DDB,DDB			;ADDRESS OF NEXT DDB
	JUMPN	DDB,IOALR2		;CONTINUE THROUGH THE DDB CHAIN.
IOALR3:	POP	P,USRJDA
	MOVE	J,JOB(PID)		;KEEP THIS HONEST
	POPJ	P,
;IOKILL, CLRUSR

;KILL ALL DEVICES(RELEASE WITHOUT WAITING FOR DEVICE INACTIVE)

↑IOKILL:MOVEI	TAC,RELEA5
	PUSHJ	P,IOALL		;RELEASE ALL DEVICES WITHOUT WAITING
	PUSHJ	P,IOALLR	;CHASE THRU DDB LIST AND RELEASE ANY OTHERS

;ROUTINE TO CLEAR PROTECTED JOB DATA AREA IN MONITOR
;AND RECLAIM FREE AREA ABOVE USER PROGRAM FOR IO BUFFERS

	XCTR	XR,[HLRZ TAC,JOBSA]	;RESET FIRST FREE LOC. FOR THIS JOB
	XCTR	XW,[MOVEM TAC,JOBFF]
↑CLRUSR:XCTR	XW,[SETZM JOBENB]	;INITIALIZE USER FOR NO TRAPS ENABLED
	MOVEI	TAC,USRLO1		;FIRST LOC+1 TO CLEAR
	HRLI	TAC,USRLO		;FIRST LOC.
	SETZM	USRLO
	BLT	TAC,USRHI
	SETZM	USRHCU			;CLEAR HIGHEST USER IO CHAN. IN USE
	POPJ	P,

;FLAG DEVICE AS ACTIVE  - ORACT, SETACT, CLRACT, STOIOS
;CALL	MOVE IOS,IO STATUS BITS
;	MOVE DDB,ADDRESS OF DEVICE DATA BLOCK
;	PUSHJ	P,SETACT
;CALLED BY ALL IO SERVICE ROUTINES AT UUO AND INTERRUPT LEVELS

LOSYS


↑ORACT:	ERRSPW				;JUMP TO SPWERR IF SPACEWAR LEVEL
	TRO	IOS,IOACT
	IORB	IOS,DEVIOS(DDB)
	JRST	ORACT1

↑SETACT:ERRSPW
	TROE	IOS,IOACT
	JRST	STOIOS
	TLZA	IOS,IOW
↑CLRACT:TRZ	IOS,IOACT
↑STOIOS:MOVEM	IOS,DEVIOS(DDB)
ORACT1:	LDB	TAC,PDVTIM		;GET NO. OF SECONDS
	DPB	TAC,PDVCNT		;TO WAIT BEFORE DEVICE IS HUNG
	POPJ	P,

HISYS
;DEVCHK  - HUNG TIMEOUT 
;UPDATES HUNG COUNT FOR EACH DEVICE.
;DISPATCHES TO DEVICE SERVICE IF COUNT IS EXHAUSTED.

↑DEVCHK:MOVEI	TAC,JIFSEC	;RESET HUNG DEVICE CHECK TIME
	MOVEM	TAC,HNGTIM	;TO CHECK ONCE A SECOND
	SOSN	DSKHNG		;SEE IF DISK IS HUNG THIS WAY!
	PUSHJ	P,DSKDSP+DHNG	;CALL DISK HUNG ROUTINE

	SKIPLE	IOPHCT		;SKIP IF IOP IS INACTIVE
	SOSE	IOPHCT		;IOP ACTIVE. COUNT DOWN AND SKIP IF HUNG.
	JRST	.+2		;IOP IDLE OR NOT HUNG
	PUSHJ	P,IOPHNG	;KICK IOP

	MOVEI	DDB,PTRDDB	;SKIP DSK AND UDP
DEVCK0:	MOVE	IOS,DEVIOS(DDB)	;IS DEVICE ACTIVE?
	TRNE	IOS,IOACT
	JRST	DEVCK3		;YES.
	MOVE	DAT,DEVCMR(DDB)	;PULL IN EXTRA DEVCHR BITS
	TLNE	DAT,DEVIBF	;DOES THIS DEVICE HAVE AN INTERNAL BUFFER?
	TLNN	IOS,DEVSBB	;IF IT DOES, IS IT BUSY?
	JRST	DEVCK1		;NOT BUSY, IGNORE DEVICE
DEVCK3:	LDB	TAC,PDVCNT	;YES, DECREMENT HUNG COUNT
	SOJL	TAC,DEVCK1	;0 MEANS IGNORE DEVICE
	DPB	TAC,PDVCNT	;NOW REPLACE IT IN THE DDB
	JUMPN	TAC,DEVCK1	;HAS COUNT GONE TO 0?
	MOVE	DSER,DEVSER(DDB);YES, GET DISPATCH TABLE ENTRY
	PUSH	P,DDB
	PUSHJ	P,DHNG(DSER)	;DISPATCH TO SERVICE ROUTINES TO UNHANG DEVICE
	PUSHJ	P,DEVHNG	;PRINT ERROR MESSAGE AND STOP JOB
	POP	P,DDB		;DO NOT PRINT MESS. AND STOP JOB RETURN
DEVCK1:	HLRZ	DDB,DEVSER(DDB)
	CAIE	DDB,TTYLST	;DON'T DO TTY'S
	JUMPN	DDB,DEVCK0
	POPJ	P,

;IOSETC

;CALLED FROM INPUT AND OUTPUT UUOS.

;CALLING SEQUENCE
;	MOVE	JBUF,<ADDRESS OF USER'S BUFFER HEADER>
;	MOVE	TAC1,<ADDRESS OF BUFFER>
;	MOVE	ITEM,<BUFFER WC>
;	PUSHJ	P,IOSETC
;	EXIT		ALWAYS RETURNS HERE

;SETS JBFPTR18-35:=C(TAC1 18-35)
;JBFCTR:=C(ITEM)*[WORD LENGTH/BYTE SIZE]
;WHERE	WORD LENGTH:=36 DECIMAL
;	BYTE SIZE:=C(JBFPTR6-11)
;	[X]:= INTEGER PART OF X




↑IOSETC:MOVSI	TAC,7777		;CLEAR BYTE POINTER IN BUFFER HEADER.
	XCTR	XRW,[ANDM TAC,1(JBUF)]	;CLEAR ALL BUT BYTE SIZE, INDEX.
	XCTR	XRW,[HRRM TAC1,1(JBUF)]	;SET ADDRESS PART.
	XCTR	XRW,[AOS 1(JBUF)]	;ADVANCE ADDRESS TO WC WORD
	XCTR	XLB,[LDB TAC1,[POINT 17,(TAC1),17]]	;GET BUFFER SIZE
	CAILE	ITEM,-1(TAC1)		;IS THE DATA WC TOO BIG?
	MOVEI	ITEM,-1(TAC1)		;YES.  REDUCE IT TO WHAT CAN FIT IN BUFFER
	XCTR	XLB,[LDB TAC1,[POINT 6,1(JBUF),11]]	;USER'S BYTE SIZE.
	MOVEI	TAC,44			;COMPUTE ITEM COUNT FROM NUMBER OF DATA
	IDIV	TAC,TAC1		;  WORDS*NUMBER OF BYTES/WORD USING THIS
	IMUL	ITEM,TAC		;  BYTE SIZE.
	XCTR	XW,[MOVEM ITEM,2(JBUF)]	;STORE ITEM COUNT IN USER'S BUFFER HEADER
	POPJ	P,			;EXIT TO USER.
;SETIOS, SETMOD - (SETSTS UUO)  SET DEVICE STATUS WORD FROM UUO, SETUP IOS


;SETSTS UUO

↑SETIOS:PUSHJ	P,WAIT1
	MOVE	TAC1,DEVCMR(DDB)
	TLNE	TAC1,DEVSTS		;CALL DEVICE SERVICE AT STATUS CHANGE?
	PUSHJ	P,DSETST(DSER)		;YES. DO IT.  (DSK,UDP)
	PUSHJ	P,SETMOD
	JRST	ILLMOD
	POPJ	P,

;HERE FROM INIT (OPEN) UUO

↑SETMOD:LDB	TAC1,[POINT 4,UUO,35]		;GET DEVICE DATA MODE
	MOVEI	TAC,1				;AND CHECK FOR LEGALITY
	LSH	TAC,(TAC1)
	TDNN	TAC,DEVMOD(DDB)
	POPJ	P,				;ILLEGAL MODE.
	TRZ	UUO,IOACT			;LET USER SET ALL BITS EXCEPT IOACT
	HRRM	UUO,DEVIOS(DDB)
	JRST	CPOPJ1
SUBTTL	RUNCSS	4 AUG 67	;PHOLD, HOLD, ESTOP, ESTOP2, MSTOP

LOSYS

;RUN CONTROL IS A COLLECTION OF ROUTINES WHICH SET AND CLEAR BITS IN
;THE JOB STATUS WORD OF ALL (ANY) JOBS SO THAT THE SCHEDULER WILL START
;AND STOP THEM ACCORDINGLY.

;COMMON ERROR STOPPING ROUTINES
;CALLED AT ANY LEVEL (UUO, CLK, OR INTERRUPT)

;CALL:	MOVE	J,JOB CAUSING ERROR OR BEING STOPPED
;	MOVE	DDB,<ADRRESS OF THAT JOB'S TTY DDB>
;	MOVE	DAT,<BYTE POINTER TO LAST CHAR IN TTY OUTPUT BUFFER>
;	PUSHJ	P,PHOLD
;OR	PUSHJ	P,HOLD
;OR	PUSHJ	P,ESTOP

;	NEVER RETURN IF CALLED AT UUO LEVEL


;PHOLD - PRINT MESSAGE THEN
;HOLD - STOP JOB, SET ERROR BIT, AND ADD "↑C<CRLF><CRLF><PERIOD>

;CALL:	MOVEI	TAC,<ADDR. OF MESSAGE>
;	PUSHJ	P,PHOLD


↑PHOLD:	PUSHJ	P,CONMES	;MOVE MESSAGE TO TTY OUTPUT BUFFER.
↑HOLD:	PUSHJ	P,PRCRCC
	SKIPN	PID		;SKIP TTYSTC IF THIS IS P2
	PUSHJ	P,TTYSTC	;SET TTY TO MONITOR MODE. START TTY.  ESTOP

MSTOP:
↑ESTOP:	JUMPE	J,CPOPJ			;STOP USER. FLAG ERROR STOP
	ERRSPW				;IF SPACEWAR, JUMP TO SPWERR
	MOVSI	TAC,JACCT
	ANDCAM	TAC,JBTSTS(J)		;NO LONGER AN ACCOUNTING PROGRAM
	MOVSI	TAC,JLOG
	TDNE	TAC,JBTSTS(J)		;IS THIS JOB REALLY LOGGED IN?
	JRST	ESTOP4			;YES, PROCEED NORMALLY
	SKIPN	JBTPAG(J)
	JRST	ESTOP4			;NOT LOGGED IN AND NO CORE.
	CONSZ	PI,77400		;NOT LOGGED IN.  ARE WE AT UUO LEVEL
	JRST	ESTP3B			;NOT UUO LEVEL. USE MONITOR JOB TO KILL JOB
	SKIPE	INTACT(PID)
	JRST	ESTP3C			;AT UUO LEVEL AND USER INT LEVEL
	JRST	JOBKL			;AT UUO LEVEL, KILL JOB FROM HERE.

ESTP3B:	CAMN	J,JOB(PID)		;PI IN PROGRESS.  JLOG OFF
	SKIPN	INTACT(PID)
	JRST	ESTOP3			;NOT CURRENT JOB AND AT USER INT LEVEL
ESTP3C:	PUSHJ	P,ESTOP3		;SET JLOG, SETUP MONJOB,
	SETOM	ESTINT			;TELL CH7 WE'RE COMING FROM ESTOP
	JRST	WSCHD2			;GET INTO CHANNEL 7

ESTOP3:	IORM	TAC,JBTSTS(J)	; FINISH LOGGING IN JOB SO WE WON'T GET HERE AGAIN
	MOVE	TAC,['-DIE!-']
	MOVEM	TAC,JOBNAM(J)	;(EVEN IF WE FAIL TO KILL THIS, WE GET NEW PHANTOM)
	PUSHJ	P,INTKIL	;NO MORE INTERRUPTS PLEASE.
	PUSHJ	P,MAPSET	;SETUP MAP FOR THIS JOB
	MOVEI	TAC1,JOBKL	;ADDRESS OF MONITOR JOB TO RUN AND KILL JOB.
	JRST	MONJOB		;CAUSE MONITOR JOB TO BE STARTED. RESTORE MAP. POPJ


;GET HERE FROM JOBKL(KSTOP),  ALSO SET JOB TO NOT RUNNABLE FROM CORE 0 - CORE 1.
↑ESTOP2:JUMPE	J,CPOPJ			;IS THIS ERROR IN JOB 0?
	ERRSPW				;IF SPACEWAR JOB, JUMP TO SPWERR
	MOVSI	TAC,JACCT		;ZERO OUT ACCT BIT
	ANDCAM	TAC,JBTSTS(J)		;SO IF LOGIN BLOWS, WE CAN KILL IT!!
ESTOP4:	MOVSI	TAC,JERR		;SET ERROR BIT
	IORB	TAC,JBTSTS(J)		;SO JOB CAN NOT CONTINUE(CONT COM.)
	TRNN	TAC,JLOCK		;IS THIS JOB LOCKED IN?
	JRST	ESTOP5			;NO
	MOVSI	TAC,UNLOKC		;MAKE A CLOCK REQUEST TO UNLOCK IT.
	HRR	TAC,J
	CONO	PI,PIOFF
	IDPB	TAC,CLKQ		;USE DPYSER CLOCK QUEUE.
	CONO	PI,PION
ESTOP5:	PUSHJ	P,INTKILL		;CLEAR THE USER INTERRUPT SYSTEM
	CAME	J,STUSER		;SYSTEM TAPE USER?
	JRST	ESTOP6			;NO
	MOVSI	TAC,'SYS'		;FIND SYS DDB
	PUSHJ	P,DEVSRC
	HALT	ESTOP6			;CAN'T HAPPEN.
	PUSHJ	P,RELEA9		;RELEASE SYSTEM TAPE WITHOUT WAITING
ESTOP6:	CAMN	J,JOB(PID)		;IF NOT CURRENT JOB
	CONSZ	PI,77400		;OR AT INTERRUPT LEVEL
	JRST	STOP1			;JUST GO TO STOP1 AS ALWAYS
	SKIPE	INTACT(PID)
	JRST	STOP1			;ALSO IF FROM USER INT
	PUSHJ	P,SETSTP		;OTHERWISE PUT HIM IN STOPQ, ETC.
	MOVE	TAC,UUOPC(J)
	TLNN	TAC,USRMOD
	TDZA	TAC,TAC			;GIVE HIM 0 IF PC WAS EXEC
	HRRI	TAC,-1(TAC)		;ELSE BACK IT UP TO LOSING UUO
	MOVEM	TAC,UUOPC(J)
	JRST	USRX4A			;CATCH HIM ON HIS WAY OUT OF UUOCON.
;STOP1, SETSTP - STOP A JOB FROM BEING SCHEDULED

;CALL:	MOVE	J,<JOB NUMBER>
;	PUSHJ	P,STOP1
;	EXIT	;RETURN HERE IMMEDIATELY, IF CALLED FROM HIGHER
;PRIORITY PI CHANNEL THAN CLK(LOWEST), OTHERWISE WHEN JOB IS RUNABLE
;CALLED FROM COMMAND DECODER WHEN <CONTROL>C TYPED IN BY USER

↑STOP1:	PUSHJ	P,SETSTP	;SET IT TO STOPQ, ETC
	CAME	J,JOB(PID)	;IS THIS JOB CURRENT USER
	JRST	REQUE		;NO, SET REQUE JOB FLAG
	SKIPE	INTACT(PID)
	SETOM	ESTINT		;TELL CH7 WE'RE COMING FROM ESTOP
	JRST	WSCHD2		;YES, CALL WSCHED TO WAKE CH7

;THIS ROUTINE DOES ALL THE WORK OF STOPPING THE GUY WITHOUT ACTIVATING CH7
↑SETSTP:MOVSI	TAC,RUN
	CONO	PI,PIOFF
	CAME	J,STUSER	;IS THIS JOB CURRENTLY USING THE SYSTEM TAPE?
	TDNN	TAC,JBTSTS(J)	;NO, IS RUN BIT OFF IN JOB STATUS WORD
	JRST	STOP1A		;YES
	ANDCAM	TAC,JBTSTS(J)	;NO, SO CLEAR IT
	CONO	PI, PION
	MOVM	TAC,JOBQUE(J)	;GET JOB WAIT QUEUE CODE(IF ANY)
	CAIG	TAC,MAXQ	;DOES STATE HAVE Q ?
	SOSL	REQTAB(TAC)	;YES. REDUCE IT.
	JRST	STOP1A		;NO
	SOSGE	AVALTB(TAC)	;YES REDUCE  COUNT
	SETZM	AVALTB(TAC)	;CLEAR AVAL FLAG IF NO ONE WAITING
STOP1A:	CONO	PI,PION		;MAKE SURE PI ON
	MOVE	TAC1,J
	PUSHJ	P,CORSGT	;GET CORE SIZE OF THIS JOB (INTO TAC1)
	SKIPN	TAC1		;SKIP IF THERE'S CORE ASSIGNED TO THIS JOB
	TROA	TAC1,NULQ	;NO CORE ASSIGNED - REQUE JOB TO NULL QUEUE
	MOVEI	TAC1,STOPQ	;CORE ASSIGNED - THIS JOB GOES TO STOPQ
	MOVNM	TAC1,JOBQUE(J)	;STORE QUEUE CODE.
	CAMN	J,LOCKNO	;WERE WE WAITING TO BE LOCKED IN?
	SETZM	LOCKNO		;YES. WELL, THERE'S NO ONE THERE ANYMORE.
	POPJ	P,		;↑C, CONTINUE WILL NOT UNLOCK A JOB!
;DLYCOM, NOCORQ, MONJOB

HISYS

;REQUE JOB WHICH HAS HAD A COMMAND TYPED
;WHICH NEEDS CORE AND THE CORE IMAGE IS ON THE DISK.
;OR IS IN CORE AND HAS ACTIVE DEVICES.
;CALLED FROM COMMAND DECODER
;CALL:	MOVE J,JOB NO.
;	PUSHJ P,DLYCOM


↑DLYCOM:MOVSI TAC,CMWB			;SET COMMAND WAIT BIT IN JBTSTS
	IORB TAC,JBTSTS(J)		;(NOTE: IF JNA IS OFF, CMWB KEEPS SLOT)
	TLNN TAC,SWP			;DO WE NEED HIM IN??
	POPJ P,				;IN ALREADY
	MOVSI TAC,COMSNB		;ADD TO SWAPIN LIST
	JRST SETSIN


;NOCORQ - PUT A JOB IN NULQ, DELETE SWAPIN REQUESTS. RELEASE SWAP SPACE AND JBTMAP

↑NOCORQ:PUSHJ P,FLUSIN		;FLUSH FROM SWAP IN LIST

IFN FTPAGER,<
	CAME J,JOB(PID)		;IS THIS THE CURRENT JOB?
	JRST NOCOR1		;NO.
	PUSH P,J
	MOVEI J,0
	PUSHJ P,PAGSET		;SETUP PAGER TO REFERENCE NOTHING!
	POP P,J
NOCOR1: SKIPE AC1,JBTMAP(J)
	PUSHJ P,GIVMAP		;RETURN THE PAGE MAP TO FREE STORAGE
	SETZM JBTMAP(J)
>;FTPAGER

	SKIPGE JBTSWP(J)	;SKIP IF NO SPACE ASSIGNED ON LIBRASCOPE
	PUSHJ P,FBRELS		;RELEASE FASTBAND STORAGE IF ANY ASSIGNED
	SETZM JBTSWP(J)		;NO CORE ASSIGNED ON THE LIBRASCOPE
	SETZM JB2SWP(J)
	MOVEI TAC,NULQ		;NO JOB NUMBER OR NO CORE QUEUE
	MOVNM TAC,JOBQUE(J)
	JRST REQUE


;SETUP MONITOR JOB TO RUN LATER AT UUO LEVEL
;CALLED BY COMMANDS WHICH MAY OR MAY NOT NEED TO
;RUN MONITOR JOB DEPENDING ON WHETHER JOB HAS CORE(KJOB,IJOB)
;TTY WILL REMAIN IN MONITOR MODE
;JOB MUST HAVE CORE ASSIGNED
;CALL:	MOVE	J,<JOB NUMBER>
;	MOVEI	TAC1,<ADDR. OF MONITOR JOB TO BE RUN>
;BE SURE MAP FOR THIS JOB IS SETUP.
;	PUSHJ	P,MONJOB
;WHEN SCHEDULED TO RUN, MONITOR JOB MUST SET UP ITS OWN ACS (MONSTR)


↑MONJOB:PUSHJ	P,MSTART	;START WITH PC IN MONITOR
	JRST	SETRUN		;SET TTY TO START JOB WHEN COMMAND RESPONSE
				;IS FINISHED AND KEEP TTY IN MONITOR MODE
;MONSTR 

;SETUP ACS FOR MONITOR JOB STARTING AT UUO LEVEL.
;J←JOB NO.
;PROG←PROTECT RELOCATE
;P←JBTPDL
;PID←PROCESSOR ID.
;USED BY KJOB,CORE 0,SAVE,GET,RUN,R AND FINISH COMMANDS
;CALL:	MOVEI	TAC1,<MONITOR JOB STOP ADDRESS>
;	JSP	TAC,MONSTR
;	RETURN WITH ACS P, PROG AND J SETUP AS ABOVE.


↑MONSTR:MOVEI	PID,P1PID
	SKIPP1
	MOVEI	PID,P2PID	;(FAT CHANCE)
	MOVE	J,JOB(PID)	;GET CURRENT JOB NUMBER
	SKIPN	P,JBTPDL(J)	;GET A PDL FOR THIS JOB.  MAKE SURE IT'S THERE.
	JRST	LOSPDL
	PUSH	P,TAC1		;SAVE STOP ADRRESS
	JRST	(TAC)		;RETURN AND DO MONITOR JOB
;USTART, MSTART

;SET JOB STATE TO BE SCHEDULED TO RUN WITH SPECIFIED STARTING
;ADDRESS INCLUDING PC FLAGS CALLED ONLY WHEN JOB IN CORE AND AFTER
;JOB HAS BEEN ;SAFELY STOPPED IN ONE OF 2 STATES:
;1) PC IN USER MODE
;2) JOB IN A WAIT FOR SHARABLE DEVICE, OR IO WAIT
;CALL:	MOVE	TAC1,<STARTING PC>
;	MOVE	J,<JOB NUMBER>
;MAP FOR THIS JOB MUST BE SETUP.  JOB MUST BE IN CORE.
;	PUSHJ	P,USTART (PC TO USER MODE), OR MSTART (PC TO MONITOR MODE)
;	<RETURN HERE IMMEDIATELY>


↑USTART:XCTR	XR,[MOVE TAC,JOBPC]	;GET OLD PC
	TLNE	TAC,USRMOD		;IS IT IN USER MODE TOO?
	JRST	USTRT1			;YES, DUMP ACS AND PC FLAGS ARE ALREADY HIS
	MOVEI	TAC,JOBDAC		;NO, MOVE USERS(UUO) ACS TO DUMP ACS
	XCTR	XBLTRW,[BLT TAC,JOBD17]	;MOVE 20-37 INTO 0-17.
	MOVE	TAC,UUOPC(J)		;UUO PC HAS LAST KNOWN PC
	TLNN	TAC,USRMOD		;IF NOT USEER MODE
	MOVE	TAC,UUOOPC(J)		;TRY THIS
	TLNN	TAC,USRMOD		;IS IT?
	TLZ	TAC,-1			;NO, CLEAR ALL PC FLAGS
	HRRI	TAC,-1(TAC)		;SUBTRACT 1 FROM RIGHT HALF AND PRESERVE
					;PC FLAGS (RH=0 ON HALT 0 OR FIRST START)
USTRT1:	HLL	TAC1,TAC		;PRESERVE USER APR FLAGS
	TLO	TAC1,USRMOD		;MAKE SURE NEW PC IN USER MODE
NOKL10,<TLZ	TAC1,37			;MAKE SURE NO INDIRECT BITS OR INDEX FIELD >
IFKL10,<TLZ	TAC1,37!PCPUBL		;CLEAR INDIRECT/INDEX. SET PRIVATE >
	JRST	MSTAR1

↑MSTART:XCTR	XR,[MOVE TAC,JOBPC]	;PICK UP USER'S PC
	TLNE	TAC,USRMOD		;IN USER MODE?
	JRST	MSTAR1			;YES, THIS IS CORRECT JOBOPC
	MOVE	TAC,UUOPC(J)		;HERE IS LAST USER PC (MAYBE)
	HRRI	TAC,-1(TAC)		;JUST LIKE USTART
MSTAR1:	TLNE	TAC,USRMOD		;IF THIS ISN'T USER PC LEAVE HIS OLD ONE
	XCTR	XW,[MOVEM TAC,JOBOPC]	;STORE IT FOR LATER USE
	XCTR	XW,[MOVEM TAC1,JOBPC]	;STORE NEW PC
	CAMN	J,JOB(PID)		;IS THIS CURRENT JOB?
	MOVEM	TAC1,USRPC(PID)		;YES.  STORE IN SYSTEM CORE AS WELL.
	SKIPE	INTACT(PID)
	CAME	J,SJOB			;IS THIS JOB RUNNING USER INTERRUPTS?
	JRST	MSTAR2			;NO
	MOVE	TAC,INTSP		;UPDATE USRPC IN THE INTERRUPT STACK
	MOVEM	TAC1,USRPC-USRJDA-20(TAC)
MSTAR2:	PUSHJ	P,STXTM2		;UPDATE INTERACTION RUN TIME FOR THIS JOB
	MOVSI	TAC,JERR+WTMASK
	ANDCAM	TAC,JBTSTS(J)		;CLEAR ERROR AND WAIT STATUS BITS
	MOVNI	TAC,RUNQ		;REQUE JOB TO RUN QUEUE
	MOVEM	TAC,JOBQUE(J)
	SETOM	STIME(J)		;THIS CORE IMAGE HAS BEEN MODIFIED
	JRST	TTYSET			;SET TTY STATE TO INITIAL COND.

;TTYUSR OR TTYURC SHOULD BE CALLED TO INDICATE WHETHER TTY TO USER
;OR EXEC MODE AND THAT JOB IS TO RUN (RUN BIT =1) WHEN MONITOR COMMAND
;RESPONSE FINISHES.  SET MONITOR MODE.
;SETRUN, REQUE


;SETRUN - SET JOB STATUS RUN BIT (RUN).  CALLED BY SCANNER SERVICE WHEN
;TTY MONITOR COMMAND RESPONSE FINISHES.  THIS ACTION IS ENABLED BY CALLING
;TTYUSR, OR TTYURC IN SCNSER
;CALL:	MOVE	J,<JOB NUMBER>
;	PUSHJ	P,SETRUN

;REQUE - CAUSE JOB TO BE REQUEUED NEXT TIME THE SCHEDULER RUNS
;CALL:	MOVE	J,<JOB NUMBER>
;	STORE QUEUE CODE IN JOBQUE(J)
;	PUSHJ	P,REQUE


↑SETRUN:LDB	TAC,[POINT JWSIZ,JBTSTS(J),JWPOS]  ;GET OLD WAIT QUEUE CODE
	JUMPE	TAC,SETR1		;JUMP IF NONE
	AOSE	REQTAB(TAC)		;DEVICE AVAILABLE?
	MOVNM	TAC,JOBQUE(J)		;NO - PUT US BACK INTO WAIT Q
SETR1:	MOVSI	TAC,RUN			;SET RUN BIT IN JOB STATUS WORD
	IORM	TAC,JBTSTS(J)
↑REQUE:	PUSH	P,TAC
	MOVEI	TAC,QJOB(J)
	CONO	PI,PIOFF
	SKIPE	(TAC)
	JRST	.+3
	EXCH	TAC,QJOB		;QJOB←ADDRESS QJOB(J).  TAC←OLD QJOB
	HRROM	TAC,@QJOB		;QJOB(J)←-1,,OLD QJOB
	CONO	PI,PION
	JRST	TPOPJ
;SETSLP, WAKE

;ROUTINE TO PUT A JOB TO SLEEP AND WAKE UP AGAIN LATER
;CALLED AFTER CLOCK QUEUE REQUEST PUT IN BY UUO ROUTINE

↑SETSLP:MOVSI	TAC,CLKR	;FLAG THAT A CLOCK REQUEST HAS BEEN PUT IN.
	IORM	TAC,JBTSTS(J)	;SO ONLY ONE PER JOB
	MOVEI	AC1,IOWQ	;SLEEP STATE CODE
	JRST	SETSTT		;SET STATUS AND RESCHEDULE

;HERE AT CLOCK LEVEL WHEN CLOCK REQUEST TIMES OUT FOR SLEEP. JOB NO. IN TAC

↑WAKE:	MOVNI	TAC1,RUNQ	;RUN QUEUE CODE
	MOVE	J,TAC		;JOB NO.
	MOVSI	TAC,CLKR	;CLEAR CLOCK REQUEST BIT FOR THIS JOB
	ANDCAM	TAC,JBTSTS(J)	;SO IT CAN PUT ANOTHER ONE IN
	MOVM	TAC,JOBQUE(J)	;GET QUEUE CODE
	CAIE	TAC,IOWQ	;IS JOB STILL SLEEPING?
	POPJ	P,		;NO
	MOVEM	TAC1,JOBQUE(J)	;YES, STORE RUN QUEUE CODE
	JRST	REQUE		;(↑C, START CAN GET JOB OUT OF SLEEP)
;GETDCDT, GETDCMT, MTWAIT, DTWAIT, DCWAIT, STWAIT, DVWAIT


;GET DATA CONTROL AND ANOTHER SHARABLE DEVICE.
;JOB NEVER GETS ONE DEVICE AND WAITS FOR SECOND, SINCE TYPING
;CONTROL C WOULD NEVER FINISH WITH FIRST DEVICE
;CALL	PUSHJ	P,GETDCXX
;	AOSE	XXREQ		;REQUEST COUNT FOR OTHER DEVICE
;	<RETURN WHEN BOTH AVAILABLE>

↑GETDCDT:↑GETDCMT:
	XCT	@(P)		;INCREASE SHARABLE DEVICE REQ. COUNT
GETWT:	PUSHJ	P,DVWAT1	;NOT AVAIL., GO WAIT FOR IT
	AOSN	DCREQ		;IS DATA BONTROL AVAILABLE?
	JRST	CPOPJ1		;YES, RETURN BOTH AVAILABLE
	MOVE	AC1,@(P)	;DATA CONTROL NOT AVAILABLE
	SUBI	AC1,REQTAB
	SOSL	REQTAB(AC1)	;REDUCE REQ. COUNT FOR OTHER SHARABLE DEVICE.
	SETOM	AVALTB(AC1)	;SET AVAILABLE IF OTHER JOBS WAITING
	JFCL	DCREQ		;ARGUMENT FOR DCWAIT
	PUSHJ	P,DCWAIT	;WAIT FOR DATA CONTROL FREE
	MOVE	AC1,@(P)	;INCREMENT REQ. COUNT
	AOSN	@AC1		;NOW IS SHARABLE DEVICE FREE?
	JRST	CPOPJ1		;YES
	SOSL	DCREQ		;NO, REDUCE DATA CONTROL REQUEST
	SETOM	DCAVAL		;SET AVAIL.  SOME OTHER JOB WAITING FOR IT
	JRST	GETWT		;TRY AGAIN

;WAIT FOR A SHARABLE DEVICE -  UUO LEVEL ONLY- FROM DEVICE SERVICE ROUTINES
;CALL:	AOSLE	XXREQ		;ADD 1 TO SHARABLE DEVICE REQUEST COUNT
;				;IS DEVICE AVAILABLE?
;	PUSHJ	P,XXWAIT	;NO, PUT JOB IN WAIT QUEUE
;	<RETURN WHEN DEVICE AVAILABLE>

;INITIALLY THE REQUEST COUNT IS -N, WHERE N IS THE
;NUMBER OF JOBS WHICH CAN USE THE SHARABLE DEVICE AT THE SAME TIME
;A REQUEST COUNT OF 0 MEANS THE MAXIMUM NO. OF JOBS ARE
;USING THE DEVICE, A POSITIVE NUMBER IS THE
;NUMBER OF JOBS WAITING IN THE SHARABLE DEVICE WAIT QUEUE

↑MTWAIT:↑DTWAIT:↑DCWAIT:↑STWAIT:
↑DVWAIT:MOVE	AC1,(P)		;GET ADDRESS OF CALLER
	SKIPA	AC1,-2(AC1)	;GET AOSLE XXREQ INSTRUCTION
DVWAT1:	MOVE	AC1,@-1(P)	;GET ADR. OF CALLER OF THIS ROUTINE
	SUBI	AC1,REQTAB	;COMPUTE WAIT-STATE QUEUE CODE
SETSTT:	MOVE	AC3,JOB(PID)	;CURRENT JOB NO.
	HRRZ	AC1,AC1		;CLEAN UP JOB QUEUE CODE
	MOVNM	AC1,JOBQUE(AC3)	;STORE IN JOB STATUS WORD

IFN FTMQBUG,<	CAIE	AC1,MTQ		;ARE WE ENTERING MTQ?
		JRST	WSCHED		;NO.  JUST WAIT.
		CAMN	AC3,MTQBUG	;IS BUG TRAP ENABLED?
		SETOM	MTQBG1		;YES. SET FLAG DENOTING WRITE IS SIGNIFICANT
		PUSHJ	P,WSCHED
		SKIPN	MTCUSR		;IS MTC FREE?
		POPJ	P,		;YES.
		PUSHACS
		PUSHJ	P,DISMES
		ASCIZ	/AT MTWAIT AFTER WAITING FOR MTC, BUT IT'S NOT FREE.
/
		PUSHJ	P,DISFLU
		POPACS
		PUSHJ	P,DDTCALL
		POPJ	P,		>;FTMQBUG


	JRST	WSCHED		;GO SCHEDULE ANOTHER AND RETURN TO CALLER
				;WHEN SHARABLE DEVICE BECOMES AVAILABLE
				;SEE CLOCK AND CLKCSS WORD WAIT QUEUE CODE.
;STTIOD, SETIOD

;CALL FROM INTERRUPT LEVEL (INCLUDING CLK LEVEL) ONLY.
;SET JOB TO RUN AFTER IT HAS BEEN STOPPED BECAUSE IT HAD TO WAIT
;FOR IO TO COMPLETE FOR SOME DEVICE.  EACH SERVICE ROUTINE AT INTERRUPT
;LEVEL CHECKS WHEN IT FINISHES A TASK (BUFFERFUL) TO SEE IF THE
;JOB USING THE DEVICE HAS PREVIOUSLY CAUGHT UP WITH DEVICE AND HAS
;BEEN STOPPED
;
;CALL:	MOVE	DDB,<ADR. OF DEVICE DATA BLOCK>
;	MOVE	IOS,DEVIOS(DDB)	;GET DEVICE IO STATUS WORD FROM DDB
;	TLZE	IOS,IOW		;IS JOB IN AN IO WAIT FOR THIS DEVICE?
;	PUSHJ	P,SETIOD	;YES, GO FLAG JOB TO START UP AGAIN
;	RETURN
;
;REQUEUES JOB TO A RUN QUEUE.  THE SCHEDULER THEN SEES THAT THIS JOB
;HAS ITS IO WAIT SATISFIED AND IS WAITING TO BE RUN AGAIN


↑STTIOD:PUSH	P,[-TQ]		;HIGH-PRIORITY RUN QUEUE.
	CAIA
↑SETIOD:PUSH	P,[-RUNQ]	;REQUE TO RUNQ
	EXCH	J,(P)		;SAVE J
	PUSH	P,J		;SAVE QUEUE NUMBER
	LDB	J,PJOBN		;GET JOB NUMBER FROM DDB
	SKIPL	JBTSTS(J)	;IS JOB STILL RUNNABLE?
	JRST	SETID0		;NO. AVOID CHANGING QUEUE AND CALLING REQUE
	POP	P,JOBQUE(J)
	PUSHJ	P,REQUE		;ARRANGE TO REQUEUE THIS JOB.
	JRST	SETID1

SETID0:	POP	P,J		;FLUSH QUEUE CODE FROM STACK
SETID1:	POP	P,J		;RESTORE ORIGINAL CONTENTS OF J
NULTST:	SKIPE	JOB(PID)	;IS NULL JOB RUNNING?
	POPJ	P,		;NO.  LET CURRENT JOB FINISH IT'S QUANTUM
	CONO	PI,PIOFF	;FORCE NULL JOB OFF.
	JRST	STOP2
;WSCHED - CAUSE CLK ROUTINE TO RESCHEDULE   STOP2

;CALLED AT ANY LEVEL
;CALL:	PUSHJ	P,WSCHED
;	RETURN IMMEDIATELY EXCEPT IF AT UUO LEVEL
;	IF AT UUO LEVEL, RETURN WHEN JOB IS RUNABLE AGAIN


↑WSCHED:JUMPE	PID,WSCHD1
	PUSHACS
	SKIPP2
	JRST	WSCHDA
	PUSHJ	P,DISMES
	ASCIZ	/P2 AT WSCHED
/
	PUSHJ	P,DISFLUSH
	POPACS
	HALT	AUTOLOAD

WSCHDA:	PUSHJ	P,DISMES
	ASCIZ	/PID CLOBBERED AT WSCHED
/
	POPACS
	MOVEI	PID,0
WSCHD1:	ERRSPW			;IF THIS IS A SPACEWAR JOB, JUMP TO SPWERR
WSCHD2:	AOS	NWSCHEDS	;COUNT SCHEDULES
	CONO	PI,PIOFF	;AVOID PREMATURE CLK INT
	SETOM	SCHEDF(PID)	;THIS IS A SCHEDULING INTERRUPT
↑STOP2:	HLLOS	CLKFLG(PID)	;SET FLAG TO INDICATE CLK INTERRUPT
				;EVEN THOUGH CLK INTERRUPT IS NOT A TIME INTERRUPT
	CONO	PI,PION+1B24!1⊗(7-CLKCHN)
				;TURN PI BACK ON AND REQUEST INTERRUPT TO
				;CLK PI CHANNEL(LOWEST PRIORITY CHANNEL)
	CONO PI,PION		;RANDOM INSTRUCTION WHICH NEEDS THE ECL EBUS
				;AND WILL THEREFORE HANG UNTIL THE INTERRUPT
				;HAPPENS
	POPJ	P,		;INTERRUPT IMMEDIATELY IF AT UUO LEVEL
;WAIT1
;ROUTINE TO WAIT TILL DEVICE CATCHES UP WITH USER AND BECOMES INACTIVE
;CALLING SEQUENCE
;	PUSHJ	P,WAIT1
;	<RETURN HERE>
;
;n.b. this routine waits for INACTIVE, as compared to WSYNC which waits for IOW=0
 
;IF THE DEVICE IS INACTIVE (IOACT=0), RETURNS TO EXIT. OTHERWISE, SETS
;IOW:=1 AND ENTERS WAIT UNLESS IOACT BECOMES ZERO BEFORE THE
;JUMP IS MADE, IN WHICH CASE IT SETS IOW:=0 AND RETURNS TO EXIT.
;ON LEAVING THE WAIT STATE, RETURNS TO EXIT.

;CALLS WSYNC AND LOOPS TO PREVENT CALL-CONTINUE LOSSAGE.

↑WAIT1:	MOVE	IOS,DEVIOS(DDB)
	MOVE	AC1,DEVMOD(DDB)
	TLNE	AC1,DVTTY	;TTY MAY ALWAYS PROCEED FROM HERE - RPH
	POPJ	P,
	MOVSI	AC1,DEVIBF
	TDNE	AC1,DEVCMR(DDB)	;SKIP UNLESS INTERNALLY BUFFERED
	SKIPA	AC1,[DEVSBB,,0]
	MOVEI	AC1,IOACT
	TDNN	IOS,AC1		;IS DEVICE ACTIVE?
	POPJ	P,		;NO.
	PUSHJ	P,WSYNC		;WAIT
	JRST	WAIT1
;WSYNC
;WAIT FOR SETIOD TO BE CALLED BY INTERRUPT SERVICE ROUTINE
;IE  UNTIL CURRENT BUFFER ACTIVITY IS COMPLETED
;CALLED ONLY FROM UUO LEVEL
;CALL:	MOVE	DDB,<ADR. OF DEVICE DATA BLOCK>
;	PUSHJ	P,WSYNC
;	<RETURN HERE>

;RETURN IMMEDIATELY IF DEVICE IS INACTIVE, ELSE RETURN WHEN DEVICE FINISHES
;ITS NEXT BUFFER.  THIS ROUTINE PREVENTS THE STATE IOACT=0 AND IOW=1 FROM
;OCCURING. SETS IOW, WAITS UNTIL EXIT WHEN IOACT (OR DEVSBB) IS CLEARED.


↑WSYNC:	MOVEI	AC1,DIOWQ	;DEVICE IO WAIT QUEUE (QUEUE IF IOACT SET)
	MOVE	AC3,DEVIOS(DDB)	;SEE IF JOB IS LOCKED IN CORE
	MOVE	AC2,DEVMOD(DDB)	;FOR DEVICES OTHER THAN THE TTY MEANS IOACT IS ON
	TLNN	AC2,DVTTY
	TRNN	AC3,IOACT	;LOCKED IN?
	MOVEI	AC1,IOWQ	;NO, STRAIGHT IO WAIT QUEUE CODE
	MOVSI	AC2,DEVIBF	;IS THIS DEVICE INTERNALLY BUFFERED?
	TDNE	AC2,DEVCMR(DDB)	;(LPT, PTP, CAR, DSK, PTR)
	SKIPA	AC2,[DEVSBB,,0]	;YES, THEN TEST DEVSBB,
	MOVEI	AC2,IOACT	;OR IOACT IF NOT SO BUFFERED.
	HRRZ	AC3,DEVCMR(DDB)	;FIRST, DOES HE HAVE CONTROL CELLS?
	PUSH	P,AC3		;PUSH ADDRESS OF CONTROL CELL ON STACK.
	MOVE	AC3,JOB(PID)	;CURRENT JOB NO.
	SKIPN	(P)		;ANY CONTROL CELLS?
	JRST	WSYN.1		;NO.
	PSYNC1	<HRRZ TAC,DEVCMR(DDB)>	;GET CONTROL OF DEVIOS
WSYN.1:	MOVSI	IOS,IOW		;SETUP DEVICE IO WAIT BIT
	CONO	PI,PIOFF	;MAKE SURE NO ONE'S PEEKING.
	TDNN	AC2,DEVIOS(DDB)
	JRST	WSYN.4		;NOTHING ELSE TO WAIT FOR. TURN ON PI,RELEASE SYNC
	IORM	IOS,DEVIOS(DDB)
	MOVNM	AC1,JOBQUE(AC3)
	CONO	PI,PION
	SKIPN	(P)		;ANY CONTROL CELLS?
	JRST	WSYN.2		;NO.
	XSYNC1	<HRRZ TAC,DEVCMR(DDB)>
WSYN.2:	PUSHJ	P,WSCHED
	SKIPN	(P)		;ANY CONTROL CELLS?
	JRST	WSYN.3		;NO
	PSYNC1	<HRRZ TAC,DEVCMR(DDB)>	;GET CONTROL OF DEVIOS
WSYN.3:	TDNN	IOS,DEVIOS(DDB)	;MAKE SURE IOW IS CLEAR NOW.  REG 1/29/75
	JRST	WSYN.5		;YES. SOMEONE CALLED SETIOD (OR STTIOD)
	ANDCAM	IOS,DEVIOS(DDB)	;TURN OFF IOW IN CASE OF TTY OR SOME OTHER MISTAKE
	MOVE	IOS,DEVMOD(DDB)	;TTY IS A SPECIAL CASE.
	TLNE	IOS,DVTTY	
	JRST	WSYN.5		;TTY: JUST SET UP IOS AND LEAVE
	JRST	WSYN.1		;LOOP UNTIL SOMEONE TURNS IOW OFF OR IOACT GOES OFF.

WSYN.4:	CONO	PI,PION
WSYN.5:	MOVE	IOS,DEVIOS(DDB)
	SKIPN	(P)
	JRST	WSYN.6
	XSYNC1	<HRRZ TAC,DEVCMR(DDB)>
WSYN.6:	SUB	P,[1,,1]
	POPJ	P,
REPEAT 0,<
; ROUTINE TO SWITCH YOUR JOB TO THE OTHER PROCESSOR TEMPORARILY
; CALLING . . .
;	PUSHJ P,PSWITCH
; CLOBBERS ACCUMULATOR AC1

PSWITCH:
	LDB AC1,PRUNB		; PICK UP THIS JOB'S PROCESSOR BITS
	PUSH P,AC1		; SAVE THEM
	MOVEI AC1,RUN1
	SKIPN PID
	MOVEI AC1,RUN2
	PSYNC JBTCSC
	DPB AC1,PRUNB
	XSYNC JBTCSC
	PUSHJ P,WSCHED
	MOVE PID,OTHERID(PID)	; PICK UP THE PROPER ID
	POP P,AC1
	PSYNC JBTCSC
	DPB AC1,PRUNB
	XSYNC JBTCSC		; RESTORE RUN BITS
	POPJ P,

GOTOP1:	JUMPE PID,CPOPJ
	JRST PSWITCH
>
SUBTTL	BATCON	INITIATE PHANTOM PROCESSES	;BATCLK

;THERE ARE 4 EQUAL-LENGTH TABLES IN APRDAT WHICH CONTAIN THE NAMES
;OF ALL THE PHANTOM JOBS, THE CORRESPONDING PPN AND PRIVILEGES, AND
;THE DATE AND TIME WHEN NEXT TO START THE PROCESS.  ALL THE JOBS ARE
;STARTED WHEN THE SYSTEM STARTS UP, AND CHECKED FOR RESTART EVERY MINUTE

IFN FTBAT,<
BATCLK:	HGMAC	(0)
	MOVEI	TAC,=60*JIFSEC	;RESET TO LOOK AGAIN IN 1 MINUTE
	MOVEM	TAC,BATYET	;SET RETRY TIME
	SKIPE	MAINTM		;MAINTMODE?
	POPJ	P,		;DON'T START PHANTOMS DURING MAINTENANCE.
	MOVSI	TAC,-BATLEN	;LENGTH OF BATMAN
BATLOP:	MOVEM	TAC,BATPNT	;SAVE IT
	SKIPE	AC1,BATMAN(TAC)	;JOBNAM
	SKIPN	AC3,ROBIN(TAC)	;PPN
	JRST	BAT3		;AVOID EMBARASSING CONFUSION!
	SKIPGE	J,ALFRED(TAC)	;GET THE TIME AND DATE OF NEXT STARTUP
	JRST	BAT3		;NEGATIVE MEANS DON'T START IT.
	JUMPE	J,BAT0		;IF ZERO THEN START IT.
	MOVE	TAC,TIME	;GET JIFFIE TIME
	IDIVI	TAC,=60*JIFSEC	;MAKE IT MINUTES
	HRL	TAC,THSDAT	;GET THE DATE
	CAMGE	TAC,J		;COMPARE WITH HIS REQUEST
	JRST	BAT3		;NOT YET.
	HRRZ	TAC,BATPNT	;GET CURRENT POINTER BACK
	SETZM	ALFRED(TAC)	;SO WE DON'T GET HERE AGAIN
BAT0:	MOVEI	J,JOBN-1	;SCAN JOBS LOOKING FOR ONE LIKE THIS.
	MOVSI	TAC,JNA
BAT1:	TDNN	TAC,JBTSTS(J)	;IS THERE A JOB HERE?
	JRST	BAT2		;NO.
	CAMN	AC1,JOBNAM(J)	;WITH A NAME LIKE MINE?
	CAME	AC3,PRJPRG(J)	;AND A PPN LIKE MINE TOO?
	JRST	BAT2		;NO MATCH.
	SKIPL	AC2,JBTSTS(J)	;IS THIS JOB RUNNABLE?
	TLNE	AC2,JLOG	;NOT RUNNABLE. IS IT LOGGED IN?
	JRST	BAT3		;RUNNABLE OR LOGGED IN.
;HERE WE HAVE A DEAD PHANTOM.  KILL IT AND START A NEW ONE.
;TO BE CONTINUED....
	JRST	BAT3		;TO BE CONTINUED. IN THE MEANTIME, DO NOTHING.

BAT2:	SOJG	J,BAT1		;LOOP LOOKING THRU ALL JOBS.
	PUSHJ	P,INIJOB	;ATTEMPT TO MAKE A NEW JOB
	POPJ	P,		;NONE AVAILABLE. (NO JOB SLOTS)
	JRST	BAT3B		;AVAILABLE LATER. (NEEDS FREE STORAGE)
	PUSHJ	P,GETBAT	;START A PHANTOM JOB.
BAT3:	MOVE	TAC,BATPNT	;GET BACK BAT POINTER
	AOBJN	TAC,BATLOP
	POPJ	P,		;DONE

BAT3B:	MOVEI	TAC,JIFSEC	;RETRY ONE SECOND FROM NOW
	MOVEM	TAC,BATYET
	POPJ	P,

;GETBAT	

↑GETBT0:MOVE	J,TAC		;HERE FROM AN XGPSER CLOCK REQUEST
	JRST	GETBTX		;JNA FOR THIS JOB IS TURNED ON ALREADY.

GETBAT:	SKIPE	MAINTMODE
	POPJ	P,
	MOVE	TAC,BATPNT	;GET THE POINTER TO BAT TABLES
	MOVE	TAC,GORDON(TAC)	;GET THIS PHANTOM'S PRIVILEGE BITS
	MOVEM	TAC,JBTPRV(J)	;SAVE
	MOVEM	TAC,JB2PRV(J)	;ALSO IN PASSIVE BITS
	MOVEM	AC3,PRJPRG(J)
	MOVEM	AC3,JOBPPN(J)
	MOVEM	AC1,JOBNAM(J)	;SETUP THIS GUY'S NAME
IFN FTSTAT,<	PUSHJ P,NAMSTT	>;IFN FTSTAT
	MOVSI	TAC,JNA		;MAKE SURE NO ONE GETS THIS NUMBER
	IORM	TAC,JBTSTS(J)
GETBTX:	MOVSI	TAC,'DSK'	;DEVICE DISK. 
	MOVEM	TAC,JOBDEV(J)
	MOVSI	TAC,'DMP'	;AND DUMP
	MOVEM	TAC,JOBLOG(J)
	SETZM	JOBCRD(J)	;NO CORE SIZE OR STARTING INCREMENT
	SETZM	JBTUFD(J)
	SETZM	DSKPPN(J)	;INITIALIZE DISK ALIAS PPN
	SETZM	JBTKCJ(J)
	SETZM	JBTMSC(J)	;NO RANDOM BITS
	MOVSI	TAC,JLOG
	ANDCAM	TAC,JBTSTS(J)
	HLLZS	SAVSAI(J)	;JUST IN CASE
GETBT1:	SETO	TAC1,		;ASK FOR A DETACHED TTY DDB
	PUSHJ	P,DDBSRC	;FIND ONE.
	JRST	DELBTT		;NO DDB, DELAY
GETBT2:	MOVEI	TAC,JOBDA	;AMOUNT OF NEW CORE NEEDED FOR JOB DATA AREA.
	PUSHJ	P,CORE0		;GET IT SOME CORE
	JRST	DELBAT		;NOT AVAILABLE, WAIT FOR IT
GETBT3:	MOVSI	TAC,SWP!SHF
	SKIPN	XJOB(J)		;IF STILL GETTING CORE, DELAY A WHILE
	TDNE	TAC,JBTSTS(J)	;DID JOB GO AWAY DURING ALL THIS?
	JRST	BATSWP		;YES, GET IT BACK IN
↑BATSW:				;ENTER HERE FROM SWAPPER WHEN JOB COMES IN
	PUSHJ	P,SETLOG	;SET-UP LOGIN STUFF (UUOCON)
	PUSHJ	P,MAPSET	;SETUP MAP FOR THIS USER.
	MOVE	TAC,JOBNAM(J)
	XCTR	XW,[MOVEM TAC,FILNAM]
	MOVE	TAC,JOBDEV(J)	;DEVICE
	XCTR	XW,[MOVEM TAC,DEVWRD]
	HLLZ	TAC,JOBLOG(J)	;EXTENSION
	XCTR	XW,[MOVEM TAC,FILEXT]
	SKIPN	TAC,JOBCRD(J)	;CORE SIZE
	JRST	.+3		;DON'T FUTZ WITH ZERO
	LSH	TAC,12		;TO WORDS
	SUBI	TAC,1		;TO PROT
	XCTR	XW,[MOVEM TAC,JOBCOR]
	HRRZ	TAC,JOBLOG(J)
	XCTR	XW,[MOVEM TAC,INCWRD]	;SAVE IN PLACE WE CAN FIND IT LATER
	MOVEI	TAC1,PRUNJB		;THIS GUY KNOWS ABOUT INCREMENTAL START-UP
	JRST	MONJOB			;RETURN FROM MONJOB VIA MAPSET

DELBAT:	LSH	J,=12		;HERE WE WAIT FOR CORE TO BECOME AVAILABLE
	ADD	J,[BATRS,,1]
DELB1:	CONO	PI,PIOFF
	IDPB	J,CLOCK(PID)
	CONO	PI,PION
	POPJ	P,

BATRS:	MOVE	J,TAC
	JRST	GETBT2

DELBTT:	LSH	J,=12
	ADD	J,[BATTT,,1]
	JRST	DELB1

BATTT:	MOVE	J,TAC
	JRST	GETBT1

BATSWP:	MOVSI	TAC,BATSNB	; SET THIS FLAG AND PUT IN SWAPIN LIST
	JRST	SETSIN		; WILL CALL BATSW WHEN SWAPPED IN

>;END OF FTBAT
;CSTAT, STAPUT, STAPTT		STATISTICS SERVICE
IFN FTSTAT,<

↑STAPUT:IORI	TAC,(J)
↑STAPTT:CONSO	PI,77000	;ARE WE ON CHAN HIGHER THAN 7?
	JRST	STAPOK		;NO, OK
	HRLI	TAC,STACLK	;YES, SEND THIS DATA UP TO CH7
	CONO	PI,PIOFF
	IDPB	TAC,CLKQ
	CONO	PI,PION
	POPJ	P,

STACLK:	HRRZ	TAC,DAT
STAPOK:	PUSH	P,TAC
	MOVE	TAC,TIME
	CAMN	TAC,STATIM	;DID THE TIME CHANGE SINCE LAST STAT. BYTE?
	JRST	STAPOJ		;NO.
	MOVEM	TAC,STATIM	;YES.  STORE TIME OF LAST STAT. BYTE.
	HLRZ	TAC,TAC		;TRANSMIT TIME IN 2 BYTES.
	ANDI	TAC,7777
	IORI	TAC,TIMSTA
	PUSHJ	P,STAPDO
	HRRZ	TAC,STATIM
	PUSHJ	P,STAPDO
STAPOJ:	POP	P,TAC
STAPDO:	IDPB	TAC,STATPTR
	MOVE	TAC,STATPTR
	CAME	TAC,[POINT 18,STATS+STATLEN-1,35]
	POPJ	P,
	MOVE	TAC,[POINT 18,STATS]
	MOVEM	TAC,STATPTR
	AOS	STATNUM
	POPJ	P,

↑GLUSTT:PUSH	P,TAC
	MOVE	TAC,JBTGLU(J)
	ANDI	TAC,77
	LSH	TAC,6
	TRO	TAC,GLUSTA
	PUSHJ	P,STAPUT
	POP	P,TAC
	POPJ	P,

↑NAMSTT:CONSO	PI,77000	;ARE WE ON CHAN HIGHER THAN 7?
	JRST	NAMOK		;NO, OK
	PUSH	P,J
	HRLI	J,NAMCLK	;REMEMBER THE JOB NUMBER AND COME BACK LATER
	CONO	PI,PIOFF
	IDPB	J,CLKQ
	CONO	PI,PION
	POP	P,J
	POPJ	P,

NAMCLK:	HRRZ	J,DAT
NAMOK:	PUSH	P,TAC
	MOVEI	TAC,NAMSTA(J)
	PUSHJ	P,STAPOK	;FIRST BYTE SAYS NAME FOLLOWS
	HLRZ	TAC,JOBNAM(J)
	PUSHJ	P,STAPOK
	HRRZ	TAC,JOBNAM(J)
	PUSHJ	P,STAPOK
	JRST	TPOPJ

↑SEGSTT:PUSH	P,TAC
	LDB	TAC,PSEGN
	LSH	TAC,6
	TRO	TAC,SEGSTA
	PUSHJ	P,STAPUT
	JRST	TPOPJ

>;FTSTAT